sopgtr()

subroutine sopgtr	(	character	uplo,
		integer	n,
		real, dimension( * )	ap,
		real, dimension( * )	tau,
		real, dimension( ldq, * )	q,
		integer	ldq,
		real, dimension( * )	work,
		integer	info
	)

SOPGTR

Download SOPGTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SOPGTR generates a real orthogonal matrix Q which is defined as the
 product of n-1 elementary reflectors H(i) of order n, as returned by
 SSPTRD using packed storage:

 if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),

 if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangular packed storage used in previous call to SSPTRD; = 'L': Lower triangular packed storage used in previous call to SSPTRD.
[in]	N	N is INTEGER The order of the matrix Q. N >= 0.
[in]	AP	AP is REAL array, dimension (N*(N+1)/2) The vectors which define the elementary reflectors, as returned by SSPTRD.
[in]	TAU	TAU is REAL array, dimension (N-1) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SSPTRD.
[out]	Q	Q is REAL array, dimension (LDQ,N) The N-by-N orthogonal matrix Q.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[out]	WORK	WORK is REAL array, dimension (N-1)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 113 of file sopgtr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDQ, N
*     ..
*     .. Array Arguments ..
      REAL               AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IINFO, IJ, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           sorg2l, sorg2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SOPGTR', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Q was determined by a call to SSPTRD with UPLO = 'U'
*
*        Unpack the vectors which define the elementary reflectors and
*        set the last row and column of Q equal to those of the unit
*        matrix
*
         ij = 2
         DO 20 j = 1, n - 1
            DO 10 i = 1, j - 1
               q( i, j ) = ap( ij )
               ij = ij + 1
   10       CONTINUE
            ij = ij + 2
            q( n, j ) = zero
   20    CONTINUE
         DO 30 i = 1, n - 1
            q( i, n ) = zero
   30    CONTINUE
         q( n, n ) = one
*
*        Generate Q(1:n-1,1:n-1)
*
         CALL sorg2l( n-1, n-1, n-1, q, ldq, tau, work, iinfo )
*
      ELSE
*
*        Q was determined by a call to SSPTRD with UPLO = 'L'.
*
*        Unpack the vectors which define the elementary reflectors and
*        set the first row and column of Q equal to those of the unit
*        matrix
*
         q( 1, 1 ) = one
         DO 40 i = 2, n
            q( i, 1 ) = zero
   40    CONTINUE
         ij = 3
         DO 60 j = 2, n
            q( 1, j ) = zero
            DO 50 i = j + 1, n
               q( i, j ) = ap( ij )
               ij = ij + 1
   50       CONTINUE
            ij = ij + 2
   60    CONTINUE
         IF( n.GT.1 ) THEN
*
*           Generate Q(2:n,2:n)
*
            CALL sorg2r( n-1, n-1, n-1, q( 2, 2 ), ldq, tau, work,
     $                   iinfo )
         END IF
      END IF
      RETURN
*
*     End of SOPGTR
*

Here is the call graph for this function:

Here is the caller graph for this function: