cdotc()

complex function cdotc	(	integer	n,
		complex, dimension(*)	cx,
		integer	incx,
		complex, dimension(*)	cy,
		integer	incy
	)

CDOTC

Purpose:

 CDOTC forms the dot product of two complex vectors
      CDOTC = X^H * Y

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in]	CX	CX is COMPLEX array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
[in]	INCX	INCX is INTEGER storage spacing between elements of CX
[in]	CY	CY is COMPLEX array, dimension ( 1 + ( N - 1 )*abs( INCY ) )
[in]	INCY	INCY is INTEGER storage spacing between elements of CY

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

     jack dongarra, linpack,  3/11/78.
     modified 12/3/93, array(1) declarations changed to array(*)

Definition at line 82 of file cdotc.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,INCY,N
*     ..
*     .. Array Arguments ..
      COMPLEX CX(*),CY(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      COMPLEX CTEMP
      INTEGER I,IX,IY
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC conjg
*     ..
      ctemp = (0.0,0.0)
      cdotc = (0.0,0.0)
      IF (n.LE.0) RETURN
      IF (incx.EQ.1 .AND. incy.EQ.1) THEN
*
*        code for both increments equal to 1
*
         DO i = 1,n
            ctemp = ctemp + conjg(cx(i))*cy(i)
         END DO
      ELSE
*
*        code for unequal increments or equal increments
*          not equal to 1
*
         ix = 1
         iy = 1
         IF (incx.LT.0) ix = (-n+1)*incx + 1
         IF (incy.LT.0) iy = (-n+1)*incy + 1
         DO i = 1,n
            ctemp = ctemp + conjg(cx(ix))*cy(iy)
            ix = ix + incx
            iy = iy + incy
         END DO
      END IF
      cdotc = ctemp
      RETURN
*
*     End of CDOTC
*

Here is the call graph for this function:

Here is the caller graph for this function: