sget01()

subroutine sget01	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldafac, * )	afac,
		integer	ldafac,
		integer, dimension( * )	ipiv,
		real, dimension( * )	rwork,
		real	resid
	)

SGET01

Purpose:

 SGET01 reconstructs a matrix A from its L*U factorization and
 computes the residual
    norm(L*U - A) / ( N * norm(A) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The original M x N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	AFAC	AFAC is REAL array, dimension (LDAFAC,N) The factored form of the matrix A. AFAC contains the factors L and U from the L*U factorization as computed by SGETRF. Overwritten with the reconstructed matrix, and then with the difference L*U - A.
[in]	LDAFAC	LDAFAC is INTEGER The leading dimension of the array AFAC. LDAFAC >= max(1,M).
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from SGETRF.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESID	RESID is REAL norm(L*U - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 105 of file sget01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDAFAC, M, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               A( LDA, * ), AFAC( LDAFAC, * ), RWORK( * )
*     ..
*
*  =====================================================================
*
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      REAL               ANORM, EPS, T
*     ..
*     .. External Functions ..
      REAL               SDOT, SLAMCH, SLANGE
      EXTERNAL           sdot, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv, slaswp, sscal, strmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0.
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = slange( '1', m, n, a, lda, rwork )
*
*     Compute the product L*U and overwrite AFAC with the result.
*     A column at a time of the product is obtained, starting with
*     column N.
*
      DO 10 k = n, 1, -1
         IF( k.GT.m ) THEN
            CALL strmv( 'Lower', 'No transpose', 'Unit', m, afac,
     $                  ldafac, afac( 1, k ), 1 )
         ELSE
*
*           Compute elements (K+1:M,K)
*
            t = afac( k, k )
            IF( k+1.LE.m ) THEN
               CALL sscal( m-k, t, afac( k+1, k ), 1 )
               CALL sgemv( 'No transpose', m-k, k-1, one,
     $                     afac( k+1, 1 ), ldafac, afac( 1, k ), 1, one,
     $                     afac( k+1, k ), 1 )
            END IF
*
*           Compute the (K,K) element
*
            afac( k, k ) = t + sdot( k-1, afac( k, 1 ), ldafac,
     $                     afac( 1, k ), 1 )
*
*           Compute elements (1:K-1,K)
*
            CALL strmv( 'Lower', 'No transpose', 'Unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
         END IF
   10 CONTINUE
      CALL slaswp( n, afac, ldafac, 1, min( m, n ), ipiv, -1 )
*
*     Compute the difference  L*U - A  and store in AFAC.
*
      DO 30 j = 1, n
         DO 20 i = 1, m
            afac( i, j ) = afac( i, j ) - a( i, j )
   20    CONTINUE
   30 CONTINUE
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = slange( '1', m, n, afac, ldafac, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / real( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of SGET01
*

Here is the call graph for this function:

Here is the caller graph for this function: