chpr2()

subroutine chpr2	(	character	uplo,
		integer	n,
		complex	alpha,
		complex, dimension(*)	x,
		integer	incx,
		complex, dimension(*)	y,
		integer	incy,
		complex, dimension(*)	ap )

CHPR2

Purpose:

!>
!> CHPR2  performs the hermitian rank 2 operation
!>
!>    A := alpha*x*y**H + conjg( alpha )*y*x**H + A,
!>
!> where alpha is a scalar, x and y are n element vectors and A is an
!> n by n hermitian matrix, supplied in packed form.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> On entry, UPLO specifies whether the upper or lower !> triangular part of the matrix A is supplied in the packed !> array AP as follows: !> !> UPLO = 'U' or 'u' The upper triangular part of A is !> supplied in AP. !> !> UPLO = 'L' or 'l' The lower triangular part of A is !> supplied in AP. !>
[in]	N	!> N is INTEGER !> On entry, N specifies the order of the matrix A. !> N must be at least zero. !>
[in]	ALPHA	!> ALPHA is COMPLEX !> On entry, ALPHA specifies the scalar alpha. !>
[in]	X	!> X is COMPLEX array, dimension at least !> ( 1 + ( n - 1 )*abs( INCX ) ). !> Before entry, the incremented array X must contain the n !> element vector x. !>
[in]	INCX	!> INCX is INTEGER !> On entry, INCX specifies the increment for the elements of !> X. INCX must not be zero. !>
[in]	Y	!> Y is COMPLEX array, dimension at least !> ( 1 + ( n - 1 )*abs( INCY ) ). !> Before entry, the incremented array Y must contain the n !> element vector y. !>
[in]	INCY	!> INCY is INTEGER !> On entry, INCY specifies the increment for the elements of !> Y. INCY must not be zero. !>
[in,out]	AP	!> AP is COMPLEX array, dimension at least !> ( ( n*( n + 1 ) )/2 ). !> Before entry with UPLO = 'U' or 'u', the array AP must !> contain the upper triangular part of the hermitian matrix !> packed sequentially, column by column, so that AP( 1 ) !> contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 1, 2 ) !> and a( 2, 2 ) respectively, and so on. On exit, the array !> AP is overwritten by the upper triangular part of the !> updated matrix. !> Before entry with UPLO = 'L' or 'l', the array AP must !> contain the lower triangular part of the hermitian matrix !> packed sequentially, column by column, so that AP( 1 ) !> contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 2, 1 ) !> and a( 3, 1 ) respectively, and so on. On exit, the array !> AP is overwritten by the lower triangular part of the !> updated matrix. !> Note that the imaginary parts of the diagonal elements need !> not be set, they are assumed to be zero, and on exit they !> are set to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  Level 2 Blas routine.
!>
!>  -- Written on 22-October-1986.
!>     Jack Dongarra, Argonne National Lab.
!>     Jeremy Du Croz, Nag Central Office.
!>     Sven Hammarling, Nag Central Office.
!>     Richard Hanson, Sandia National Labs.
!> 

Definition at line 144 of file chpr2.f.

*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      COMPLEX ALPHA
      INTEGER INCX,INCY,N
      CHARACTER UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX AP(*),X(*),Y(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX ZERO
      parameter(zero= (0.0e+0,0.0e+0))
*     ..
*     .. Local Scalars ..
      COMPLEX TEMP1,TEMP2
      INTEGER I,INFO,IX,IY,J,JX,JY,K,KK,KX,KY
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC conjg,real
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (n.LT.0) THEN
          info = 2
      ELSE IF (incx.EQ.0) THEN
          info = 5
      ELSE IF (incy.EQ.0) THEN
          info = 7
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('CHPR2 ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF ((n.EQ.0) .OR. (alpha.EQ.zero)) RETURN
*
*     Set up the start points in X and Y if the increments are not both
*     unity.
*
      IF ((incx.NE.1) .OR. (incy.NE.1)) THEN
          IF (incx.GT.0) THEN
              kx = 1
          ELSE
              kx = 1 - (n-1)*incx
          END IF
          IF (incy.GT.0) THEN
              ky = 1
          ELSE
              ky = 1 - (n-1)*incy
          END IF
          jx = kx
          jy = ky
      END IF
*
*     Start the operations. In this version the elements of the array AP
*     are accessed sequentially with one pass through AP.
*
      kk = 1
      IF (lsame(uplo,'U')) THEN
*
*        Form  A  when upper triangle is stored in AP.
*
          IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
              DO 20 j = 1,n
                  IF ((x(j).NE.zero) .OR. (y(j).NE.zero)) THEN
                      temp1 = alpha*conjg(y(j))
                      temp2 = conjg(alpha*x(j))
                      k = kk
                      DO 10 i = 1,j - 1
                          ap(k) = ap(k) + x(i)*temp1 + y(i)*temp2
                          k = k + 1
   10                 CONTINUE
                      ap(kk+j-1) = real(ap(kk+j-1)) +
     +                             real(x(j)*temp1+y(j)*temp2)
                  ELSE
                      ap(kk+j-1) = real(ap(kk+j-1))
                  END IF
                  kk = kk + j
   20         CONTINUE
          ELSE
              DO 40 j = 1,n
                  IF ((x(jx).NE.zero) .OR. (y(jy).NE.zero)) THEN
                      temp1 = alpha*conjg(y(jy))
                      temp2 = conjg(alpha*x(jx))
                      ix = kx
                      iy = ky
                      DO 30 k = kk,kk + j - 2
                          ap(k) = ap(k) + x(ix)*temp1 + y(iy)*temp2
                          ix = ix + incx
                          iy = iy + incy
   30                 CONTINUE
                      ap(kk+j-1) = real(ap(kk+j-1)) +
     +                             real(x(jx)*temp1+y(jy)*temp2)
                  ELSE
                      ap(kk+j-1) = real(ap(kk+j-1))
                  END IF
                  jx = jx + incx
                  jy = jy + incy
                  kk = kk + j
   40         CONTINUE
          END IF
      ELSE
*
*        Form  A  when lower triangle is stored in AP.
*
          IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
              DO 60 j = 1,n
                  IF ((x(j).NE.zero) .OR. (y(j).NE.zero)) THEN
                      temp1 = alpha*conjg(y(j))
                      temp2 = conjg(alpha*x(j))
                      ap(kk) = real(ap(kk)) +
     +                         real(x(j)*temp1+y(j)*temp2)
                      k = kk + 1
                      DO 50 i = j + 1,n
                          ap(k) = ap(k) + x(i)*temp1 + y(i)*temp2
                          k = k + 1
   50                 CONTINUE
                  ELSE
                      ap(kk) = real(ap(kk))
                  END IF
                  kk = kk + n - j + 1
   60         CONTINUE
          ELSE
              DO 80 j = 1,n
                  IF ((x(jx).NE.zero) .OR. (y(jy).NE.zero)) THEN
                      temp1 = alpha*conjg(y(jy))
                      temp2 = conjg(alpha*x(jx))
                      ap(kk) = real(ap(kk)) +
     +                         real(x(jx)*temp1+y(jy)*temp2)
                      ix = jx
                      iy = jy
                      DO 70 k = kk + 1,kk + n - j
                          ix = ix + incx
                          iy = iy + incy
                          ap(k) = ap(k) + x(ix)*temp1 + y(iy)*temp2
   70                 CONTINUE
                  ELSE
                      ap(kk) = real(ap(kk))
                  END IF
                  jx = jx + incx
                  jy = jy + incy
                  kk = kk + n - j + 1
   80         CONTINUE
          END IF
      END IF
*
      RETURN
*
*     End of CHPR2
*

Here is the call graph for this function:

Here is the caller graph for this function: