cgbcon()

subroutine cgbcon	(	character	norm,
		integer	n,
		integer	kl,
		integer	ku,
		complex, dimension( ldab, * )	ab,
		integer	ldab,
		integer, dimension( * )	ipiv,
		real	anorm,
		real	rcond,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	info )

CGBCON

Download CGBCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGBCON estimates the reciprocal of the condition number of a complex
!> general band matrix A, in either the 1-norm or the infinity-norm,
!> using the LU factorization computed by CGBTRF.
!>
!> An estimate is obtained for norm(inv(A)), and the reciprocal of the
!> condition number is computed as
!>    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
!> 

Parameters

[in]	NORM	!> NORM is CHARACTER*1 !> Specifies whether the 1-norm condition number or the !> infinity-norm condition number is required: !> = '1' or 'O': 1-norm; !> = 'I': Infinity-norm. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in]	AB	!> AB is COMPLEX array, dimension (LDAB,N) !> Details of the LU factorization of the band matrix A, as !> computed by CGBTRF. U is stored as an upper triangular band !> matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and !> the multipliers used during the factorization are stored in !> rows KL+KU+2 to 2*KL+KU+1. !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= 2*KL+KU+1. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> The pivot indices; for 1 <= i <= N, row i of the matrix was !> interchanged with row IPIV(i). !>
[in]	ANORM	!> ANORM is REAL !> If NORM = '1' or 'O', the 1-norm of the original matrix A. !> If NORM = 'I', the infinity-norm of the original matrix A. !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal of the condition number of the matrix A, !> computed as RCOND = 1/(norm(A) * norm(inv(A))). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*N) !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 143 of file cgbcon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            INFO, KL, KU, LDAB, N
      REAL               ANORM, RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               RWORK( * )
      COMPLEX            AB( LDAB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LNOTI, ONENRM
      CHARACTER          NORMIN
      INTEGER            IX, J, JP, KASE, KASE1, KD, LM
      REAL               AINVNM, SCALE, SMLNUM
      COMPLEX            T, ZDUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAMCH
      COMPLEX            CDOTC
      EXTERNAL           lsame, icamax, slamch, cdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, clacn2, clatbs, csrscl,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, min, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 ) THEN
         info = -3
      ELSE IF( ku.LT.0 ) THEN
         info = -4
      ELSE IF( ldab.LT.2*kl+ku+1 ) THEN
         info = -6
      ELSE IF( anorm.LT.zero ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGBCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      END IF
*
      smlnum = slamch( 'Safe minimum' )
*
*     Estimate the norm of inv(A).
*
      ainvnm = zero
      normin = 'N'
      IF( onenrm ) THEN
         kase1 = 1
      ELSE
         kase1 = 2
      END IF
      kd = kl + ku + 1
      lnoti = kl.GT.0
      kase = 0
   10 CONTINUE
      CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.kase1 ) THEN
*
*           Multiply by inv(L).
*
            IF( lnoti ) THEN
               DO 20 j = 1, n - 1
                  lm = min( kl, n-j )
                  jp = ipiv( j )
                  t = work( jp )
                  IF( jp.NE.j ) THEN
                     work( jp ) = work( j )
                     work( j ) = t
                  END IF
                  CALL caxpy( lm, -t, ab( kd+1, j ), 1, work( j+1 ),
     $                        1 )
   20          CONTINUE
            END IF
*
*           Multiply by inv(U).
*
            CALL clatbs( 'Upper', 'No transpose', 'Non-unit', normin,
     $                   n,
     $                   kl+ku, ab, ldab, work, scale, rwork, info )
         ELSE
*
*           Multiply by inv(U**H).
*
            CALL clatbs( 'Upper', 'Conjugate transpose', 'Non-unit',
     $                   normin, n, kl+ku, ab, ldab, work, scale, rwork,
     $                   info )
*
*           Multiply by inv(L**H).
*
            IF( lnoti ) THEN
               DO 30 j = n - 1, 1, -1
                  lm = min( kl, n-j )
                  work( j ) = work( j ) - cdotc( lm, ab( kd+1, j ),
     $                  1,
     $                        work( j+1 ), 1 )
                  jp = ipiv( j )
                  IF( jp.NE.j ) THEN
                     t = work( jp )
                     work( jp ) = work( j )
                     work( j ) = t
                  END IF
   30          CONTINUE
            END IF
         END IF
*
*        Divide X by 1/SCALE if doing so will not cause overflow.
*
         normin = 'Y'
         IF( scale.NE.one ) THEN
            ix = icamax( n, work, 1 )
            IF( scale.LT.cabs1( work( ix ) )*smlnum .OR. scale.EQ.zero )
     $         GO TO 40
            CALL csrscl( n, scale, work, 1 )
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
   40 CONTINUE
      RETURN
*
*     End of CGBCON
*

Here is the call graph for this function:

Here is the caller graph for this function: