cdrvvx()

subroutine cdrvvx	(	integer	nsizes,
		integer, dimension( * )	nn,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer, dimension( 4 )	iseed,
		real	thresh,
		integer	niunit,
		integer	nounit,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( lda, * )	h,
		complex, dimension( * )	w,
		complex, dimension( * )	w1,
		complex, dimension( ldvl, * )	vl,
		integer	ldvl,
		complex, dimension( ldvr, * )	vr,
		integer	ldvr,
		complex, dimension( ldlre, * )	lre,
		integer	ldlre,
		real, dimension( * )	rcondv,
		real, dimension( * )	rcndv1,
		real, dimension( * )	rcdvin,
		real, dimension( * )	rconde,
		real, dimension( * )	rcnde1,
		real, dimension( * )	rcdein,
		real, dimension( * )	scale,
		real, dimension( * )	scale1,
		real, dimension( 11 )	result,
		complex, dimension( * )	work,
		integer	nwork,
		real, dimension( * )	rwork,
		integer	info )

CDRVVX

Purpose:

!>
!>    CDRVVX  checks the nonsymmetric eigenvalue problem expert driver
!>    CGEEVX.
!>
!>    CDRVVX uses both test matrices generated randomly depending on
!>    data supplied in the calling sequence, as well as on data
!>    read from an input file and including precomputed condition
!>    numbers to which it compares the ones it computes.
!>
!>    When CDRVVX is called, a number of matrix  () and a
!>    number of matrix  are specified in the calling sequence.
!>    For each size () and each type of matrix, one matrix will be
!>    generated and used to test the nonsymmetric eigenroutines.  For
!>    each matrix, 9 tests will be performed:
!>
!>    (1)     | A * VR - VR * W | / ( n |A| ulp )
!>
!>      Here VR is the matrix of unit right eigenvectors.
!>      W is a diagonal matrix with diagonal entries W(j).
!>
!>    (2)     | A**H  * VL - VL * W**H | / ( n |A| ulp )
!>
!>      Here VL is the matrix of unit left eigenvectors, A**H is the
!>      conjugate transpose of A, and W is as above.
!>
!>    (3)     | |VR(i)| - 1 | / ulp and largest component real
!>
!>      VR(i) denotes the i-th column of VR.
!>
!>    (4)     | |VL(i)| - 1 | / ulp and largest component real
!>
!>      VL(i) denotes the i-th column of VL.
!>
!>    (5)     W(full) = W(partial)
!>
!>      W(full) denotes the eigenvalues computed when VR, VL, RCONDV
!>      and RCONDE are also computed, and W(partial) denotes the
!>      eigenvalues computed when only some of VR, VL, RCONDV, and
!>      RCONDE are computed.
!>
!>    (6)     VR(full) = VR(partial)
!>
!>      VR(full) denotes the right eigenvectors computed when VL, RCONDV
!>      and RCONDE are computed, and VR(partial) denotes the result
!>      when only some of VL and RCONDV are computed.
!>
!>    (7)     VL(full) = VL(partial)
!>
!>      VL(full) denotes the left eigenvectors computed when VR, RCONDV
!>      and RCONDE are computed, and VL(partial) denotes the result
!>      when only some of VR and RCONDV are computed.
!>
!>    (8)     0 if SCALE, ILO, IHI, ABNRM (full) =
!>                 SCALE, ILO, IHI, ABNRM (partial)
!>            1/ulp otherwise
!>
!>      SCALE, ILO, IHI and ABNRM describe how the matrix is balanced.
!>      (full) is when VR, VL, RCONDE and RCONDV are also computed, and
!>      (partial) is when some are not computed.
!>
!>    (9)     RCONDV(full) = RCONDV(partial)
!>
!>      RCONDV(full) denotes the reciprocal condition numbers of the
!>      right eigenvectors computed when VR, VL and RCONDE are also
!>      computed. RCONDV(partial) denotes the reciprocal condition
!>      numbers when only some of VR, VL and RCONDE are computed.
!>
!>    The  are specified by an array NN(1:NSIZES); the value of
!>    each element NN(j) specifies one size.
!>    The  are specified by a logical array DOTYPE( 1:NTYPES );
!>    if DOTYPE(j) is .TRUE., then matrix type  will be generated.
!>    Currently, the list of possible types is:
!>
!>    (1)  The zero matrix.
!>    (2)  The identity matrix.
!>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
!>
!>    (4)  A diagonal matrix with evenly spaced entries
!>         1, ..., ULP  and random complex angles.
!>         (ULP = (first number larger than 1) - 1 )
!>    (5)  A diagonal matrix with geometrically spaced entries
!>         1, ..., ULP  and random complex angles.
!>    (6)  A diagonal matrix with  entries 1, ULP, ..., ULP
!>         and random complex angles.
!>
!>    (7)  Same as (4), but multiplied by a constant near
!>         the overflow threshold
!>    (8)  Same as (4), but multiplied by a constant near
!>         the underflow threshold
!>
!>    (9)  A matrix of the form  U' T U, where U is unitary and
!>         T has evenly spaced entries 1, ..., ULP with random complex
!>         angles on the diagonal and random O(1) entries in the upper
!>         triangle.
!>
!>    (10) A matrix of the form  U' T U, where U is unitary and
!>         T has geometrically spaced entries 1, ..., ULP with random
!>         complex angles on the diagonal and random O(1) entries in
!>         the upper triangle.
!>
!>    (11) A matrix of the form  U' T U, where U is unitary and
!>         T has  entries 1, ULP,..., ULP with random
!>         complex angles on the diagonal and random O(1) entries in
!>         the upper triangle.
!>
!>    (12) A matrix of the form  U' T U, where U is unitary and
!>         T has complex eigenvalues randomly chosen from
!>         ULP < |z| < 1   and random O(1) entries in the upper
!>         triangle.
!>
!>    (13) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
!>         with random complex angles on the diagonal and random O(1)
!>         entries in the upper triangle.
!>
!>    (14) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has geometrically spaced entries
!>         1, ..., ULP with random complex angles on the diagonal
!>         and random O(1) entries in the upper triangle.
!>
!>    (15) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has  entries 1, ULP,..., ULP
!>         with random complex angles on the diagonal and random O(1)
!>         entries in the upper triangle.
!>
!>    (16) A matrix of the form  X' T X, where X has condition
!>         SQRT( ULP ) and T has complex eigenvalues randomly chosen
!>         from ULP < |z| < 1 and random O(1) entries in the upper
!>         triangle.
!>
!>    (17) Same as (16), but multiplied by a constant
!>         near the overflow threshold
!>    (18) Same as (16), but multiplied by a constant
!>         near the underflow threshold
!>
!>    (19) Nonsymmetric matrix with random entries chosen from |z| < 1
!>         If N is at least 4, all entries in first two rows and last
!>         row, and first column and last two columns are zero.
!>    (20) Same as (19), but multiplied by a constant
!>         near the overflow threshold
!>    (21) Same as (19), but multiplied by a constant
!>         near the underflow threshold
!>
!>    In addition, an input file will be read from logical unit number
!>    NIUNIT. The file contains matrices along with precomputed
!>    eigenvalues and reciprocal condition numbers for the eigenvalues
!>    and right eigenvectors. For these matrices, in addition to tests
!>    (1) to (9) we will compute the following two tests:
!>
!>   (10)  |RCONDV - RCDVIN| / cond(RCONDV)
!>
!>      RCONDV is the reciprocal right eigenvector condition number
!>      computed by CGEEVX and RCDVIN (the precomputed true value)
!>      is supplied as input. cond(RCONDV) is the condition number of
!>      RCONDV, and takes errors in computing RCONDV into account, so
!>      that the resulting quantity should be O(ULP). cond(RCONDV) is
!>      essentially given by norm(A)/RCONDE.
!>
!>   (11)  |RCONDE - RCDEIN| / cond(RCONDE)
!>
!>      RCONDE is the reciprocal eigenvalue condition number
!>      computed by CGEEVX and RCDEIN (the precomputed true value)
!>      is supplied as input.  cond(RCONDE) is the condition number
!>      of RCONDE, and takes errors in computing RCONDE into account,
!>      so that the resulting quantity should be O(ULP). cond(RCONDE)
!>      is essentially given by norm(A)/RCONDV.
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of sizes of matrices to use. NSIZES must be at !> least zero. If it is zero, no randomly generated matrices !> are tested, but any test matrices read from NIUNIT will be !> tested. !>
[in]	NN	!> NN is INTEGER array, dimension (NSIZES) !> An array containing the sizes to be used for the matrices. !> Zero values will be skipped. The values must be at least !> zero. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. NTYPES must be at least !> zero. If it is zero, no randomly generated test matrices !> are tested, but and test matrices read from NIUNIT will be !> tested. If it is MAXTYP+1 and NSIZES is 1, then an !> additional type, MAXTYP+1 is defined, which is to use !> whatever matrix is in A. This is only useful if !> DOTYPE(1:MAXTYP) is .FALSE. and DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size in NN a !> matrix of that size and of type j will be generated. !> If NTYPES is smaller than the maximum number of types !> defined (PARAMETER MAXTYP), then types NTYPES+1 through !> MAXTYP will not be generated. If NTYPES is larger !> than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES) !> will be ignored. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The random number generator uses a linear !> congruential sequence limited to small integers, and so !> should produce machine independent random numbers. The !> values of ISEED are changed on exit, and can be used in the !> next call to CDRVVX to continue the same random number !> sequence. !>
[in]	THRESH	!> THRESH is REAL !> A test will count as if the , computed as !> described above, exceeds THRESH. Note that the error !> is scaled to be O(1), so THRESH should be a reasonably !> small multiple of 1, e.g., 10 or 100. In particular, !> it should not depend on the precision (single vs. double) !> or the size of the matrix. It must be at least zero. !>
[in]	NIUNIT	!> NIUNIT is INTEGER !> The FORTRAN unit number for reading in the data file of !> problems to solve. !>
[in]	NOUNIT	!> NOUNIT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns INFO not equal to 0.) !>
[out]	A	!> A is COMPLEX array, dimension (LDA, max(NN,12)) !> Used to hold the matrix whose eigenvalues are to be !> computed. On exit, A contains the last matrix actually used. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A, and H. LDA must be at !> least 1 and at least max( NN, 12 ). (12 is the !> dimension of the largest matrix on the precomputed !> input file.) !>
[out]	H	!> H is COMPLEX array, dimension (LDA, max(NN,12)) !> Another copy of the test matrix A, modified by CGEEVX. !>
[out]	W	!> W is COMPLEX array, dimension (max(NN,12)) !> Contains the eigenvalues of A. !>
[out]	W1	!> W1 is COMPLEX array, dimension (max(NN,12)) !> Like W, this array contains the eigenvalues of A, !> but those computed when CGEEVX only computes a partial !> eigendecomposition, i.e. not the eigenvalues and left !> and right eigenvectors. !>
[out]	VL	!> VL is COMPLEX array, dimension (LDVL, max(NN,12)) !> VL holds the computed left eigenvectors. !>
[in]	LDVL	!> LDVL is INTEGER !> Leading dimension of VL. Must be at least max(1,max(NN,12)). !>
[out]	VR	!> VR is COMPLEX array, dimension (LDVR, max(NN,12)) !> VR holds the computed right eigenvectors. !>
[in]	LDVR	!> LDVR is INTEGER !> Leading dimension of VR. Must be at least max(1,max(NN,12)). !>
[out]	LRE	!> LRE is COMPLEX array, dimension (LDLRE, max(NN,12)) !> LRE holds the computed right or left eigenvectors. !>
[in]	LDLRE	!> LDLRE is INTEGER !> Leading dimension of LRE. Must be at least max(1,max(NN,12)) !>
[out]	RCONDV	!> RCONDV is REAL array, dimension (N) !> RCONDV holds the computed reciprocal condition numbers !> for eigenvectors. !>
[out]	RCNDV1	!> RCNDV1 is REAL array, dimension (N) !> RCNDV1 holds more computed reciprocal condition numbers !> for eigenvectors. !>
[in]	RCDVIN	!> RCDVIN is REAL array, dimension (N) !> When COMP = .TRUE. RCDVIN holds the precomputed reciprocal !> condition numbers for eigenvectors to be compared with !> RCONDV. !>
[out]	RCONDE	!> RCONDE is REAL array, dimension (N) !> RCONDE holds the computed reciprocal condition numbers !> for eigenvalues. !>
[out]	RCNDE1	!> RCNDE1 is REAL array, dimension (N) !> RCNDE1 holds more computed reciprocal condition numbers !> for eigenvalues. !>
[in]	RCDEIN	!> RCDEIN is REAL array, dimension (N) !> When COMP = .TRUE. RCDEIN holds the precomputed reciprocal !> condition numbers for eigenvalues to be compared with !> RCONDE. !>
[out]	SCALE	!> SCALE is REAL array, dimension (N) !> Holds information describing balancing of matrix. !>
[out]	SCALE1	!> SCALE1 is REAL array, dimension (N) !> Holds information describing balancing of matrix. !>
[out]	RESULT	!> RESULT is REAL array, dimension (11) !> The values computed by the seven tests described above. !> The values are currently limited to 1/ulp, to avoid !> overflow. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (NWORK) !>
[in]	NWORK	!> NWORK is INTEGER !> The number of entries in WORK. This must be at least !> max(6*12+2*12**2,6*NN(j)+2*NN(j)**2) = !> max( 360 ,6*NN(j)+2*NN(j)**2) for all j. !>
[out]	RWORK	!> RWORK is REAL array, dimension (2*max(NN,12)) !>
[out]	INFO	!> INFO is INTEGER !> If 0, then successful exit. !> If <0, then input parameter -INFO is incorrect. !> If >0, CLATMR, CLATMS, CLATME or CGET23 returned an error !> code, and INFO is its absolute value. !> !>----------------------------------------------------------------------- !> !> Some Local Variables and Parameters: !> ---- ----- --------- --- ---------- !> !> ZERO, ONE Real 0 and 1. !> MAXTYP The number of types defined. !> NMAX Largest value in NN or 12. !> NERRS The number of tests which have exceeded THRESH !> COND, CONDS, !> IMODE Values to be passed to the matrix generators. !> ANORM Norm of A; passed to matrix generators. !> !> OVFL, UNFL Overflow and underflow thresholds. !> ULP, ULPINV Finest relative precision and its inverse. !> RTULP, RTULPI Square roots of the previous 4 values. !> !> The following four arrays decode JTYPE: !> KTYPE(j) The general type (1-10) for type . !> KMODE(j) The MODE value to be passed to the matrix !> generator for type . !> KMAGN(j) The order of magnitude ( O(1), !> O(overflow^(1/2) ), O(underflow^(1/2) ) !> KCONDS(j) Selectw whether CONDS is to be 1 or !> 1/sqrt(ulp). (0 means irrelevant.) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 491 of file cdrvvx.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDLRE, LDVL, LDVR, NIUNIT, NOUNIT,
     $                   NSIZES, NTYPES, NWORK
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), NN( * )
      REAL               RCDEIN( * ), RCDVIN( * ), RCNDE1( * ),
     $                   RCNDV1( * ), RCONDE( * ), RCONDV( * ),
     $                   RESULT( 11 ), RWORK( * ), SCALE( * ),
     $                   SCALE1( * )
      COMPLEX            A( LDA, * ), H( LDA, * ), LRE( LDLRE, * ),
     $                   VL( LDVL, * ), VR( LDVR, * ), W( * ), W1( * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      INTEGER            MAXTYP
      parameter( maxtyp = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN
      CHARACTER          BALANC
      CHARACTER*3        PATH
      INTEGER            I, IBAL, IINFO, IMODE, ISRT, ITYPE, IWK, J,
     $                   JCOL, JSIZE, JTYPE, MTYPES, N, NERRS,
     $                   NFAIL, NMAX, NNWORK, NTEST, NTESTF, NTESTT
      REAL               ANORM, COND, CONDS, OVFL, RTULP, RTULPI, ULP,
     $                   ULPINV, UNFL, WI, WR
*     ..
*     .. Local Arrays ..
      CHARACTER          BAL( 4 )
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), KCONDS( MAXTYP ),
     $                   KMAGN( MAXTYP ), KMODE( MAXTYP ),
     $                   KTYPE( MAXTYP )
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cget23, clatme, clatmr, clatms, claset, slasum,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
      DATA               bal / 'N', 'P', 'S', 'B' /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'VX'
*
*     Check for errors
*
      ntestt = 0
      ntestf = 0
      info = 0
*
*     Important constants
*
      badnn = .false.
*
*     7 is the largest dimension in the input file of precomputed
*     problems
*
      nmax = 7
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LT.1 .OR. lda.LT.nmax ) THEN
         info = -10
      ELSE IF( ldvl.LT.1 .OR. ldvl.LT.nmax ) THEN
         info = -15
      ELSE IF( ldvr.LT.1 .OR. ldvr.LT.nmax ) THEN
         info = -17
      ELSE IF( ldlre.LT.1 .OR. ldlre.LT.nmax ) THEN
         info = -19
      ELSE IF( 6*nmax+2*nmax**2.GT.nwork ) THEN
         info = -30
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CDRVVX', -info )
         RETURN
      END IF
*
*     If nothing to do check on NIUNIT
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   GO TO 160
*
*     More Important constants
*
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      ulp = slamch( 'Precision' )
      ulpinv = one / ulp
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
*
      DO 150 jsize = 1, nsizes
         n = nn( jsize )
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 140 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 140
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   symmetric, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random symmetric
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 90
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 30, 40, 50 )kmagn( jtype )
*
   30       CONTINUE
            anorm = one
            GO TO 60
*
   40       CONTINUE
            anorm = ovfl*ulp
            GO TO 60
*
   50       CONTINUE
            anorm = unfl*ulpinv
            GO TO 60
*
   60       CONTINUE
*
            CALL claset( 'Full', lda, n, czero, czero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices -- Identity & Jordan block
*
*              Zero
*
            IF( itype.EQ.1 ) THEN
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 70 jcol = 1, n
                  a( jcol, jcol ) = anorm
   70          CONTINUE
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = anorm
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = one
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL clatms( n, n, 'S', iseed, 'H', rwork, imode, cond,
     $                      anorm, 0, 0, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL clatms( n, n, 'S', iseed, 'H', rwork, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               CALL clatme( n, 'D', iseed, work, imode, cond, cone,
     $                      'T', 'T', 'T', rwork, 4, conds, n, n, anorm,
     $                      a, lda, work( 2*n+1 ), iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'S', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, idumma, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'H', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, idumma, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, idumma, iinfo )
               IF( n.GE.4 ) THEN
                  CALL claset( 'Full', 2, n, czero, czero, a, lda )
                  CALL claset( 'Full', n-3, 1, czero, czero, a( 3, 1 ),
     $                         lda )
                  CALL claset( 'Full', n-3, 2, czero, czero,
     $                         a( 3, n-1 ), lda )
                  CALL claset( 'Full', 1, n, czero, czero, a( n, 1 ),
     $                         lda )
               END IF
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL clatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, idumma, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9992 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
   90       CONTINUE
*
*           Test for minimal and generous workspace
*
            DO 130 iwk = 1, 3
               IF( iwk.EQ.1 ) THEN
                  nnwork = 2*n
               ELSE IF( iwk.EQ.2 ) THEN
                  nnwork = 2*n + n**2
               ELSE
                  nnwork = 6*n + 2*n**2
               END IF
               nnwork = max( nnwork, 1 )
*
*              Test for all balancing options
*
               DO 120 ibal = 1, 4
                  balanc = bal( ibal )
*
*                 Perform tests
*
                  CALL cget23( .false., 0, balanc, jtype, thresh,
     $                         ioldsd, nounit, n, a, lda, h, w, w1, vl,
     $                         ldvl, vr, ldvr, lre, ldlre, rcondv,
     $                         rcndv1, rcdvin, rconde, rcnde1, rcdein,
     $                         scale, scale1, result, work, nnwork,
     $                         rwork, info )
*
*                 Check for RESULT(j) > THRESH
*
                  ntest = 0
                  nfail = 0
                  DO 100 j = 1, 9
                     IF( result( j ).GE.zero )
     $                  ntest = ntest + 1
                     IF( result( j ).GE.thresh )
     $                  nfail = nfail + 1
  100             CONTINUE
*
                  IF( nfail.GT.0 )
     $               ntestf = ntestf + 1
                  IF( ntestf.EQ.1 ) THEN
                     WRITE( nounit, fmt = 9999 )path
                     WRITE( nounit, fmt = 9998 )
                     WRITE( nounit, fmt = 9997 )
                     WRITE( nounit, fmt = 9996 )
                     WRITE( nounit, fmt = 9995 )thresh
                     ntestf = 2
                  END IF
*
                  DO 110 j = 1, 9
                     IF( result( j ).GE.thresh ) THEN
                        WRITE( nounit, fmt = 9994 )balanc, n, iwk,
     $                     ioldsd, jtype, j, result( j )
                     END IF
  110             CONTINUE
*
                  nerrs = nerrs + nfail
                  ntestt = ntestt + ntest
*
  120          CONTINUE
  130       CONTINUE
  140    CONTINUE
  150 CONTINUE
*
  160 CONTINUE
*
*     Read in data from file to check accuracy of condition estimation.
*     Assume input eigenvalues are sorted lexicographically (increasing
*     by real part, then decreasing by imaginary part)
*
      jtype = 0
  170 CONTINUE
      READ( niunit, fmt = *, END = 220 )N, isrt
*
*     Read input data until N=0
*
      IF( n.EQ.0 )
     $   GO TO 220
      jtype = jtype + 1
      iseed( 1 ) = jtype
      DO 180 i = 1, n
         READ( niunit, fmt = * )( a( i, j ), j = 1, n )
  180 CONTINUE
      DO 190 i = 1, n
         READ( niunit, fmt = * )wr, wi, rcdein( i ), rcdvin( i )
         w1( i ) = cmplx( wr, wi )
  190 CONTINUE
      CALL cget23( .true., isrt, 'N', 22, thresh, iseed, nounit, n, a,
     $             lda, h, w, w1, vl, ldvl, vr, ldvr, lre, ldlre,
     $             rcondv, rcndv1, rcdvin, rconde, rcnde1, rcdein,
     $             scale, scale1, result, work, 6*n+2*n**2, rwork,
     $             info )
*
*     Check for RESULT(j) > THRESH
*
      ntest = 0
      nfail = 0
      DO 200 j = 1, 11
         IF( result( j ).GE.zero )
     $      ntest = ntest + 1
         IF( result( j ).GE.thresh )
     $      nfail = nfail + 1
  200 CONTINUE
*
      IF( nfail.GT.0 )
     $   ntestf = ntestf + 1
      IF( ntestf.EQ.1 ) THEN
         WRITE( nounit, fmt = 9999 )path
         WRITE( nounit, fmt = 9998 )
         WRITE( nounit, fmt = 9997 )
         WRITE( nounit, fmt = 9996 )
         WRITE( nounit, fmt = 9995 )thresh
         ntestf = 2
      END IF
*
      DO 210 j = 1, 11
         IF( result( j ).GE.thresh ) THEN
            WRITE( nounit, fmt = 9993 )n, jtype, j, result( j )
         END IF
  210 CONTINUE
*
      nerrs = nerrs + nfail
      ntestt = ntestt + ntest
      GO TO 170
  220 CONTINUE
*
*     Summary
*
      CALL slasum( path, nounit, nerrs, ntestt )
*
 9999 FORMAT( / 1x, a3, ' -- Complex Eigenvalue-Eigenvector ',
     $      'Decomposition Expert Driver',
     $      / ' Matrix types (see CDRVVX for details): ' )
*
 9998 FORMAT( / ' Special Matrices:', / '  1=Zero matrix.             ',
     $      '           ', '  5=Diagonal: geometr. spaced entries.',
     $      / '  2=Identity matrix.                    ', '  6=Diagona',
     $      'l: clustered entries.', / '  3=Transposed Jordan block.  ',
     $      '          ', '  7=Diagonal: large, evenly spaced.', / '  ',
     $      '4=Diagonal: evenly spaced entries.    ', '  8=Diagonal: s',
     $      'mall, evenly spaced.' )
 9997 FORMAT( ' Dense, Non-Symmetric Matrices:', / '  9=Well-cond., ev',
     $      'enly spaced eigenvals.', ' 14=Ill-cond., geomet. spaced e',
     $      'igenals.', / ' 10=Well-cond., geom. spaced eigenvals. ',
     $      ' 15=Ill-conditioned, clustered e.vals.', / ' 11=Well-cond',
     $      'itioned, clustered e.vals. ', ' 16=Ill-cond., random comp',
     $      'lex ', / ' 12=Well-cond., random complex ', '         ',
     $      ' 17=Ill-cond., large rand. complx ', / ' 13=Ill-condi',
     $      'tioned, evenly spaced.     ', ' 18=Ill-cond., small rand.',
     $      ' complx ' )
 9996 FORMAT( ' 19=Matrix with random O(1) entries.    ', ' 21=Matrix ',
     $      'with small random entries.', / ' 20=Matrix with large ran',
     $      'dom entries.   ', ' 22=Matrix read from input file', / )
 9995 FORMAT( ' Tests performed with test threshold =', f8.2,
     $      / / ' 1 = | A VR - VR W | / ( n |A| ulp ) ',
     $      / ' 2 = | transpose(A) VL - VL W | / ( n |A| ulp ) ',
     $      / ' 3 = | |VR(i)| - 1 | / ulp ',
     $      / ' 4 = | |VL(i)| - 1 | / ulp ',
     $      / ' 5 = 0 if W same no matter if VR or VL computed,',
     $      ' 1/ulp otherwise', /
     $      ' 6 = 0 if VR same no matter what else computed,',
     $      '  1/ulp otherwise', /
     $      ' 7 = 0 if VL same no matter what else computed,',
     $      '  1/ulp otherwise', /
     $      ' 8 = 0 if RCONDV same no matter what else computed,',
     $      '  1/ulp otherwise', /
     $      ' 9 = 0 if SCALE, ILO, IHI, ABNRM same no matter what else',
     $      ' computed,  1/ulp otherwise',
     $      / ' 10 = | RCONDV - RCONDV(precomputed) | / cond(RCONDV),',
     $      / ' 11 = | RCONDE - RCONDE(precomputed) | / cond(RCONDE),' )
 9994 FORMAT( ' BALANC=''', a1, ''',N=', i4, ',IWK=', i1, ', seed=',
     $      4( i4, ',' ), ' type ', i2, ', test(', i2, ')=', g10.3 )
 9993 FORMAT( ' N=', i5, ', input example =', i3, ',  test(', i2, ')=',
     $      g10.3 )
 9992 FORMAT( ' CDRVVX: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
      RETURN
*
*     End of CDRVVX
*

Here is the call graph for this function:

Here is the caller graph for this function: