LAPACK  3.10.1 LAPACK: Linear Algebra PACKage
zrqt03.f
Go to the documentation of this file.
1 *> \brief \b ZRQT03
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE ZRQT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
12 * RWORK, RESULT )
13 *
14 * .. Scalar Arguments ..
15 * INTEGER K, LDA, LWORK, M, N
16 * ..
17 * .. Array Arguments ..
18 * DOUBLE PRECISION RESULT( * ), RWORK( * )
19 * COMPLEX*16 AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
20 * \$ Q( LDA, * ), TAU( * ), WORK( LWORK )
21 * ..
22 *
23 *
24 *> \par Purpose:
25 * =============
26 *>
27 *> \verbatim
28 *>
29 *> ZRQT03 tests ZUNMRQ, which computes Q*C, Q'*C, C*Q or C*Q'.
30 *>
31 *> ZRQT03 compares the results of a call to ZUNMRQ with the results of
32 *> forming Q explicitly by a call to ZUNGRQ and then performing matrix
33 *> multiplication by a call to ZGEMM.
34 *> \endverbatim
35 *
36 * Arguments:
37 * ==========
38 *
39 *> \param[in] M
40 *> \verbatim
41 *> M is INTEGER
42 *> The number of rows or columns of the matrix C; C is n-by-m if
43 *> Q is applied from the left, or m-by-n if Q is applied from
44 *> the right. M >= 0.
45 *> \endverbatim
46 *>
47 *> \param[in] N
48 *> \verbatim
49 *> N is INTEGER
50 *> The order of the orthogonal matrix Q. N >= 0.
51 *> \endverbatim
52 *>
53 *> \param[in] K
54 *> \verbatim
55 *> K is INTEGER
56 *> The number of elementary reflectors whose product defines the
57 *> orthogonal matrix Q. N >= K >= 0.
58 *> \endverbatim
59 *>
60 *> \param[in] AF
61 *> \verbatim
62 *> AF is COMPLEX*16 array, dimension (LDA,N)
63 *> Details of the RQ factorization of an m-by-n matrix, as
64 *> returned by ZGERQF. See CGERQF for further details.
65 *> \endverbatim
66 *>
67 *> \param[out] C
68 *> \verbatim
69 *> C is COMPLEX*16 array, dimension (LDA,N)
70 *> \endverbatim
71 *>
72 *> \param[out] CC
73 *> \verbatim
74 *> CC is COMPLEX*16 array, dimension (LDA,N)
75 *> \endverbatim
76 *>
77 *> \param[out] Q
78 *> \verbatim
79 *> Q is COMPLEX*16 array, dimension (LDA,N)
80 *> \endverbatim
81 *>
82 *> \param[in] LDA
83 *> \verbatim
84 *> LDA is INTEGER
85 *> The leading dimension of the arrays AF, C, CC, and Q.
86 *> \endverbatim
87 *>
88 *> \param[in] TAU
89 *> \verbatim
90 *> TAU is COMPLEX*16 array, dimension (min(M,N))
91 *> The scalar factors of the elementary reflectors corresponding
92 *> to the RQ factorization in AF.
93 *> \endverbatim
94 *>
95 *> \param[out] WORK
96 *> \verbatim
97 *> WORK is COMPLEX*16 array, dimension (LWORK)
98 *> \endverbatim
99 *>
100 *> \param[in] LWORK
101 *> \verbatim
102 *> LWORK is INTEGER
103 *> The length of WORK. LWORK must be at least M, and should be
104 *> M*NB, where NB is the blocksize for this environment.
105 *> \endverbatim
106 *>
107 *> \param[out] RWORK
108 *> \verbatim
109 *> RWORK is DOUBLE PRECISION array, dimension (M)
110 *> \endverbatim
111 *>
112 *> \param[out] RESULT
113 *> \verbatim
114 *> RESULT is DOUBLE PRECISION array, dimension (4)
115 *> The test ratios compare two techniques for multiplying a
116 *> random matrix C by an n-by-n orthogonal matrix Q.
117 *> RESULT(1) = norm( Q*C - Q*C ) / ( N * norm(C) * EPS )
118 *> RESULT(2) = norm( C*Q - C*Q ) / ( N * norm(C) * EPS )
119 *> RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS )
120 *> RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )
121 *> \endverbatim
122 *
123 * Authors:
124 * ========
125 *
126 *> \author Univ. of Tennessee
127 *> \author Univ. of California Berkeley
128 *> \author Univ. of Colorado Denver
129 *> \author NAG Ltd.
130 *
131 *> \ingroup complex16_lin
132 *
133 * =====================================================================
134  SUBROUTINE zrqt03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
135  \$ RWORK, RESULT )
136 *
137 * -- LAPACK test routine --
138 * -- LAPACK is a software package provided by Univ. of Tennessee, --
139 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
140 *
141 * .. Scalar Arguments ..
142  INTEGER K, LDA, LWORK, M, N
143 * ..
144 * .. Array Arguments ..
145  DOUBLE PRECISION RESULT( * ), RWORK( * )
146  COMPLEX*16 AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
147  \$ q( lda, * ), tau( * ), work( lwork )
148 * ..
149 *
150 * =====================================================================
151 *
152 * .. Parameters ..
153  DOUBLE PRECISION ZERO, ONE
154  parameter( zero = 0.0d+0, one = 1.0d+0 )
155  COMPLEX*16 ROGUE
156  parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
157 * ..
158 * .. Local Scalars ..
159  CHARACTER SIDE, TRANS
160  INTEGER INFO, ISIDE, ITRANS, J, MC, MINMN, NC
161  DOUBLE PRECISION CNORM, EPS, RESID
162 * ..
163 * .. External Functions ..
164  LOGICAL LSAME
165  DOUBLE PRECISION DLAMCH, ZLANGE
166  EXTERNAL lsame, dlamch, zlange
167 * ..
168 * .. External Subroutines ..
169  EXTERNAL zgemm, zlacpy, zlarnv, zlaset, zungrq, zunmrq
170 * ..
171 * .. Local Arrays ..
172  INTEGER ISEED( 4 )
173 * ..
174 * .. Intrinsic Functions ..
175  INTRINSIC dble, dcmplx, max, min
176 * ..
177 * .. Scalars in Common ..
178  CHARACTER*32 SRNAMT
179 * ..
180 * .. Common blocks ..
181  COMMON / srnamc / srnamt
182 * ..
183 * .. Data statements ..
184  DATA iseed / 1988, 1989, 1990, 1991 /
185 * ..
186 * .. Executable Statements ..
187 *
188  eps = dlamch( 'Epsilon' )
189  minmn = min( m, n )
190 *
191 * Quick return if possible
192 *
193  IF( minmn.EQ.0 ) THEN
194  result( 1 ) = zero
195  result( 2 ) = zero
196  result( 3 ) = zero
197  result( 4 ) = zero
198  RETURN
199  END IF
200 *
201 * Copy the last k rows of the factorization to the array Q
202 *
203  CALL zlaset( 'Full', n, n, rogue, rogue, q, lda )
204  IF( k.GT.0 .AND. n.GT.k )
205  \$ CALL zlacpy( 'Full', k, n-k, af( m-k+1, 1 ), lda,
206  \$ q( n-k+1, 1 ), lda )
207  IF( k.GT.1 )
208  \$ CALL zlacpy( 'Lower', k-1, k-1, af( m-k+2, n-k+1 ), lda,
209  \$ q( n-k+2, n-k+1 ), lda )
210 *
211 * Generate the n-by-n matrix Q
212 *
213  srnamt = 'ZUNGRQ'
214  CALL zungrq( n, n, k, q, lda, tau( minmn-k+1 ), work, lwork,
215  \$ info )
216 *
217  DO 30 iside = 1, 2
218  IF( iside.EQ.1 ) THEN
219  side = 'L'
220  mc = n
221  nc = m
222  ELSE
223  side = 'R'
224  mc = m
225  nc = n
226  END IF
227 *
228 * Generate MC by NC matrix C
229 *
230  DO 10 j = 1, nc
231  CALL zlarnv( 2, iseed, mc, c( 1, j ) )
232  10 CONTINUE
233  cnorm = zlange( '1', mc, nc, c, lda, rwork )
234  IF( cnorm.EQ.zero )
235  \$ cnorm = one
236 *
237  DO 20 itrans = 1, 2
238  IF( itrans.EQ.1 ) THEN
239  trans = 'N'
240  ELSE
241  trans = 'C'
242  END IF
243 *
244 * Copy C
245 *
246  CALL zlacpy( 'Full', mc, nc, c, lda, cc, lda )
247 *
248 * Apply Q or Q' to C
249 *
250  srnamt = 'ZUNMRQ'
251  IF( k.GT.0 )
252  \$ CALL zunmrq( side, trans, mc, nc, k, af( m-k+1, 1 ), lda,
253  \$ tau( minmn-k+1 ), cc, lda, work, lwork,
254  \$ info )
255 *
256 * Form explicit product and subtract
257 *
258  IF( lsame( side, 'L' ) ) THEN
259  CALL zgemm( trans, 'No transpose', mc, nc, mc,
260  \$ dcmplx( -one ), q, lda, c, lda,
261  \$ dcmplx( one ), cc, lda )
262  ELSE
263  CALL zgemm( 'No transpose', trans, mc, nc, nc,
264  \$ dcmplx( -one ), c, lda, q, lda,
265  \$ dcmplx( one ), cc, lda )
266  END IF
267 *
268 * Compute error in the difference
269 *
270  resid = zlange( '1', mc, nc, cc, lda, rwork )
271  result( ( iside-1 )*2+itrans ) = resid /
272  \$ ( dble( max( 1, n ) )*cnorm*eps )
273 *
274  20 CONTINUE
275  30 CONTINUE
276 *
277  RETURN
278 *
279 * End of ZRQT03
280 *
281  END
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:187
subroutine zrqt03(M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK, RWORK, RESULT)
ZRQT03
Definition: zrqt03.f:136
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:103
subroutine zlarnv(IDIST, ISEED, N, X)
ZLARNV returns a vector of random numbers from a uniform or normal distribution.
Definition: zlarnv.f:99
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: zlaset.f:106
subroutine zungrq(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
ZUNGRQ
Definition: zungrq.f:128
subroutine zunmrq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
ZUNMRQ
Definition: zunmrq.f:167