zpstf2.f

Go to the documentation of this file.

*> \brief \b ZPSTF2 computes the Cholesky factorization with complete pivoting of a complex Hermitian positive semidefinite matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZPSTF2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zpstf2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zpstf2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zpstf2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZPSTF2( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
*
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   TOL
*       INTEGER            INFO, LDA, N, RANK
*       CHARACTER          UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * )
*       DOUBLE PRECISION   WORK( 2*N )
*       INTEGER            PIV( N )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZPSTF2 computes the Cholesky factorization with complete
*> pivoting of a complex Hermitian positive semidefinite matrix A.
*>
*> The factorization has the form
*>    P**T * A * P = U**H * U ,  if UPLO = 'U',
*>    P**T * A * P = L  * L**H,  if UPLO = 'L',
*> where U is an upper triangular matrix and L is lower triangular, and
*> P is stored as vector PIV.
*>
*> This algorithm does not attempt to check that A is positive
*> semidefinite. This version of the algorithm calls level 2 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrix A is stored.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
*>          n by n upper triangular part of A contains the upper
*>          triangular part of the matrix A, and the strictly lower
*>          triangular part of A is not referenced.  If UPLO = 'L', the
*>          leading n by n lower triangular part of A contains the lower
*>          triangular part of the matrix A, and the strictly upper
*>          triangular part of A is not referenced.
*>
*>          On exit, if INFO = 0, the factor U or L from the Cholesky
*>          factorization as above.
*> \endverbatim
*>
*> \param[out] PIV
*> \verbatim
*>          PIV is INTEGER array, dimension (N)
*>          PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
*> \endverbatim
*>
*> \param[out] RANK
*> \verbatim
*>          RANK is INTEGER
*>          The rank of A given by the number of steps the algorithm
*>          completed.
*> \endverbatim
*>
*> \param[in] TOL
*> \verbatim
*>          TOL is DOUBLE PRECISION
*>          User defined tolerance. If TOL < 0, then N*U*MAX( A( K,K ) )
*>          will be used. The algorithm terminates at the (K-1)st step
*>          if the pivot <= TOL.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (2*N)
*>          Work space.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          < 0: If INFO = -K, the K-th argument had an illegal value,
*>          = 0: algorithm completed successfully, and
*>          > 0: the matrix A is either rank deficient with computed rank
*>               as returned in RANK, or is not positive semidefinite. See
*>               Section 7 of LAPACK Working Note #161 for further
*>               information.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup pstf2
*
*  =====================================================================
      SUBROUTINE zpstf2( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   TOL
      INTEGER            INFO, LDA, N, RANK
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * )
      DOUBLE PRECISION   WORK( 2*N )
      INTEGER            PIV( N )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      COMPLEX*16         ZTEMP
      DOUBLE PRECISION   AJJ, DSTOP, DTEMP
      INTEGER            I, ITEMP, J, PVT
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      LOGICAL            LSAME, DISNAN
      EXTERNAL           dlamch, lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal, zgemv, zlacgv, zswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dconjg, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPSTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Initialize PIV
*
      DO 100 i = 1, n
         piv( i ) = i
  100 CONTINUE
*
*     Compute stopping value
*
      DO 110 i = 1, n
         work( i ) = dble( a( i, i ) )
  110 CONTINUE
      pvt = maxloc( work( 1:n ), 1 )
      ajj = dble( a( pvt, pvt ) )
      IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
         rank = 0
         info = 1
         GO TO 200
      END IF
*
*     Compute stopping value if not supplied
*
      IF( tol.LT.zero ) THEN
         dstop = n * dlamch( 'Epsilon' ) * ajj
      ELSE
         dstop = tol
      END IF
*
*     Set first half of WORK to zero, holds dot products
*
      DO 120 i = 1, n
         work( i ) = 0
  120 CONTINUE
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization P**T * A * P = U**H* U
*
         DO 150 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 130 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) +
     $                        dble( dconjg( a( j-1, i ) )*
     $                              a( j-1, i ) )
               END IF
               work( n+i ) = dble( a( i, i ) ) - work( i )
*
  130       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 190
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL zswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
               IF( pvt.LT.n )
     $            CALL zswap( n-pvt, a( j, pvt+1 ), lda,
     $                        a( pvt, pvt+1 ), lda )
               DO 140 i = j + 1, pvt - 1
                  ztemp = dconjg( a( j, i ) )
                  a( j, i ) = dconjg( a( i, pvt ) )
                  a( i, pvt ) = ztemp
  140          CONTINUE
               a( j, pvt ) = dconjg( a( j, pvt ) )
*
*              Swap dot products and PIV
*
               dtemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = dtemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J
*
            IF( j.LT.n ) THEN
               CALL zlacgv( j-1, a( 1, j ), 1 )
               CALL zgemv( 'Trans', j-1, n-j, -cone, a( 1, j+1 ), lda,
     $                     a( 1, j ), 1, cone, a( j, j+1 ), lda )
               CALL zlacgv( j-1, a( 1, j ), 1 )
               CALL zdscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
*
  150    CONTINUE
*
      ELSE
*
*        Compute the Cholesky factorization P**T * A * P = L * L**H
*
         DO 180 j = 1, n
*
*        Find pivot, test for exit, else swap rows and columns
*        Update dot products, compute possible pivots which are
*        stored in the second half of WORK
*
            DO 160 i = j, n
*
               IF( j.GT.1 ) THEN
                  work( i ) = work( i ) +
     $                        dble( dconjg( a( i, j-1 ) )*
     $                              a( i, j-1 ) )
               END IF
               work( n+i ) = dble( a( i, i ) ) - work( i )
*
  160       CONTINUE
*
            IF( j.GT.1 ) THEN
               itemp = maxloc( work( (n+j):(2*n) ), 1 )
               pvt = itemp + j - 1
               ajj = work( n+pvt )
               IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                  a( j, j ) = ajj
                  GO TO 190
               END IF
            END IF
*
            IF( j.NE.pvt ) THEN
*
*              Pivot OK, so can now swap pivot rows and columns
*
               a( pvt, pvt ) = a( j, j )
               CALL zswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
               IF( pvt.LT.n )
     $            CALL zswap( n-pvt, a( pvt+1, j ), 1, a( pvt+1, pvt ),
     $                        1 )
               DO 170 i = j + 1, pvt - 1
                  ztemp = dconjg( a( i, j ) )
                  a( i, j ) = dconjg( a( pvt, i ) )
                  a( pvt, i ) = ztemp
  170          CONTINUE
               a( pvt, j ) = dconjg( a( pvt, j ) )
*
*              Swap dot products and PIV
*
               dtemp = work( j )
               work( j ) = work( pvt )
               work( pvt ) = dtemp
               itemp = piv( pvt )
               piv( pvt ) = piv( j )
               piv( j ) = itemp
            END IF
*
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J
*
            IF( j.LT.n ) THEN
               CALL zlacgv( j-1, a( j, 1 ), lda )
               CALL zgemv( 'No Trans', n-j, j-1, -cone, a( j+1, 1 ),
     $                     lda, a( j, 1 ), lda, cone, a( j+1, j ), 1 )
               CALL zlacgv( j-1, a( j, 1 ), lda )
               CALL zdscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
*
  180    CONTINUE
*
      END IF
*
*     Ran to completion, A has full rank
*
      rank = n
*
      GO TO 200
  190 CONTINUE
*
*     Rank is number of steps completed.  Set INFO = 1 to signal
*     that the factorization cannot be used to solve a system.
*
      rank = j - 1
      info = 1
*
  200 CONTINUE
      RETURN
*
*     End of ZPSTF2
*
      END