ssytd2()

subroutine ssytd2	(	character	uplo,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	d,
		real, dimension( * )	e,
		real, dimension( * )	tau,
		integer	info
	)

SSYTD2 reduces a symmetric matrix to real symmetric tridiagonal form by an orthogonal similarity transformation (unblocked algorithm).

Download SSYTD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SSYTD2 reduces a real symmetric matrix A to symmetric tridiagonal
 form T by an orthogonal similarity transformation: Q**T * A * Q = T.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading n-by-n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n-by-n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if UPLO = 'U', the diagonal and first superdiagonal of A are overwritten by the corresponding elements of the tridiagonal matrix T, and the elements above the first superdiagonal, with the array TAU, represent the orthogonal matrix Q as a product of elementary reflectors; if UPLO = 'L', the diagonal and first subdiagonal of A are over- written by the corresponding elements of the tridiagonal matrix T, and the elements below the first subdiagonal, with the array TAU, represent the orthogonal matrix Q as a product of elementary reflectors. See Further Details.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	D	D is REAL array, dimension (N) The diagonal elements of the tridiagonal matrix T: D(i) = A(i,i).
[out]	E	E is REAL array, dimension (N-1) The off-diagonal elements of the tridiagonal matrix T: E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'.
[out]	TAU	TAU is REAL array, dimension (N-1) The scalar factors of the elementary reflectors (see Further Details).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  If UPLO = 'U', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(n-1) . . . H(2) H(1).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
  A(1:i-1,i+1), and tau in TAU(i).

  If UPLO = 'L', the matrix Q is represented as a product of elementary
  reflectors

     Q = H(1) H(2) . . . H(n-1).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in A(i+2:n,i),
  and tau in TAU(i).

  The contents of A on exit are illustrated by the following examples
  with n = 5:

  if UPLO = 'U':                       if UPLO = 'L':

    (  d   e   v2  v3  v4 )              (  d                  )
    (      d   e   v3  v4 )              (  e   d              )
    (          d   e   v4 )              (  v1  e   d          )
    (              d   e  )              (  v1  v2  e   d      )
    (                  d  )              (  v1  v2  v3  e   d  )

  where d and e denote diagonal and off-diagonal elements of T, and vi
  denotes an element of the vector defining H(i).

Definition at line 172 of file ssytd2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), D( * ), E( * ), TAU( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO, HALF
      parameter( one = 1.0, zero = 0.0, half = 1.0 / 2.0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I
      REAL               ALPHA, TAUI
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, slarfg, ssymv, ssyr2, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SDOT
      EXTERNAL           lsame, sdot
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSYTD2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Reduce the upper triangle of A
*
         DO 10 i = n - 1, 1, -1
*
*           Generate elementary reflector H(i) = I - tau * v * v**T
*           to annihilate A(1:i-1,i+1)
*
            CALL slarfg( i, a( i, i+1 ), a( 1, i+1 ), 1, taui )
            e( i ) = a( i, i+1 )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(1:i,1:i)
*
               a( i, i+1 ) = one
*
*              Compute  x := tau * A * v  storing x in TAU(1:i)
*
               CALL ssymv( uplo, i, taui, a, lda, a( 1, i+1 ), 1, zero,
     $                     tau, 1 )
*
*              Compute  w := x - 1/2 * tau * (x**T * v) * v
*
               alpha = -half*taui*sdot( i, tau, 1, a( 1, i+1 ), 1 )
               CALL saxpy( i, alpha, a( 1, i+1 ), 1, tau, 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**T - w * v**T
*
               CALL ssyr2( uplo, i, -one, a( 1, i+1 ), 1, tau, 1, a,
     $                     lda )
*
               a( i, i+1 ) = e( i )
            END IF
            d( i+1 ) = a( i+1, i+1 )
            tau( i ) = taui
   10    CONTINUE
         d( 1 ) = a( 1, 1 )
      ELSE
*
*        Reduce the lower triangle of A
*
         DO 20 i = 1, n - 1
*
*           Generate elementary reflector H(i) = I - tau * v * v**T
*           to annihilate A(i+2:n,i)
*
            CALL slarfg( n-i, a( i+1, i ), a( min( i+2, n ), i ), 1,
     $                   taui )
            e( i ) = a( i+1, i )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(i+1:n,i+1:n)
*
               a( i+1, i ) = one
*
*              Compute  x := tau * A * v  storing y in TAU(i:n-1)
*
               CALL ssymv( uplo, n-i, taui, a( i+1, i+1 ), lda,
     $                     a( i+1, i ), 1, zero, tau( i ), 1 )
*
*              Compute  w := x - 1/2 * tau * (x**T * v) * v
*
               alpha = -half*taui*sdot( n-i, tau( i ), 1, a( i+1, i ),
     $                 1 )
               CALL saxpy( n-i, alpha, a( i+1, i ), 1, tau( i ), 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**T - w * v**T
*
               CALL ssyr2( uplo, n-i, -one, a( i+1, i ), 1, tau( i ), 1,
     $                     a( i+1, i+1 ), lda )
*
               a( i+1, i ) = e( i )
            END IF
            d( i ) = a( i, i )
            tau( i ) = taui
   20    CONTINUE
         d( n ) = a( n, n )
      END IF
*
      RETURN
*
*     End of SSYTD2
*

Here is the call graph for this function:

Here is the caller graph for this function: