cget23()

subroutine cget23	(	logical	comp,
		integer	isrt,
		character	balanc,
		integer	jtype,
		real	thresh,
		integer, dimension( 4 )	iseed,
		integer	nounit,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( lda, * )	h,
		complex, dimension( * )	w,
		complex, dimension( * )	w1,
		complex, dimension( ldvl, * )	vl,
		integer	ldvl,
		complex, dimension( ldvr, * )	vr,
		integer	ldvr,
		complex, dimension( ldlre, * )	lre,
		integer	ldlre,
		real, dimension( * )	rcondv,
		real, dimension( * )	rcndv1,
		real, dimension( * )	rcdvin,
		real, dimension( * )	rconde,
		real, dimension( * )	rcnde1,
		real, dimension( * )	rcdein,
		real, dimension( * )	scale,
		real, dimension( * )	scale1,
		real, dimension( 11 )	result,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	info )

CGET23

Purpose:

!>
!>    CGET23  checks the nonsymmetric eigenvalue problem driver CGEEVX.
!>    If COMP = .FALSE., the first 8 of the following tests will be
!>    performed on the input matrix A, and also test 9 if LWORK is
!>    sufficiently large.
!>    if COMP is .TRUE. all 11 tests will be performed.
!>
!>    (1)     | A * VR - VR * W | / ( n |A| ulp )
!>
!>      Here VR is the matrix of unit right eigenvectors.
!>      W is a diagonal matrix with diagonal entries W(j).
!>
!>    (2)     | A**H * VL - VL * W**H | / ( n |A| ulp )
!>
!>      Here VL is the matrix of unit left eigenvectors, A**H is the
!>      conjugate transpose of A, and W is as above.
!>
!>    (3)     | |VR(i)| - 1 | / ulp and largest component real
!>
!>      VR(i) denotes the i-th column of VR.
!>
!>    (4)     | |VL(i)| - 1 | / ulp and largest component real
!>
!>      VL(i) denotes the i-th column of VL.
!>
!>    (5)     0 if W(full) = W(partial), 1/ulp otherwise
!>
!>      W(full) denotes the eigenvalues computed when VR, VL, RCONDV
!>      and RCONDE are also computed, and W(partial) denotes the
!>      eigenvalues computed when only some of VR, VL, RCONDV, and
!>      RCONDE are computed.
!>
!>    (6)     0 if VR(full) = VR(partial), 1/ulp otherwise
!>
!>      VR(full) denotes the right eigenvectors computed when VL, RCONDV
!>      and RCONDE are computed, and VR(partial) denotes the result
!>      when only some of VL and RCONDV are computed.
!>
!>    (7)     0 if VL(full) = VL(partial), 1/ulp otherwise
!>
!>      VL(full) denotes the left eigenvectors computed when VR, RCONDV
!>      and RCONDE are computed, and VL(partial) denotes the result
!>      when only some of VR and RCONDV are computed.
!>
!>    (8)     0 if SCALE, ILO, IHI, ABNRM (full) =
!>                 SCALE, ILO, IHI, ABNRM (partial)
!>            1/ulp otherwise
!>
!>      SCALE, ILO, IHI and ABNRM describe how the matrix is balanced.
!>      (full) is when VR, VL, RCONDE and RCONDV are also computed, and
!>      (partial) is when some are not computed.
!>
!>    (9)     0 if RCONDV(full) = RCONDV(partial), 1/ulp otherwise
!>
!>      RCONDV(full) denotes the reciprocal condition numbers of the
!>      right eigenvectors computed when VR, VL and RCONDE are also
!>      computed. RCONDV(partial) denotes the reciprocal condition
!>      numbers when only some of VR, VL and RCONDE are computed.
!>
!>   (10)     |RCONDV - RCDVIN| / cond(RCONDV)
!>
!>      RCONDV is the reciprocal right eigenvector condition number
!>      computed by CGEEVX and RCDVIN (the precomputed true value)
!>      is supplied as input. cond(RCONDV) is the condition number of
!>      RCONDV, and takes errors in computing RCONDV into account, so
!>      that the resulting quantity should be O(ULP). cond(RCONDV) is
!>      essentially given by norm(A)/RCONDE.
!>
!>   (11)     |RCONDE - RCDEIN| / cond(RCONDE)
!>
!>      RCONDE is the reciprocal eigenvalue condition number
!>      computed by CGEEVX and RCDEIN (the precomputed true value)
!>      is supplied as input.  cond(RCONDE) is the condition number
!>      of RCONDE, and takes errors in computing RCONDE into account,
!>      so that the resulting quantity should be O(ULP). cond(RCONDE)
!>      is essentially given by norm(A)/RCONDV.
!> 

Parameters

[in]	COMP	!> COMP is LOGICAL !> COMP describes which input tests to perform: !> = .FALSE. if the computed condition numbers are not to !> be tested against RCDVIN and RCDEIN !> = .TRUE. if they are to be compared !>
[in]	ISRT	!> ISRT is INTEGER !> If COMP = .TRUE., ISRT indicates in how the eigenvalues !> corresponding to values in RCDVIN and RCDEIN are ordered: !> = 0 means the eigenvalues are sorted by !> increasing real part !> = 1 means the eigenvalues are sorted by !> increasing imaginary part !> If COMP = .FALSE., ISRT is not referenced. !>
[in]	BALANC	!> BALANC is CHARACTER !> Describes the balancing option to be tested. !> = 'N' for no permuting or diagonal scaling !> = 'P' for permuting but no diagonal scaling !> = 'S' for no permuting but diagonal scaling !> = 'B' for permuting and diagonal scaling !>
[in]	JTYPE	!> JTYPE is INTEGER !> Type of input matrix. Used to label output if error occurs. !>
[in]	THRESH	!> THRESH is REAL !> A test will count as if the , computed as !> described above, exceeds THRESH. Note that the error !> is scaled to be O(1), so THRESH should be a reasonably !> small multiple of 1, e.g., 10 or 100. In particular, !> it should not depend on the precision (single vs. double) !> or the size of the matrix. It must be at least zero. !>
[in]	ISEED	!> ISEED is INTEGER array, dimension (4) !> If COMP = .FALSE., the random number generator seed !> used to produce matrix. !> If COMP = .TRUE., ISEED(1) = the number of the example. !> Used to label output if error occurs. !>
[in]	NOUNIT	!> NOUNIT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns INFO not equal to 0.) !>
[in]	N	!> N is INTEGER !> The dimension of A. N must be at least 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> Used to hold the matrix whose eigenvalues are to be !> computed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A, and H. LDA must be at !> least 1 and at least N. !>
[out]	H	!> H is COMPLEX array, dimension (LDA,N) !> Another copy of the test matrix A, modified by CGEEVX. !>
[out]	W	!> W is COMPLEX array, dimension (N) !> Contains the eigenvalues of A. !>
[out]	W1	!> W1 is COMPLEX array, dimension (N) !> Like W, this array contains the eigenvalues of A, !> but those computed when CGEEVX only computes a partial !> eigendecomposition, i.e. not the eigenvalues and left !> and right eigenvectors. !>
[out]	VL	!> VL is COMPLEX array, dimension (LDVL,N) !> VL holds the computed left eigenvectors. !>
[in]	LDVL	!> LDVL is INTEGER !> Leading dimension of VL. Must be at least max(1,N). !>
[out]	VR	!> VR is COMPLEX array, dimension (LDVR,N) !> VR holds the computed right eigenvectors. !>
[in]	LDVR	!> LDVR is INTEGER !> Leading dimension of VR. Must be at least max(1,N). !>
[out]	LRE	!> LRE is COMPLEX array, dimension (LDLRE,N) !> LRE holds the computed right or left eigenvectors. !>
[in]	LDLRE	!> LDLRE is INTEGER !> Leading dimension of LRE. Must be at least max(1,N). !>
[out]	RCONDV	!> RCONDV is REAL array, dimension (N) !> RCONDV holds the computed reciprocal condition numbers !> for eigenvectors. !>
[out]	RCNDV1	!> RCNDV1 is REAL array, dimension (N) !> RCNDV1 holds more computed reciprocal condition numbers !> for eigenvectors. !>
[in]	RCDVIN	!> RCDVIN is REAL array, dimension (N) !> When COMP = .TRUE. RCDVIN holds the precomputed reciprocal !> condition numbers for eigenvectors to be compared with !> RCONDV. !>
[out]	RCONDE	!> RCONDE is REAL array, dimension (N) !> RCONDE holds the computed reciprocal condition numbers !> for eigenvalues. !>
[out]	RCNDE1	!> RCNDE1 is REAL array, dimension (N) !> RCNDE1 holds more computed reciprocal condition numbers !> for eigenvalues. !>
[in]	RCDEIN	!> RCDEIN is REAL array, dimension (N) !> When COMP = .TRUE. RCDEIN holds the precomputed reciprocal !> condition numbers for eigenvalues to be compared with !> RCONDE. !>
[out]	SCALE	!> SCALE is REAL array, dimension (N) !> Holds information describing balancing of matrix. !>
[out]	SCALE1	!> SCALE1 is REAL array, dimension (N) !> Holds information describing balancing of matrix. !>
[out]	RESULT	!> RESULT is REAL array, dimension (11) !> The values computed by the 11 tests described above. !> The values are currently limited to 1/ulp, to avoid !> overflow. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The number of entries in WORK. This must be at least !> 2*N, and 2*N+N**2 if tests 9, 10 or 11 are to be performed. !>
[out]	RWORK	!> RWORK is REAL array, dimension (2*N) !>
[out]	INFO	!> INFO is INTEGER !> If 0, successful exit. !> If <0, input parameter -INFO had an incorrect value. !> If >0, CGEEVX returned an error code, the absolute !> value of which is returned. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 363 of file cget23.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            COMP
      CHARACTER          BALANC
      INTEGER            INFO, ISRT, JTYPE, LDA, LDLRE, LDVL, LDVR,
     $                   LWORK, N, NOUNIT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               RCDEIN( * ), RCDVIN( * ), RCNDE1( * ),
     $                   RCNDV1( * ), RCONDE( * ), RCONDV( * ),
     $                   RESULT( 11 ), RWORK( * ), SCALE( * ),
     $                   SCALE1( * )
      COMPLEX            A( LDA, * ), H( LDA, * ), LRE( LDLRE, * ),
     $                   VL( LDVL, * ), VR( LDVR, * ), W( * ), W1( * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0 )
      REAL               EPSIN
      parameter( epsin = 5.9605e-8 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BALOK, NOBAL
      CHARACTER          SENSE
      INTEGER            I, IHI, IHI1, IINFO, ILO, ILO1, ISENS, ISENSM,
     $                   J, JJ, KMIN
      REAL               ABNRM, ABNRM1, EPS, SMLNUM, TNRM, TOL, TOLIN,
     $                   ULP, ULPINV, V, VMAX, VMX, VRICMP, VRIMIN,
     $                   VRMX, VTST
      COMPLEX            CTMP
*     ..
*     .. Local Arrays ..
      CHARACTER          SENS( 2 )
      REAL               RES( 2 )
      COMPLEX            CDUM( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SCNRM2, SLAMCH
      EXTERNAL           lsame, scnrm2, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgeevx, cget22, clacpy, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, min, real
*     ..
*     .. Data statements ..
      DATA               sens / 'N', 'V' /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      nobal = lsame( balanc, 'N' )
      balok = nobal .OR. lsame( balanc, 'P' ) .OR.
     $        lsame( balanc, 'S' ) .OR. lsame( balanc, 'B' )
      info = 0
      IF( isrt.NE.0 .AND. isrt.NE.1 ) THEN
         info = -2
      ELSE IF( .NOT.balok ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -5
      ELSE IF( nounit.LE.0 ) THEN
         info = -7
      ELSE IF( n.LT.0 ) THEN
         info = -8
      ELSE IF( lda.LT.1 .OR. lda.LT.n ) THEN
         info = -10
      ELSE IF( ldvl.LT.1 .OR. ldvl.LT.n ) THEN
         info = -15
      ELSE IF( ldvr.LT.1 .OR. ldvr.LT.n ) THEN
         info = -17
      ELSE IF( ldlre.LT.1 .OR. ldlre.LT.n ) THEN
         info = -19
      ELSE IF( lwork.LT.2*n .OR. ( comp .AND. lwork.LT.2*n+n*n ) ) THEN
         info = -30
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGET23', -info )
         RETURN
      END IF
*
*     Quick return if nothing to do
*
      DO 10 i = 1, 11
         result( i ) = -one
   10 CONTINUE
*
      IF( n.EQ.0 )
     $   RETURN
*
*     More Important constants
*
      ulp = slamch( 'Precision' )
      smlnum = slamch( 'S' )
      ulpinv = one / ulp
*
*     Compute eigenvalues and eigenvectors, and test them
*
      IF( lwork.GE.2*n+n*n ) THEN
         sense = 'B'
         isensm = 2
      ELSE
         sense = 'E'
         isensm = 1
      END IF
      CALL clacpy( 'F', n, n, a, lda, h, lda )
      CALL cgeevx( balanc, 'V', 'V', sense, n, h, lda, w, vl, ldvl, vr,
     $             ldvr, ilo, ihi, scale, abnrm, rconde, rcondv, work,
     $             lwork, rwork, iinfo )
      IF( iinfo.NE.0 ) THEN
         result( 1 ) = ulpinv
         IF( jtype.NE.22 ) THEN
            WRITE( nounit, fmt = 9998 )'CGEEVX1', iinfo, n, jtype,
     $         balanc, iseed
         ELSE
            WRITE( nounit, fmt = 9999 )'CGEEVX1', iinfo, n, iseed( 1 )
         END IF
         info = abs( iinfo )
         RETURN
      END IF
*
*     Do Test (1)
*
      CALL cget22( 'N', 'N', 'N', n, a, lda, vr, ldvr, w, work, rwork,
     $             res )
      result( 1 ) = res( 1 )
*
*     Do Test (2)
*
      CALL cget22( 'C', 'N', 'C', n, a, lda, vl, ldvl, w, work, rwork,
     $             res )
      result( 2 ) = res( 1 )
*
*     Do Test (3)
*
      DO 30 j = 1, n
         tnrm = scnrm2( n, vr( 1, j ), 1 )
         result( 3 ) = max( result( 3 ),
     $                 min( ulpinv, abs( tnrm-one ) / ulp ) )
         vmx = zero
         vrmx = zero
         DO 20 jj = 1, n
            vtst = abs( vr( jj, j ) )
            IF( vtst.GT.vmx )
     $         vmx = vtst
            IF( aimag( vr( jj, j ) ).EQ.zero .AND.
     $          abs( real( vr( jj, j ) ) ).GT.vrmx )
     $          vrmx = abs( real( vr( jj, j ) ) )
   20    CONTINUE
         IF( vrmx / vmx.LT.one-two*ulp )
     $      result( 3 ) = ulpinv
   30 CONTINUE
*
*     Do Test (4)
*
      DO 50 j = 1, n
         tnrm = scnrm2( n, vl( 1, j ), 1 )
         result( 4 ) = max( result( 4 ),
     $                 min( ulpinv, abs( tnrm-one ) / ulp ) )
         vmx = zero
         vrmx = zero
         DO 40 jj = 1, n
            vtst = abs( vl( jj, j ) )
            IF( vtst.GT.vmx )
     $         vmx = vtst
            IF( aimag( vl( jj, j ) ).EQ.zero .AND.
     $          abs( real( vl( jj, j ) ) ).GT.vrmx )
     $          vrmx = abs( real( vl( jj, j ) ) )
   40    CONTINUE
         IF( vrmx / vmx.LT.one-two*ulp )
     $      result( 4 ) = ulpinv
   50 CONTINUE
*
*     Test for all options of computing condition numbers
*
      DO 200 isens = 1, isensm
*
         sense = sens( isens )
*
*        Compute eigenvalues only, and test them
*
         CALL clacpy( 'F', n, n, a, lda, h, lda )
         CALL cgeevx( balanc, 'N', 'N', sense, n, h, lda, w1, cdum, 1,
     $                cdum, 1, ilo1, ihi1, scale1, abnrm1, rcnde1,
     $                rcndv1, work, lwork, rwork, iinfo )
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ulpinv
            IF( jtype.NE.22 ) THEN
               WRITE( nounit, fmt = 9998 )'CGEEVX2', iinfo, n, jtype,
     $            balanc, iseed
            ELSE
               WRITE( nounit, fmt = 9999 )'CGEEVX2', iinfo, n,
     $            iseed( 1 )
            END IF
            info = abs( iinfo )
            GO TO 190
         END IF
*
*        Do Test (5)
*
         DO 60 j = 1, n
            IF( w( j ).NE.w1( j ) )
     $         result( 5 ) = ulpinv
   60    CONTINUE
*
*        Do Test (8)
*
         IF( .NOT.nobal ) THEN
            DO 70 j = 1, n
               IF( scale( j ).NE.scale1( j ) )
     $            result( 8 ) = ulpinv
   70       CONTINUE
            IF( ilo.NE.ilo1 )
     $         result( 8 ) = ulpinv
            IF( ihi.NE.ihi1 )
     $         result( 8 ) = ulpinv
            IF( abnrm.NE.abnrm1 )
     $         result( 8 ) = ulpinv
         END IF
*
*        Do Test (9)
*
         IF( isens.EQ.2 .AND. n.GT.1 ) THEN
            DO 80 j = 1, n
               IF( rcondv( j ).NE.rcndv1( j ) )
     $            result( 9 ) = ulpinv
   80       CONTINUE
         END IF
*
*        Compute eigenvalues and right eigenvectors, and test them
*
         CALL clacpy( 'F', n, n, a, lda, h, lda )
         CALL cgeevx( balanc, 'N', 'V', sense, n, h, lda, w1, cdum, 1,
     $                lre, ldlre, ilo1, ihi1, scale1, abnrm1, rcnde1,
     $                rcndv1, work, lwork, rwork, iinfo )
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ulpinv
            IF( jtype.NE.22 ) THEN
               WRITE( nounit, fmt = 9998 )'CGEEVX3', iinfo, n, jtype,
     $            balanc, iseed
            ELSE
               WRITE( nounit, fmt = 9999 )'CGEEVX3', iinfo, n,
     $            iseed( 1 )
            END IF
            info = abs( iinfo )
            GO TO 190
         END IF
*
*        Do Test (5) again
*
         DO 90 j = 1, n
            IF( w( j ).NE.w1( j ) )
     $         result( 5 ) = ulpinv
   90    CONTINUE
*
*        Do Test (6)
*
         DO 110 j = 1, n
            DO 100 jj = 1, n
               IF( vr( j, jj ).NE.lre( j, jj ) )
     $            result( 6 ) = ulpinv
  100       CONTINUE
  110    CONTINUE
*
*        Do Test (8) again
*
         IF( .NOT.nobal ) THEN
            DO 120 j = 1, n
               IF( scale( j ).NE.scale1( j ) )
     $            result( 8 ) = ulpinv
  120       CONTINUE
            IF( ilo.NE.ilo1 )
     $         result( 8 ) = ulpinv
            IF( ihi.NE.ihi1 )
     $         result( 8 ) = ulpinv
            IF( abnrm.NE.abnrm1 )
     $         result( 8 ) = ulpinv
         END IF
*
*        Do Test (9) again
*
         IF( isens.EQ.2 .AND. n.GT.1 ) THEN
            DO 130 j = 1, n
               IF( rcondv( j ).NE.rcndv1( j ) )
     $            result( 9 ) = ulpinv
  130       CONTINUE
         END IF
*
*        Compute eigenvalues and left eigenvectors, and test them
*
         CALL clacpy( 'F', n, n, a, lda, h, lda )
         CALL cgeevx( balanc, 'V', 'N', sense, n, h, lda, w1, lre,
     $                ldlre, cdum, 1, ilo1, ihi1, scale1, abnrm1,
     $                rcnde1, rcndv1, work, lwork, rwork, iinfo )
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ulpinv
            IF( jtype.NE.22 ) THEN
               WRITE( nounit, fmt = 9998 )'CGEEVX4', iinfo, n, jtype,
     $            balanc, iseed
            ELSE
               WRITE( nounit, fmt = 9999 )'CGEEVX4', iinfo, n,
     $            iseed( 1 )
            END IF
            info = abs( iinfo )
            GO TO 190
         END IF
*
*        Do Test (5) again
*
         DO 140 j = 1, n
            IF( w( j ).NE.w1( j ) )
     $         result( 5 ) = ulpinv
  140    CONTINUE
*
*        Do Test (7)
*
         DO 160 j = 1, n
            DO 150 jj = 1, n
               IF( vl( j, jj ).NE.lre( j, jj ) )
     $            result( 7 ) = ulpinv
  150       CONTINUE
  160    CONTINUE
*
*        Do Test (8) again
*
         IF( .NOT.nobal ) THEN
            DO 170 j = 1, n
               IF( scale( j ).NE.scale1( j ) )
     $            result( 8 ) = ulpinv
  170       CONTINUE
            IF( ilo.NE.ilo1 )
     $         result( 8 ) = ulpinv
            IF( ihi.NE.ihi1 )
     $         result( 8 ) = ulpinv
            IF( abnrm.NE.abnrm1 )
     $         result( 8 ) = ulpinv
         END IF
*
*        Do Test (9) again
*
         IF( isens.EQ.2 .AND. n.GT.1 ) THEN
            DO 180 j = 1, n
               IF( rcondv( j ).NE.rcndv1( j ) )
     $            result( 9 ) = ulpinv
  180       CONTINUE
         END IF
*
  190    CONTINUE
*
  200 CONTINUE
*
*     If COMP, compare condition numbers to precomputed ones
*
      IF( comp ) THEN
         CALL clacpy( 'F', n, n, a, lda, h, lda )
         CALL cgeevx( 'N', 'V', 'V', 'B', n, h, lda, w, vl, ldvl, vr,
     $                ldvr, ilo, ihi, scale, abnrm, rconde, rcondv,
     $                work, lwork, rwork, iinfo )
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ulpinv
            WRITE( nounit, fmt = 9999 )'CGEEVX5', iinfo, n, iseed( 1 )
            info = abs( iinfo )
            GO TO 250
         END IF
*
*        Sort eigenvalues and condition numbers lexicographically
*        to compare with inputs
*
         DO 220 i = 1, n - 1
            kmin = i
            IF( isrt.EQ.0 ) THEN
               vrimin = real( w( i ) )
            ELSE
               vrimin = aimag( w( i ) )
            END IF
            DO 210 j = i + 1, n
               IF( isrt.EQ.0 ) THEN
                  vricmp = real( w( j ) )
               ELSE
                  vricmp = aimag( w( j ) )
               END IF
               IF( vricmp.LT.vrimin ) THEN
                  kmin = j
                  vrimin = vricmp
               END IF
  210       CONTINUE
            ctmp = w( kmin )
            w( kmin ) = w( i )
            w( i ) = ctmp
            vrimin = rconde( kmin )
            rconde( kmin ) = rconde( i )
            rconde( i ) = vrimin
            vrimin = rcondv( kmin )
            rcondv( kmin ) = rcondv( i )
            rcondv( i ) = vrimin
  220    CONTINUE
*
*        Compare condition numbers for eigenvectors
*        taking their condition numbers into account
*
         result( 10 ) = zero
         eps = max( epsin, ulp )
         v = max( real( n )*eps*abnrm, smlnum )
         IF( abnrm.EQ.zero )
     $      v = one
         DO 230 i = 1, n
            IF( v.GT.rcondv( i )*rconde( i ) ) THEN
               tol = rcondv( i )
            ELSE
               tol = v / rconde( i )
            END IF
            IF( v.GT.rcdvin( i )*rcdein( i ) ) THEN
               tolin = rcdvin( i )
            ELSE
               tolin = v / rcdein( i )
            END IF
            tol = max( tol, smlnum / eps )
            tolin = max( tolin, smlnum / eps )
            IF( eps*( rcdvin( i )-tolin ).GT.rcondv( i )+tol ) THEN
               vmax = one / eps
            ELSE IF( rcdvin( i )-tolin.GT.rcondv( i )+tol ) THEN
               vmax = ( rcdvin( i )-tolin ) / ( rcondv( i )+tol )
            ELSE IF( rcdvin( i )+tolin.LT.eps*( rcondv( i )-tol ) ) THEN
               vmax = one / eps
            ELSE IF( rcdvin( i )+tolin.LT.rcondv( i )-tol ) THEN
               vmax = ( rcondv( i )-tol ) / ( rcdvin( i )+tolin )
            ELSE
               vmax = one
            END IF
            result( 10 ) = max( result( 10 ), vmax )
  230    CONTINUE
*
*        Compare condition numbers for eigenvalues
*        taking their condition numbers into account
*
         result( 11 ) = zero
         DO 240 i = 1, n
            IF( v.GT.rcondv( i ) ) THEN
               tol = one
            ELSE
               tol = v / rcondv( i )
            END IF
            IF( v.GT.rcdvin( i ) ) THEN
               tolin = one
            ELSE
               tolin = v / rcdvin( i )
            END IF
            tol = max( tol, smlnum / eps )
            tolin = max( tolin, smlnum / eps )
            IF( eps*( rcdein( i )-tolin ).GT.rconde( i )+tol ) THEN
               vmax = one / eps
            ELSE IF( rcdein( i )-tolin.GT.rconde( i )+tol ) THEN
               vmax = ( rcdein( i )-tolin ) / ( rconde( i )+tol )
            ELSE IF( rcdein( i )+tolin.LT.eps*( rconde( i )-tol ) ) THEN
               vmax = one / eps
            ELSE IF( rcdein( i )+tolin.LT.rconde( i )-tol ) THEN
               vmax = ( rconde( i )-tol ) / ( rcdein( i )+tolin )
            ELSE
               vmax = one
            END IF
            result( 11 ) = max( result( 11 ), vmax )
  240    CONTINUE
  250    CONTINUE
*
      END IF
*
 9999 FORMAT( ' CGET23: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', INPUT EXAMPLE NUMBER = ', i4 )
 9998 FORMAT( ' CGET23: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', BALANC = ', a, ', ISEED=(',
     $      3( i5, ',' ), i5, ')' )
*
      RETURN
*
*     End of CGET23
*

Here is the call graph for this function:

Here is the caller graph for this function: