LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zunmbr()

subroutine zunmbr ( character vect,
character side,
character trans,
integer m,
integer n,
integer k,
complex*16, dimension( lda, * ) a,
integer lda,
complex*16, dimension( * ) tau,
complex*16, dimension( ldc, * ) c,
integer ldc,
complex*16, dimension( * ) work,
integer lwork,
integer info )

ZUNMBR

Download ZUNMBR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> If VECT = 'Q', ZUNMBR overwrites the general complex M-by-N matrix C
!> with
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'C':      Q**H * C       C * Q**H
!>
!> If VECT = 'P', ZUNMBR overwrites the general complex M-by-N matrix C
!> with
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      P * C          C * P
!> TRANS = 'C':      P**H * C       C * P**H
!>
!> Here Q and P**H are the unitary matrices determined by ZGEBRD when
!> reducing a complex matrix A to bidiagonal form: A = Q * B * P**H. Q
!> and P**H are defined as products of elementary reflectors H(i) and
!> G(i) respectively.
!>
!> Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
!> order of the unitary matrix Q or P**H that is applied.
!>
!> If VECT = 'Q', A is assumed to have been an NQ-by-K matrix:
!> if nq >= k, Q = H(1) H(2) . . . H(k);
!> if nq < k, Q = H(1) H(2) . . . H(nq-1).
!>
!> If VECT = 'P', A is assumed to have been a K-by-NQ matrix:
!> if k < nq, P = G(1) G(2) . . . G(k);
!> if k >= nq, P = G(1) G(2) . . . G(nq-1).
!>
Parameters
[in]VECT
!>          VECT is CHARACTER*1
!>          = 'Q': apply Q or Q**H;
!>          = 'P': apply P or P**H.
!>
[in]SIDE
!>          SIDE is CHARACTER*1
!>          = 'L': apply Q, Q**H, P or P**H from the Left;
!>          = 'R': apply Q, Q**H, P or P**H from the Right.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          = 'N':  No transpose, apply Q or P;
!>          = 'C':  Conjugate transpose, apply Q**H or P**H.
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix C. M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix C. N >= 0.
!>
[in]K
!>          K is INTEGER
!>          If VECT = 'Q', the number of columns in the original
!>          matrix reduced by ZGEBRD.
!>          If VECT = 'P', the number of rows in the original
!>          matrix reduced by ZGEBRD.
!>          K >= 0.
!>
[in]A
!>          A is COMPLEX*16 array, dimension
!>                                (LDA,min(nq,K)) if VECT = 'Q'
!>                                (LDA,nq)        if VECT = 'P'
!>          The vectors which define the elementary reflectors H(i) and
!>          G(i), whose products determine the matrices Q and P, as
!>          returned by ZGEBRD.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.
!>          If VECT = 'Q', LDA >= max(1,nq);
!>          if VECT = 'P', LDA >= max(1,min(nq,K)).
!>
[in]TAU
!>          TAU is COMPLEX*16 array, dimension (min(nq,K))
!>          TAU(i) must contain the scalar factor of the elementary
!>          reflector H(i) or G(i) which determines Q or P, as returned
!>          by ZGEBRD in the array argument TAUQ or TAUP.
!>
[in,out]C
!>          C is COMPLEX*16 array, dimension (LDC,N)
!>          On entry, the M-by-N matrix C.
!>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q
!>          or P*C or P**H*C or C*P or C*P**H.
!>
[in]LDC
!>          LDC is INTEGER
!>          The leading dimension of the array C. LDC >= max(1,M).
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK.
!>          If SIDE = 'L', LWORK >= max(1,N);
!>          if SIDE = 'R', LWORK >= max(1,M);
!>          if N = 0 or M = 0, LWORK >= 1.
!>          For optimum performance LWORK >= max(1,N*NB) if SIDE = 'L',
!>          and LWORK >= max(1,M*NB) if SIDE = 'R', where NB is the
!>          optimal blocksize. (NB = 0 if M = 0 or N = 0.)
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 192 of file zunmbr.f.

194*
195* -- LAPACK computational routine --
196* -- LAPACK is a software package provided by Univ. of Tennessee, --
197* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
198*
199* .. Scalar Arguments ..
200 CHARACTER SIDE, TRANS, VECT
201 INTEGER INFO, K, LDA, LDC, LWORK, M, N
202* ..
203* .. Array Arguments ..
204 COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
205* ..
206*
207* =====================================================================
208*
209* .. Local Scalars ..
210 LOGICAL APPLYQ, LEFT, LQUERY, NOTRAN
211 CHARACTER TRANST
212 INTEGER I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
213* ..
214* .. External Functions ..
215 LOGICAL LSAME
216 INTEGER ILAENV
217 EXTERNAL lsame, ilaenv
218* ..
219* .. External Subroutines ..
220 EXTERNAL xerbla, zunmlq, zunmqr
221* ..
222* .. Intrinsic Functions ..
223 INTRINSIC max, min
224* ..
225* .. Executable Statements ..
226*
227* Test the input arguments
228*
229 info = 0
230 applyq = lsame( vect, 'Q' )
231 left = lsame( side, 'L' )
232 notran = lsame( trans, 'N' )
233 lquery = ( lwork.EQ.-1 )
234*
235* NQ is the order of Q or P and NW is the minimum dimension of WORK
236*
237 IF( left ) THEN
238 nq = m
239 nw = max( 1, n )
240 ELSE
241 nq = n
242 nw = max( 1, m )
243 END IF
244 IF( .NOT.applyq .AND. .NOT.lsame( vect, 'P' ) ) THEN
245 info = -1
246 ELSE IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
247 info = -2
248 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
249 info = -3
250 ELSE IF( m.LT.0 ) THEN
251 info = -4
252 ELSE IF( n.LT.0 ) THEN
253 info = -5
254 ELSE IF( k.LT.0 ) THEN
255 info = -6
256 ELSE IF( ( applyq .AND. lda.LT.max( 1, nq ) ) .OR.
257 $ ( .NOT.applyq .AND. lda.LT.max( 1, min( nq, k ) ) ) )
258 $ THEN
259 info = -8
260 ELSE IF( ldc.LT.max( 1, m ) ) THEN
261 info = -11
262 ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
263 info = -13
264 END IF
265*
266 IF( info.EQ.0 ) THEN
267 IF( m.GT.0 .AND. n.GT.0 ) THEN
268 IF( applyq ) THEN
269 IF( left ) THEN
270 nb = ilaenv( 1, 'ZUNMQR', side // trans, m-1, n,
271 $ m-1,
272 $ -1 )
273 ELSE
274 nb = ilaenv( 1, 'ZUNMQR', side // trans, m, n-1,
275 $ n-1,
276 $ -1 )
277 END IF
278 ELSE
279 IF( left ) THEN
280 nb = ilaenv( 1, 'ZUNMLQ', side // trans, m-1, n,
281 $ m-1,
282 $ -1 )
283 ELSE
284 nb = ilaenv( 1, 'ZUNMLQ', side // trans, m, n-1,
285 $ n-1,
286 $ -1 )
287 END IF
288 END IF
289 lwkopt = nw*nb
290 ELSE
291 lwkopt = 1
292 END IF
293 work( 1 ) = lwkopt
294 END IF
295*
296 IF( info.NE.0 ) THEN
297 CALL xerbla( 'ZUNMBR', -info )
298 RETURN
299 ELSE IF( lquery ) THEN
300 RETURN
301 END IF
302*
303* Quick return if possible
304*
305 IF( m.EQ.0 .OR. n.EQ.0 )
306 $ RETURN
307*
308 IF( applyq ) THEN
309*
310* Apply Q
311*
312 IF( nq.GE.k ) THEN
313*
314* Q was determined by a call to ZGEBRD with nq >= k
315*
316 CALL zunmqr( side, trans, m, n, k, a, lda, tau, c, ldc,
317 $ work, lwork, iinfo )
318 ELSE IF( nq.GT.1 ) THEN
319*
320* Q was determined by a call to ZGEBRD with nq < k
321*
322 IF( left ) THEN
323 mi = m - 1
324 ni = n
325 i1 = 2
326 i2 = 1
327 ELSE
328 mi = m
329 ni = n - 1
330 i1 = 1
331 i2 = 2
332 END IF
333 CALL zunmqr( side, trans, mi, ni, nq-1, a( 2, 1 ), lda,
334 $ tau,
335 $ c( i1, i2 ), ldc, work, lwork, iinfo )
336 END IF
337 ELSE
338*
339* Apply P
340*
341 IF( notran ) THEN
342 transt = 'C'
343 ELSE
344 transt = 'N'
345 END IF
346 IF( nq.GT.k ) THEN
347*
348* P was determined by a call to ZGEBRD with nq > k
349*
350 CALL zunmlq( side, transt, m, n, k, a, lda, tau, c, ldc,
351 $ work, lwork, iinfo )
352 ELSE IF( nq.GT.1 ) THEN
353*
354* P was determined by a call to ZGEBRD with nq <= k
355*
356 IF( left ) THEN
357 mi = m - 1
358 ni = n
359 i1 = 2
360 i2 = 1
361 ELSE
362 mi = m
363 ni = n - 1
364 i1 = 1
365 i2 = 2
366 END IF
367 CALL zunmlq( side, transt, mi, ni, nq-1, a( 1, 2 ), lda,
368 $ tau, c( i1, i2 ), ldc, work, lwork, iinfo )
369 END IF
370 END IF
371 work( 1 ) = lwkopt
372 RETURN
373*
374* End of ZUNMBR
375*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
zunmlq
subroutine zunmlq(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
ZUNMLQ
Definition zunmlq.f:165
zunmqr
subroutine zunmqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
ZUNMQR
Definition zunmqr.f:165
Here is the call graph for this function:
Here is the caller graph for this function: