clqt03()

subroutine clqt03	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	c,
		complex, dimension( lda, * )	cc,
		complex, dimension( lda, * )	q,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result )

CLQT03

Purpose:

!>
!> CLQT03 tests CUNMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.
!>
!> CLQT03 compares the results of a call to CUNMLQ with the results of
!> forming Q explicitly by a call to CUNGLQ and then performing matrix
!> multiplication by a call to CGEMM.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows or columns of the matrix C; C is n-by-m if !> Q is applied from the left, or m-by-n if Q is applied from !> the right. M >= 0. !>
[in]	N	!> N is INTEGER !> The order of the orthogonal matrix Q. N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> orthogonal matrix Q. N >= K >= 0. !>
[in]	AF	!> AF is COMPLEX array, dimension (LDA,N) !> Details of the LQ factorization of an m-by-n matrix, as !> returned by CGELQF. See CGELQF for further details. !>
[out]	C	!> C is COMPLEX array, dimension (LDA,N) !>
[out]	CC	!> CC is COMPLEX array, dimension (LDA,N) !>
[out]	Q	!> Q is COMPLEX array, dimension (LDA,N) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays AF, C, CC, and Q. !>
[in]	TAU	!> TAU is COMPLEX array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors corresponding !> to the LQ factorization in AF. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of WORK. LWORK must be at least M, and should be !> M*NB, where NB is the blocksize for this environment. !>
[out]	RWORK	!> RWORK is REAL array, dimension (M) !>
[out]	RESULT	!> RESULT is REAL array, dimension (4) !> The test ratios compare two techniques for multiplying a !> random matrix C by an n-by-n orthogonal matrix Q. !> RESULT(1) = norm( Q*C - Q*C ) / ( N * norm(C) * EPS ) !> RESULT(2) = norm( C*Q - C*Q ) / ( N * norm(C) * EPS ) !> RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS ) !> RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 134 of file clqt03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
     $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, ISIDE, ITRANS, J, MC, NC
      REAL               CNORM, EPS, RESID
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANGE, SLAMCH
      EXTERNAL           lsame, clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, clarnv, claset, cunglq, cunmlq
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL claset( 'Full', n, n, rogue, rogue, q, lda )
      CALL clacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'CUNGLQ'
      CALL cunglq( n, n, k, q, lda, tau, work, lwork, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = n
            nc = m
         ELSE
            side = 'R'
            mc = m
            nc = n
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL clarnv( 2, iseed, mc, c( 1, j ) )
   10    CONTINUE
         cnorm = clange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.zero )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
*           Copy C
*
            CALL clacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'CUNMLQ'
            CALL cunmlq( side, trans, mc, nc, k, af, lda, tau, cc, lda,
     $                   work, lwork, info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL cgemm( trans, 'No transpose', mc, nc, mc,
     $                     cmplx( -one ), q, lda, c, lda, cmplx( one ),
     $                     cc, lda )
            ELSE
               CALL cgemm( 'No transpose', trans, mc, nc, nc,
     $                     cmplx( -one ), c, lda, q, lda, cmplx( one ),
     $                     cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = clange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( real( max( 1, n ) )*cnorm*eps )
*
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of CLQT03
*

Here is the call graph for this function:

Here is the caller graph for this function: