cqlt02()

subroutine cqlt02	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	q,
		complex, dimension( lda, * )	l,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result
	)

CQLT02

Purpose:

 CQLT02 tests CUNGQL, which generates an m-by-n matrix Q with
 orthonormal columns that is defined as the product of k elementary
 reflectors.

 Given the QL factorization of an m-by-n matrix A, CQLT02 generates
 the orthogonal matrix Q defined by the factorization of the last k
 columns of A; it compares L(m-n+1:m,n-k+1:n) with
 Q(1:m,m-n+1:m)'*A(1:m,n-k+1:n), and checks that the columns of Q are
 orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A which was factorized by CQLT01.
[in]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the QL factorization of A, as returned by CGEQLF. See CGEQLF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N)
[out]	L	L is COMPLEX array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= M.
[in]	TAU	TAU is COMPLEX array, dimension (N) The scalar factors of the elementary reflectors corresponding to the QL factorization in AF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 134 of file cqlt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clacpy, claset, cungql
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
*
*     Copy the last k columns of the factorization to the array Q
*
      CALL claset( 'Full', m, n, rogue, rogue, q, lda )
      IF( k.LT.m )
     $   CALL clacpy( 'Full', m-k, k, af( 1, n-k+1 ), lda,
     $                q( 1, n-k+1 ), lda )
      IF( k.GT.1 )
     $   CALL clacpy( 'Upper', k-1, k-1, af( m-k+1, n-k+2 ), lda,
     $                q( m-k+1, n-k+2 ), lda )
*
*     Generate the last n columns of the matrix Q
*
      srnamt = 'CUNGQL'
      CALL cungql( m, n, k, q, lda, tau( n-k+1 ), work, lwork, info )
*
*     Copy L(m-n+1:m,n-k+1:n)
*
      CALL claset( 'Full', n, k, cmplx( zero ), cmplx( zero ),
     $             l( m-n+1, n-k+1 ), lda )
      CALL clacpy( 'Lower', k, k, af( m-k+1, n-k+1 ), lda,
     $             l( m-k+1, n-k+1 ), lda )
*
*     Compute L(m-n+1:m,n-k+1:n) - Q(1:m,m-n+1:m)' * A(1:m,n-k+1:n)
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', n, k, m,
     $            cmplx( -one ), q, lda, a( 1, n-k+1 ), lda,
     $            cmplx( one ), l( m-n+1, n-k+1 ), lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = clange( '1', m, k, a( 1, n-k+1 ), lda, rwork )
      resid = clange( '1', n, k, l( m-n+1, n-k+1 ), lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), l, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', n, m, -one, q, lda,
     $            one, l, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = clansy( '1', 'Upper', n, l, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of CQLT02
*

Here is the call graph for this function:

Here is the caller graph for this function: