chptrd()

subroutine chptrd	(	character	uplo,
		integer	n,
		complex, dimension( * )	ap,
		real, dimension( * )	d,
		real, dimension( * )	e,
		complex, dimension( * )	tau,
		integer	info )

CHPTRD

Download CHPTRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHPTRD reduces a complex Hermitian matrix A stored in packed form to
!> real symmetric tridiagonal form T by a unitary similarity
!> transformation: Q**H * A * Q = T.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	AP	!> AP is COMPLEX array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangle of the Hermitian matrix !> A, packed columnwise in a linear array. The j-th column of A !> is stored in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n. !> On exit, if UPLO = 'U', the diagonal and first superdiagonal !> of A are overwritten by the corresponding elements of the !> tridiagonal matrix T, and the elements above the first !> superdiagonal, with the array TAU, represent the unitary !> matrix Q as a product of elementary reflectors; if UPLO !> = 'L', the diagonal and first subdiagonal of A are over- !> written by the corresponding elements of the tridiagonal !> matrix T, and the elements below the first subdiagonal, with !> the array TAU, represent the unitary matrix Q as a product !> of elementary reflectors. See Further Details. !>
[out]	D	!> D is REAL array, dimension (N) !> The diagonal elements of the tridiagonal matrix T: !> D(i) = A(i,i). !>
[out]	E	!> E is REAL array, dimension (N-1) !> The off-diagonal elements of the tridiagonal matrix T: !> E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. !>
[out]	TAU	!> TAU is COMPLEX array, dimension (N-1) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  If UPLO = 'U', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(n-1) . . . H(2) H(1).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in AP,
!>  overwriting A(1:i-1,i+1), and tau is stored in TAU(i).
!>
!>  If UPLO = 'L', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(1) H(2) . . . H(n-1).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in AP,
!>  overwriting A(i+2:n,i), and tau is stored in TAU(i).
!> 

Definition at line 148 of file chptrd.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * )
      COMPLEX            AP( * ), TAU( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE, ZERO, HALF
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ),
     $                   half = ( 0.5e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, I1, I1I1, II
      COMPLEX            ALPHA, TAUI
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, chpmv, chpr2, clarfg, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX            CDOTC
      EXTERNAL           lsame, cdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHPTRD', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Reduce the upper triangle of A.
*        I1 is the index in AP of A(1,I+1).
*
         i1 = n*( n-1 ) / 2 + 1
         ap( i1+n-1 ) = real( ap( i1+n-1 ) )
         DO 10 i = n - 1, 1, -1
*
*           Generate elementary reflector H(i) = I - tau * v * v**H
*           to annihilate A(1:i-1,i+1)
*
            alpha = ap( i1+i-1 )
            CALL clarfg( i, alpha, ap( i1 ), 1, taui )
            e( i ) = real( alpha )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(1:i,1:i)
*
               ap( i1+i-1 ) = one
*
*              Compute  y := tau * A * v  storing y in TAU(1:i)
*
               CALL chpmv( uplo, i, taui, ap, ap( i1 ), 1, zero, tau,
     $                     1 )
*
*              Compute  w := y - 1/2 * tau * (y**H *v) * v
*
               alpha = -half*taui*cdotc( i, tau, 1, ap( i1 ), 1 )
               CALL caxpy( i, alpha, ap( i1 ), 1, tau, 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**H - w * v**H
*
               CALL chpr2( uplo, i, -one, ap( i1 ), 1, tau, 1, ap )
*
            END IF
            ap( i1+i-1 ) = e( i )
            d( i+1 ) = real( ap( i1+i ) )
            tau( i ) = taui
            i1 = i1 - i
   10    CONTINUE
         d( 1 ) = real( ap( 1 ) )
      ELSE
*
*        Reduce the lower triangle of A. II is the index in AP of
*        A(i,i) and I1I1 is the index of A(i+1,i+1).
*
         ii = 1
         ap( 1 ) = real( ap( 1 ) )
         DO 20 i = 1, n - 1
            i1i1 = ii + n - i + 1
*
*           Generate elementary reflector H(i) = I - tau * v * v**H
*           to annihilate A(i+2:n,i)
*
            alpha = ap( ii+1 )
            CALL clarfg( n-i, alpha, ap( ii+2 ), 1, taui )
            e( i ) = real( alpha )
*
            IF( taui.NE.zero ) THEN
*
*              Apply H(i) from both sides to A(i+1:n,i+1:n)
*
               ap( ii+1 ) = one
*
*              Compute  y := tau * A * v  storing y in TAU(i:n-1)
*
               CALL chpmv( uplo, n-i, taui, ap( i1i1 ), ap( ii+1 ),
     $                     1,
     $                     zero, tau( i ), 1 )
*
*              Compute  w := y - 1/2 * tau * (y**H *v) * v
*
               alpha = -half*taui*cdotc( n-i, tau( i ), 1,
     $                                   ap( ii+1 ),
     $                 1 )
               CALL caxpy( n-i, alpha, ap( ii+1 ), 1, tau( i ), 1 )
*
*              Apply the transformation as a rank-2 update:
*                 A := A - v * w**H - w * v**H
*
               CALL chpr2( uplo, n-i, -one, ap( ii+1 ), 1, tau( i ),
     $                     1,
     $                     ap( i1i1 ) )
*
            END IF
            ap( ii+1 ) = e( i )
            d( i ) = real( ap( ii ) )
            tau( i ) = taui
            ii = i1i1
   20    CONTINUE
         d( n ) = real( ap( ii ) )
      END IF
*
      RETURN
*
*     End of CHPTRD
*

Here is the call graph for this function:

Here is the caller graph for this function: