stzrzf()

subroutine stzrzf	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( * )	work,
		integer	lwork,
		integer	info
	)

STZRZF

Download STZRZF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 STZRZF reduces the M-by-N ( M<=N ) real upper trapezoidal matrix A
 to upper triangular form by means of orthogonal transformations.

 The upper trapezoidal matrix A is factored as

    A = ( R  0 ) * Z,

 where Z is an N-by-N orthogonal matrix and R is an M-by-M upper
 triangular matrix.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= M.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the leading M-by-N upper trapezoidal part of the array A must contain the matrix to be factorized. On exit, the leading M-by-M upper triangular part of A contains the upper triangular matrix R, and elements M+1 to N of the first M rows of A, with the array TAU, represent the orthogonal matrix Z as a product of M elementary reflectors.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	TAU	TAU is REAL array, dimension (M) The scalar factors of the elementary reflectors.
[out]	WORK	WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,M). For optimum performance LWORK >= M*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Further Details:

  The N-by-N matrix Z can be computed by

     Z =  Z(1)*Z(2)* ... *Z(M)

  where each N-by-N Z(k) is given by

     Z(k) = I - tau(k)*v(k)*v(k)**T

  with v(k) is the kth row vector of the M-by-N matrix

     V = ( I   A(:,M+1:N) )

  I is the M-by-M identity matrix, A(:,M+1:N)
  is the output stored in A on exit from STZRZF,
  and tau(k) is the kth element of the array TAU.

Definition at line 150 of file stzrzf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, IWS, KI, KK, LDWORK, LWKMIN, LWKOPT,
     $                   M1, MU, NB, NBMIN, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, slarzb, slarzt, slatrz
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
*
      IF( info.EQ.0 ) THEN
         IF( m.EQ.0 .OR. m.EQ.n ) THEN
            lwkopt = 1
            lwkmin = 1
         ELSE
*
*           Determine the block size.
*
            nb = ilaenv( 1, 'SGERQF', ' ', m, n, -1, -1 )
            lwkopt = m*nb
            lwkmin = max( 1, m )
         END IF
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
            info = -7
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'STZRZF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 ) THEN
         RETURN
      ELSE IF( m.EQ.n ) THEN
         DO 10 i = 1, n
            tau( i ) = zero
   10    CONTINUE
         RETURN
      END IF
*
      nbmin = 2
      nx = 1
      iws = m
      IF( nb.GT.1 .AND. nb.LT.m ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'SGERQF', ' ', m, n, -1, -1 ) )
         IF( nx.LT.m ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = m
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'SGERQF', ' ', m, n, -1,
     $                 -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.m .AND. nx.LT.m ) THEN
*
*        Use blocked code initially.
*        The last kk rows are handled by the block method.
*
         m1 = min( m+1, n )
         ki = ( ( m-nx-1 ) / nb )*nb
         kk = min( m, ki+nb )
*
         DO 20 i = m - kk + ki + 1, m - kk + 1, -nb
            ib = min( m-i+1, nb )
*
*           Compute the TZ factorization of the current block
*           A(i:i+ib-1,i:n)
*
            CALL slatrz( ib, n-i+1, n-m, a( i, i ), lda, tau( i ),
     $                   work )
            IF( i.GT.1 ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL slarzt( 'Backward', 'Rowwise', n-m, ib, a( i, m1 ),
     $                      lda, tau( i ), work, ldwork )
*
*              Apply H to A(1:i-1,i:n) from the right
*
               CALL slarzb( 'Right', 'No transpose', 'Backward',
     $                      'Rowwise', i-1, n-i+1, ib, n-m, a( i, m1 ),
     $                      lda, work, ldwork, a( 1, i ), lda,
     $                      work( ib+1 ), ldwork )
            END IF
   20    CONTINUE
         mu = i + nb - 1
      ELSE
         mu = m
      END IF
*
*     Use unblocked code to factor the last or only block
*
      IF( mu.GT.0 )
     $   CALL slatrz( mu, n, n-m, a, lda, tau, work )
*
      work( 1 ) = sroundup_lwork(lwkopt)
*
      RETURN
*
*     End of STZRZF
*

Here is the call graph for this function:

Here is the caller graph for this function: