zchkrq()

subroutine zchkrq	(	logical, dimension( * )	dotype,
		integer	nm,
		integer, dimension( * )	mval,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer, dimension( * )	nxval,
		integer	nrhs,
		double precision	thresh,
		logical	tsterr,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	af,
		complex*16, dimension( * )	aq,
		complex*16, dimension( * )	ar,
		complex*16, dimension( * )	ac,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout
	)

ZCHKRQ

Purpose:

 ZCHKRQ tests ZGERQF, ZUNGRQ and ZUNMRQ.

Parameters

[in]	DOTYPE	DOTYPE is LOGICAL array, dimension (NTYPES) The matrix types to be used for testing. Matrices of type j (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
[in]	NM	NM is INTEGER The number of values of M contained in the vector MVAL.
[in]	MVAL	MVAL is INTEGER array, dimension (NM) The values of the matrix row dimension M.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix column dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB and NX contained in the vectors NBVAL and NXVAL. The blocking parameters are used in pairs (NB,NX).
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NXVAL	NXVAL is INTEGER array, dimension (NNB) The values of the crossover point NX.
[in]	NRHS	NRHS is INTEGER The number of right hand side vectors to be generated for each linear system.
[in]	THRESH	THRESH is DOUBLE PRECISION The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for M or N, used in dimensioning the work arrays.
[out]	A	A is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AF	AF is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AQ	AQ is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AR	AR is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AC	AC is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	B	B is COMPLEX*16 array, dimension (NMAX*NRHS)
[out]	X	X is COMPLEX*16 array, dimension (NMAX*NRHS)
[out]	XACT	XACT is COMPLEX*16 array, dimension (NMAX*NRHS)
[out]	TAU	TAU is COMPLEX*16 array, dimension (NMAX)
[out]	WORK	WORK is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (NMAX)
[out]	IWORK	IWORK is INTEGER array, dimension (NMAX)
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 198 of file zchkrq.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NMAX, NN, NNB, NOUT, NRHS
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
     $                   NXVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AC( * ), AF( * ), AQ( * ), AR( * ),
     $                   B( * ), TAU( * ), WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTESTS
      parameter( ntests = 7 )
      INTEGER            NTYPES
      parameter( ntypes = 8 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IK, IM, IMAT, IN, INB, INFO, K, KL, KU, LDA,
     $                   LWORK, M, MINMN, MODE, N, NB, NERRS, NFAIL, NK,
     $                   NRUN, NT, NX
      DOUBLE PRECISION   ANORM, CNDNUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 ), KVAL( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, xlaenv, zerrrq, zgerqs,
     $                   zget02, zlacpy, zlarhs, zlatb4, zlatms, zrqt01,
     $                   zrqt02, zrqt03
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'RQ'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrrq( path, nout )
      infot = 0
      CALL xlaenv( 2, 2 )
*
      lda = nmax
      lwork = nmax*max( nmax, nrhs )
*
*     Do for each value of M in MVAL.
*
      DO 70 im = 1, nm
         m = mval( im )
*
*        Do for each value of N in NVAL.
*
         DO 60 in = 1, nn
            n = nval( in )
            minmn = min( m, n )
            DO 50 imat = 1, ntypes
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 50
*
*              Set up parameters with ZLATB4 and generate a test matrix
*              with ZLATMS.
*
               CALL zlatb4( path, imat, m, n, TYPE, KL, KU, ANORM, MODE,
     $                      CNDNUM, DIST )
*
               srnamt = 'ZLATMS'
               CALL zlatms( m, n, dist, iseed, TYPE, RWORK, MODE,
     $                      CNDNUM, ANORM, KL, KU, 'No packing', A, LDA,
     $                      WORK, INFO )
*
*              Check error code from ZLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'ZLATMS', info, 0, ' ', m, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 50
               END IF
*
*              Set some values for K: the first value must be MINMN,
*              corresponding to the call of ZRQT01; other values are
*              used in the calls of ZRQT02, and must not exceed MINMN.
*
               kval( 1 ) = minmn
               kval( 2 ) = 0
               kval( 3 ) = 1
               kval( 4 ) = minmn / 2
               IF( minmn.EQ.0 ) THEN
                  nk = 1
               ELSE IF( minmn.EQ.1 ) THEN
                  nk = 2
               ELSE IF( minmn.LE.3 ) THEN
                  nk = 3
               ELSE
                  nk = 4
               END IF
*
*              Do for each value of K in KVAL
*
               DO 40 ik = 1, nk
                  k = kval( ik )
*
*                 Do for each pair of values (NB,NX) in NBVAL and NXVAL.
*
                  DO 30 inb = 1, nnb
                     nb = nbval( inb )
                     CALL xlaenv( 1, nb )
                     nx = nxval( inb )
                     CALL xlaenv( 3, nx )
                     DO i = 1, ntests
                        result( i ) = zero
                     END DO
                     nt = 2
                     IF( ik.EQ.1 ) THEN
*
*                       Test ZGERQF
*
                        CALL zrqt01( m, n, a, af, aq, ar, lda, tau,
     $                               work, lwork, rwork, result( 1 ) )
                     ELSE IF( m.LE.n ) THEN
*
*                       Test ZUNGRQ, using factorization
*                       returned by ZRQT01
*
                        CALL zrqt02( m, n, k, a, af, aq, ar, lda, tau,
     $                               work, lwork, rwork, result( 1 ) )
                     END IF
                     IF( m.GE.k ) THEN
*
*                       Test ZUNMRQ, using factorization returned
*                       by ZRQT01
*
                        CALL zrqt03( m, n, k, af, ac, ar, aq, lda, tau,
     $                               work, lwork, rwork, result( 3 ) )
                        nt = nt + 4
*
*                       If M>=N and K=N, call ZGERQS to solve a system
*                       with NRHS right hand sides and compute the
*                       residual.
*
                        IF( k.EQ.m .AND. inb.EQ.1 ) THEN
*
*                          Generate a solution and set the right
*                          hand side.
*
                           srnamt = 'ZLARHS'
                           CALL zlarhs( path, 'New', 'Full',
     $                                  'No transpose', m, n, 0, 0,
     $                                  nrhs, a, lda, xact, lda, b, lda,
     $                                  iseed, info )
*
                           CALL zlacpy( 'Full', m, nrhs, b, lda,
     $                                  x( n-m+1 ), lda )
                           srnamt = 'ZGERQS'
                           CALL zgerqs( m, n, nrhs, af, lda, tau, x,
     $                                  lda, work, lwork, info )
*
*                          Check error code from ZGERQS.
*
                           IF( info.NE.0 )
     $                        CALL alaerh( path, 'ZGERQS', info, 0, ' ',
     $                                     m, n, nrhs, -1, nb, imat,
     $                                     nfail, nerrs, nout )
*
                           CALL zget02( 'No transpose', m, n, nrhs, a,
     $                                  lda, x, lda, b, lda, rwork,
     $                                  result( 7 ) )
                           nt = nt + 1
                        END IF
                    END IF
*
*                    Print information about the tests that did not
*                    pass the threshold.
*
                     DO 20 i = 1, nt
                        IF( result( i ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9999 )m, n, k, nb, nx,
     $                        imat, i, result( i )
                           nfail = nfail + 1
                        END IF
   20                CONTINUE
                     nrun = nrun + nt
   30             CONTINUE
   40          CONTINUE
   50       CONTINUE
   60    CONTINUE
   70 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' M=', i5, ', N=', i5, ', K=', i5, ', NB=', i4, ', NX=',
     $      i5, ', type ', i2, ', test(', i2, ')=', g12.5 )
      RETURN
*
*     End of ZCHKRQ
*

Here is the call graph for this function:

Here is the caller graph for this function: