chegs2()

subroutine chegs2	(	integer	itype,
		character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		integer	info
	)

CHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorization results obtained from cpotrf (unblocked algorithm).

Download CHEGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CHEGS2 reduces a complex Hermitian-definite generalized
 eigenproblem to standard form.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H *A*L.

 B must have been previously factorized as U**H *U or L*L**H by ZPOTRF.

Parameters

[in]	ITYPE	ITYPE is INTEGER = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H); = 2 or 3: compute U*A*U**H or L**H *A*L.
[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored, and how B has been factorized. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrices A and B. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading n by n upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the transformed matrix, stored in the same format as A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in,out]	B	B is COMPLEX array, dimension (LDB,N) The triangular factor from the Cholesky factorization of B, as returned by CPOTRF. B is modified by the routine but restored on exit.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 127 of file chegs2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, HALF
      parameter( one = 1.0e+0, half = 0.5e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            K
      REAL               AKK, BKK
      COMPLEX            CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, cher2, clacgv, csscal, ctrmv, ctrsv,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHEGS2', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**H)*A*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of A(k:n,k:n)
*
               akk = real( a( k, k ) )
               bkk = real( b( k, k ) )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( k, k+1 ), lda )
                  ct = -half*akk
                  CALL clacgv( n-k, a( k, k+1 ), lda )
                  CALL clacgv( n-k, b( k, k+1 ), ldb )
                  CALL caxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL cher2( uplo, n-k, -cone, a( k, k+1 ), lda,
     $                        b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
                  CALL caxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL clacgv( n-k, b( k, k+1 ), ldb )
                  CALL ctrsv( uplo, 'Conjugate transpose', 'Non-unit',
     $                        n-k, b( k+1, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL clacgv( n-k, a( k, k+1 ), lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L**H)
*
            DO 20 k = 1, n
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = real( a( k, k ) )
               bkk = real( b( k, k ) )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( k+1, k ), 1 )
                  ct = -half*akk
                  CALL caxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL cher2( uplo, n-k, -cone, a( k+1, k ), 1,
     $                        b( k+1, k ), 1, a( k+1, k+1 ), lda )
                  CALL caxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL ctrsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
               END IF
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**H
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = real( a( k, k ) )
               bkk = real( b( k, k ) )
               CALL ctrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
     $                     ldb, a( 1, k ), 1 )
               ct = half*akk
               CALL caxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL cher2( uplo, k-1, cone, a( 1, k ), 1, b( 1, k ), 1,
     $                     a, lda )
               CALL caxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL csscal( k-1, bkk, a( 1, k ), 1 )
               a( k, k ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L**H *A*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(1:k,1:k)
*
               akk = real( a( k, k ) )
               bkk = real( b( k, k ) )
               CALL clacgv( k-1, a( k, 1 ), lda )
               CALL ctrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
     $                     b, ldb, a( k, 1 ), lda )
               ct = half*akk
               CALL clacgv( k-1, b( k, 1 ), ldb )
               CALL caxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL cher2( uplo, k-1, cone, a( k, 1 ), lda, b( k, 1 ),
     $                     ldb, a, lda )
               CALL caxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL clacgv( k-1, b( k, 1 ), ldb )
               CALL csscal( k-1, bkk, a( k, 1 ), lda )
               CALL clacgv( k-1, a( k, 1 ), lda )
               a( k, k ) = akk*bkk**2
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of CHEGS2
*

Here is the call graph for this function:

Here is the caller graph for this function: