zggqrf()

subroutine zggqrf	(	integer	n,
		integer	m,
		integer	p,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	taua,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( * )	taub,
		complex*16, dimension( * )	work,
		integer	lwork,
		integer	info )

ZGGQRF

Download ZGGQRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGGQRF computes a generalized QR factorization of an N-by-M matrix A
!> and an N-by-P matrix B:
!>
!>             A = Q*R,        B = Q*T*Z,
!>
!> where Q is an N-by-N unitary matrix, Z is a P-by-P unitary matrix,
!> and R and T assume one of the forms:
!>
!> if N >= M,  R = ( R11 ) M  ,   or if N < M,  R = ( R11  R12 ) N,
!>                 (  0  ) N-M                         N   M-N
!>                    M
!>
!> where R11 is upper triangular, and
!>
!> if N <= P,  T = ( 0  T12 ) N,   or if N > P,  T = ( T11 ) N-P,
!>                  P-N  N                           ( T21 ) P
!>                                                      P
!>
!> where T12 or T21 is upper triangular.
!>
!> In particular, if B is square and nonsingular, the GQR factorization
!> of A and B implicitly gives the QR factorization of inv(B)*A:
!>
!>              inv(B)*A = Z**H * (inv(T)*R)
!>
!> where inv(B) denotes the inverse of the matrix B, and Z**H denotes the
!> conjugate transpose of matrix Z.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of rows of the matrices A and B. N >= 0. !>
[in]	M	!> M is INTEGER !> The number of columns of the matrix A. M >= 0. !>
[in]	P	!> P is INTEGER !> The number of columns of the matrix B. P >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,M) !> On entry, the N-by-M matrix A. !> On exit, the elements on and above the diagonal of the array !> contain the min(N,M)-by-M upper trapezoidal matrix R (R is !> upper triangular if N >= M); the elements below the diagonal, !> with the array TAUA, represent the unitary matrix Q as a !> product of min(N,M) elementary reflectors (see Further !> Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	TAUA	!> TAUA is COMPLEX*16 array, dimension (min(N,M)) !> The scalar factors of the elementary reflectors which !> represent the unitary matrix Q (see Further Details). !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB,P) !> On entry, the N-by-P matrix B. !> On exit, if N <= P, the upper triangle of the subarray !> B(1:N,P-N+1:P) contains the N-by-N upper triangular matrix T; !> if N > P, the elements on and above the (N-P)-th subdiagonal !> contain the N-by-P upper trapezoidal matrix T; the remaining !> elements, with the array TAUB, represent the unitary !> matrix Z as a product of elementary reflectors (see Further !> Details). !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	TAUB	!> TAUB is COMPLEX*16 array, dimension (min(N,P)) !> The scalar factors of the elementary reflectors which !> represent the unitary matrix Z (see Further Details). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,N,M,P). !> For optimum performance LWORK >= max(N,M,P)*max(NB1,NB2,NB3), !> where NB1 is the optimal blocksize for the QR factorization !> of an N-by-M matrix, NB2 is the optimal blocksize for the !> RQ factorization of an N-by-P matrix, and NB3 is the optimal !> blocksize for a call of ZUNMQR. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(1) H(2) . . . H(k), where k = min(n,m).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - taua * v * v**H
!>
!>  where taua is a complex scalar, and v is a complex vector with
!>  v(1:i-1) = 0 and v(i) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
!>  and taua in TAUA(i).
!>  To form Q explicitly, use LAPACK subroutine ZUNGQR.
!>  To use Q to update another matrix, use LAPACK subroutine ZUNMQR.
!>
!>  The matrix Z is represented as a product of elementary reflectors
!>
!>     Z = H(1) H(2) . . . H(k), where k = min(n,p).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - taub * v * v**H
!>
!>  where taub is a complex scalar, and v is a complex vector with
!>  v(p-k+i+1:p) = 0 and v(p-k+i) = 1; v(1:p-k+i-1) is stored on exit in
!>  B(n-k+i,1:p-k+i-1), and taub in TAUB(i).
!>  To form Z explicitly, use LAPACK subroutine ZUNGRQ.
!>  To use Z to update another matrix, use LAPACK subroutine ZUNMRQ.
!> 

Definition at line 211 of file zggqrf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, P
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), TAUA( * ), TAUB( * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            LOPT, LWKOPT, NB, NB1, NB2, NB3
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgeqrf, zgerqf, zunmqr
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      EXTERNAL           ilaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      nb1 = ilaenv( 1, 'ZGEQRF', ' ', n, m, -1, -1 )
      nb2 = ilaenv( 1, 'ZGERQF', ' ', n, p, -1, -1 )
      nb3 = ilaenv( 1, 'ZUNMQR', ' ', n, m, p, -1 )
      nb = max( nb1, nb2, nb3 )
      lwkopt = max( 1, max( n, m, p )*nb )
      work( 1 ) = lwkopt
      lquery = ( lwork.EQ.-1 )
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( p.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.max( 1, n, m, p ) .AND. .NOT.lquery ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGGQRF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     QR factorization of N-by-M matrix A: A = Q*R
*
      CALL zgeqrf( n, m, a, lda, taua, work, lwork, info )
      lopt = int( work( 1 ) )
*
*     Update B := Q**H*B.
*
      CALL zunmqr( 'Left', 'Conjugate Transpose', n, p, min( n, m ),
     $             a,
     $             lda, taua, b, ldb, work, lwork, info )
      lopt = max( lopt, int( work( 1 ) ) )
*
*     RQ factorization of N-by-P matrix B: B = T*Z.
*
      CALL zgerqf( n, p, b, ldb, taub, work, lwork, info )
      work( 1 ) = max( lopt, int( work( 1 ) ) )
*
      RETURN
*
*     End of ZGGQRF
*

Here is the call graph for this function:

Here is the caller graph for this function: