LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
zrqt02.f
Go to the documentation of this file.
1*> \brief \b ZRQT02
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZRQT02( M, N, K, A, AF, Q, R, LDA, TAU, WORK, LWORK,
12* RWORK, RESULT )
13*
14* .. Scalar Arguments ..
15* INTEGER K, LDA, LWORK, M, N
16* ..
17* .. Array Arguments ..
18* DOUBLE PRECISION RESULT( * ), RWORK( * )
19* COMPLEX*16 A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
20* \$ R( LDA, * ), TAU( * ), WORK( LWORK )
21* ..
22*
23*
24*> \par Purpose:
25* =============
26*>
27*> \verbatim
28*>
29*> ZRQT02 tests ZUNGRQ, which generates an m-by-n matrix Q with
30*> orthonormal rows that is defined as the product of k elementary
31*> reflectors.
32*>
33*> Given the RQ factorization of an m-by-n matrix A, ZRQT02 generates
34*> the orthogonal matrix Q defined by the factorization of the last k
35*> rows of A; it compares R(m-k+1:m,n-m+1:n) with
36*> A(m-k+1:m,1:n)*Q(n-m+1:n,1:n)', and checks that the rows of Q are
37*> orthonormal.
38*> \endverbatim
39*
40* Arguments:
41* ==========
42*
43*> \param[in] M
44*> \verbatim
45*> M is INTEGER
46*> The number of rows of the matrix Q to be generated. M >= 0.
47*> \endverbatim
48*>
49*> \param[in] N
50*> \verbatim
51*> N is INTEGER
52*> The number of columns of the matrix Q to be generated.
53*> N >= M >= 0.
54*> \endverbatim
55*>
56*> \param[in] K
57*> \verbatim
58*> K is INTEGER
59*> The number of elementary reflectors whose product defines the
60*> matrix Q. M >= K >= 0.
61*> \endverbatim
62*>
63*> \param[in] A
64*> \verbatim
65*> A is COMPLEX*16 array, dimension (LDA,N)
66*> The m-by-n matrix A which was factorized by ZRQT01.
67*> \endverbatim
68*>
69*> \param[in] AF
70*> \verbatim
71*> AF is COMPLEX*16 array, dimension (LDA,N)
72*> Details of the RQ factorization of A, as returned by ZGERQF.
73*> See ZGERQF for further details.
74*> \endverbatim
75*>
76*> \param[out] Q
77*> \verbatim
78*> Q is COMPLEX*16 array, dimension (LDA,N)
79*> \endverbatim
80*>
81*> \param[out] R
82*> \verbatim
83*> R is COMPLEX*16 array, dimension (LDA,M)
84*> \endverbatim
85*>
86*> \param[in] LDA
87*> \verbatim
88*> LDA is INTEGER
89*> The leading dimension of the arrays A, AF, Q and L. LDA >= N.
90*> \endverbatim
91*>
92*> \param[in] TAU
93*> \verbatim
94*> TAU is COMPLEX*16 array, dimension (M)
95*> The scalar factors of the elementary reflectors corresponding
96*> to the RQ factorization in AF.
97*> \endverbatim
98*>
99*> \param[out] WORK
100*> \verbatim
101*> WORK is COMPLEX*16 array, dimension (LWORK)
102*> \endverbatim
103*>
104*> \param[in] LWORK
105*> \verbatim
106*> LWORK is INTEGER
107*> The dimension of the array WORK.
108*> \endverbatim
109*>
110*> \param[out] RWORK
111*> \verbatim
112*> RWORK is DOUBLE PRECISION array, dimension (M)
113*> \endverbatim
114*>
115*> \param[out] RESULT
116*> \verbatim
117*> RESULT is DOUBLE PRECISION array, dimension (2)
118*> The test ratios:
119*> RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
120*> RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
121*> \endverbatim
122*
123* Authors:
124* ========
125*
126*> \author Univ. of Tennessee
127*> \author Univ. of California Berkeley
128*> \author Univ. of Colorado Denver
129*> \author NAG Ltd.
130*
131*> \ingroup complex16_lin
132*
133* =====================================================================
134 SUBROUTINE zrqt02( M, N, K, A, AF, Q, R, LDA, TAU, WORK, LWORK,
135 \$ RWORK, RESULT )
136*
137* -- LAPACK test routine --
138* -- LAPACK is a software package provided by Univ. of Tennessee, --
139* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
140*
141* .. Scalar Arguments ..
142 INTEGER K, LDA, LWORK, M, N
143* ..
144* .. Array Arguments ..
145 DOUBLE PRECISION RESULT( * ), RWORK( * )
146 COMPLEX*16 A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
147 \$ r( lda, * ), tau( * ), work( lwork )
148* ..
149*
150* =====================================================================
151*
152* .. Parameters ..
153 DOUBLE PRECISION ZERO, ONE
154 parameter( zero = 0.0d+0, one = 1.0d+0 )
155 COMPLEX*16 ROGUE
156 parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
157* ..
158* .. Local Scalars ..
159 INTEGER INFO
160 DOUBLE PRECISION ANORM, EPS, RESID
161* ..
162* .. External Functions ..
163 DOUBLE PRECISION DLAMCH, ZLANGE, ZLANSY
164 EXTERNAL dlamch, zlange, zlansy
165* ..
166* .. External Subroutines ..
167 EXTERNAL zgemm, zherk, zlacpy, zlaset, zungrq
168* ..
169* .. Intrinsic Functions ..
170 INTRINSIC dble, dcmplx, max
171* ..
172* .. Scalars in Common ..
173 CHARACTER*32 SRNAMT
174* ..
175* .. Common blocks ..
176 COMMON / srnamc / srnamt
177* ..
178* .. Executable Statements ..
179*
180* Quick return if possible
181*
182 IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
183 result( 1 ) = zero
184 result( 2 ) = zero
185 RETURN
186 END IF
187*
188 eps = dlamch( 'Epsilon' )
189*
190* Copy the last k rows of the factorization to the array Q
191*
192 CALL zlaset( 'Full', m, n, rogue, rogue, q, lda )
193 IF( k.LT.n )
194 \$ CALL zlacpy( 'Full', k, n-k, af( m-k+1, 1 ), lda,
195 \$ q( m-k+1, 1 ), lda )
196 IF( k.GT.1 )
197 \$ CALL zlacpy( 'Lower', k-1, k-1, af( m-k+2, n-k+1 ), lda,
198 \$ q( m-k+2, n-k+1 ), lda )
199*
200* Generate the last n rows of the matrix Q
201*
202 srnamt = 'ZUNGRQ'
203 CALL zungrq( m, n, k, q, lda, tau( m-k+1 ), work, lwork, info )
204*
205* Copy R(m-k+1:m,n-m+1:n)
206*
207 CALL zlaset( 'Full', k, m, dcmplx( zero ), dcmplx( zero ),
208 \$ r( m-k+1, n-m+1 ), lda )
209 CALL zlacpy( 'Upper', k, k, af( m-k+1, n-k+1 ), lda,
210 \$ r( m-k+1, n-k+1 ), lda )
211*
212* Compute R(m-k+1:m,n-m+1:n) - A(m-k+1:m,1:n) * Q(n-m+1:n,1:n)'
213*
214 CALL zgemm( 'No transpose', 'Conjugate transpose', k, m, n,
215 \$ dcmplx( -one ), a( m-k+1, 1 ), lda, q, lda,
216 \$ dcmplx( one ), r( m-k+1, n-m+1 ), lda )
217*
218* Compute norm( R - A*Q' ) / ( N * norm(A) * EPS ) .
219*
220 anorm = zlange( '1', k, n, a( m-k+1, 1 ), lda, rwork )
221 resid = zlange( '1', k, m, r( m-k+1, n-m+1 ), lda, rwork )
222 IF( anorm.GT.zero ) THEN
223 result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
224 ELSE
225 result( 1 ) = zero
226 END IF
227*
228* Compute I - Q*Q'
229*
230 CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), r, lda )
231 CALL zherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, r,
232 \$ lda )
233*
234* Compute norm( I - Q*Q' ) / ( N * EPS ) .
235*
236 resid = zlansy( '1', 'Upper', m, r, lda, rwork )
237*
238 result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
239*
240 RETURN
241*
242* End of ZRQT02
243*
244 END
subroutine zgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
ZGEMM
Definition zgemm.f:188
subroutine zherk(uplo, trans, n, k, alpha, a, lda, beta, c, ldc)
ZHERK
Definition zherk.f:173
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:103
subroutine zlaset(uplo, m, n, alpha, beta, a, lda)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition zlaset.f:106
subroutine zungrq(m, n, k, a, lda, tau, work, lwork, info)
ZUNGRQ
Definition zungrq.f:128
subroutine zrqt02(m, n, k, a, af, q, r, lda, tau, work, lwork, rwork, result)
ZRQT02
Definition zrqt02.f:136