zpbt01()

subroutine zpbt01	(	character	uplo,
		integer	n,
		integer	kd,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldafac, * )	afac,
		integer	ldafac,
		double precision, dimension( * )	rwork,
		double precision	resid )

ZPBT01

Purpose:

!>
!> ZPBT01 reconstructs a Hermitian positive definite band matrix A from
!> its L*L' or U'*U factorization and computes the residual
!>    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
!>    norm( U'*U - A ) / ( N * norm(A) * EPS ),
!> where EPS is the machine epsilon, L' is the conjugate transpose of
!> L, and U' is the conjugate transpose of U.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of super-diagonals of the matrix A if UPLO = 'U', !> or the number of sub-diagonals if UPLO = 'L'. KD >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The original Hermitian band matrix A. If UPLO = 'U', the !> upper triangular part of A is stored as a band matrix; if !> UPLO = 'L', the lower triangular part of A is stored. The !> columns of the appropriate triangle are stored in the columns !> of A and the diagonals of the triangle are stored in the rows !> of A. See ZPBTRF for further details. !>
[in]	LDA	!> LDA is INTEGER. !> The leading dimension of the array A. LDA >= max(1,KD+1). !>
[in]	AFAC	!> AFAC is COMPLEX*16 array, dimension (LDAFAC,N) !> The factored form of the matrix A. AFAC contains the factor !> L or U from the L*L' or U'*U factorization in band storage !> format, as computed by ZPBTRF. !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. !> LDAFAC >= max(1,KD+1). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS ) !> If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 118 of file zpbt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            KD, LDA, LDAFAC, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), AFAC( LDAFAC, * )
*     ..
*
*  =====================================================================
*
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K, KC, KLEN, ML, MU
      DOUBLE PRECISION   AKK, ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANHB
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, dlamch, zlanhb, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal, zher, ztrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhb( '1', uplo, n, kd, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 j = 1, n
            IF( dimag( afac( kd+1, j ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
   10    CONTINUE
      ELSE
         DO 20 j = 1, n
            IF( dimag( afac( 1, j ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
   20    CONTINUE
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 30 k = n, 1, -1
            kc = max( 1, kd+2-k )
            klen = kd + 1 - kc
*
*           Compute the (K,K) element of the result.
*
            akk = dble(
     $         zdotc( klen+1, afac( kc, k ), 1, afac( kc, k ), 1 ) )
            afac( kd+1, k ) = akk
*
*           Compute the rest of column K.
*
            IF( klen.GT.0 )
     $         CALL ztrmv( 'Upper', 'Conjugate', 'Non-unit', klen,
     $                     afac( kd+1, k-klen ), ldafac-1,
     $                     afac( kc, k ), 1 )
*
   30    CONTINUE
*
*     UPLO = 'L':  Compute the product L*L', overwriting L.
*
      ELSE
         DO 40 k = n, 1, -1
            klen = min( kd, n-k )
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( klen.GT.0 )
     $         CALL zher( 'Lower', klen, one, afac( 2, k ), 1,
     $                    afac( 1, k+1 ), ldafac-1 )
*
*           Scale column K by the diagonal element.
*
            akk = dble( afac( 1, k ) )
            CALL zdscal( klen+1, akk, afac( 1, k ), 1 )
*
   40    CONTINUE
      END IF
*
*     Compute the difference  L*L' - A  or  U'*U - A.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 60 j = 1, n
            mu = max( 1, kd+2-j )
            DO 50 i = mu, kd + 1
               afac( i, j ) = afac( i, j ) - a( i, j )
   50       CONTINUE
   60    CONTINUE
      ELSE
         DO 80 j = 1, n
            ml = min( kd+1, n-j+1 )
            DO 70 i = 1, ml
               afac( i, j ) = afac( i, j ) - a( i, j )
   70       CONTINUE
   80    CONTINUE
      END IF
*
*     Compute norm( L*L' - A ) / ( N * norm(A) * EPS )
*
      resid = zlanhb( '1', uplo, n, kd, afac, ldafac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of ZPBT01
*

Here is the call graph for this function:

Here is the caller graph for this function: