dpotf2()

subroutine dpotf2	(	character	uplo,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		integer	info )

DPOTF2 computes the Cholesky factorization of a symmetric/Hermitian positive definite matrix (unblocked algorithm).

Download DPOTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPOTF2 computes the Cholesky factorization of a real symmetric
!> positive definite matrix A.
!>
!> The factorization has the form
!>    A = U**T * U ,  if UPLO = 'U', or
!>    A = L  * L**T,  if UPLO = 'L',
!> where U is an upper triangular matrix and L is lower triangular.
!>
!> This is the unblocked version of the algorithm, calling Level 2 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> symmetric matrix A is stored. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the symmetric matrix A. If UPLO = 'U', the leading !> n by n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n by n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, if INFO = 0, the factor U or L from the Cholesky !> factorization A = U**T *U or A = L*L**T. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !> > 0: if INFO = k, the leading principal minor of order k !> is not positive, and the factorization could not be !> completed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 106 of file dpotf2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J
      DOUBLE PRECISION   AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, DISNAN
      DOUBLE PRECISION   DDOT
      EXTERNAL           lsame, ddot, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv, dscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPOTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization A = U**T *U.
*
         DO 10 j = 1, n
*
*           Compute U(J,J) and test for non-positive-definiteness.
*
            ajj = a( j, j ) - ddot( j-1, a( 1, j ), 1, a( 1, j ), 1 )
            IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J.
*
            IF( j.LT.n ) THEN
               CALL dgemv( 'Transpose', j-1, n-j, -one, a( 1, j+1 ),
     $                     lda, a( 1, j ), 1, one, a( j, j+1 ), lda )
               CALL dscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
   10    CONTINUE
      ELSE
*
*        Compute the Cholesky factorization A = L*L**T.
*
         DO 20 j = 1, n
*
*           Compute L(J,J) and test for non-positive-definiteness.
*
            ajj = a( j, j ) - ddot( j-1, a( j, 1 ), lda, a( j, 1 ),
     $            lda )
            IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J.
*
            IF( j.LT.n ) THEN
               CALL dgemv( 'No transpose', n-j, j-1, -one, a( j+1,
     $                     1 ),
     $                     lda, a( j, 1 ), lda, one, a( j+1, j ), 1 )
               CALL dscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
   20    CONTINUE
      END IF
      GO TO 40
*
   30 CONTINUE
      info = j
*
   40 CONTINUE
      RETURN
*
*     End of DPOTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: