ctrsv.f

Go to the documentation of this file.

*> \brief \b CTRSV
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CTRSV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
*
*       .. Scalar Arguments ..
*       INTEGER INCX,LDA,N
*       CHARACTER DIAG,TRANS,UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX A(LDA,*),X(*)
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CTRSV  solves one of the systems of equations
*>
*>    A*x = b,   or   A**T*x = b,   or   A**H*x = b,
*>
*> where b and x are n element vectors and A is an n by n unit, or
*> non-unit, upper or lower triangular matrix.
*>
*> No test for singularity or near-singularity is included in this
*> routine. Such tests must be performed before calling this routine.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>           On entry, UPLO specifies whether the matrix is an upper or
*>           lower triangular matrix as follows:
*>
*>              UPLO = 'U' or 'u'   A is an upper triangular matrix.
*>
*>              UPLO = 'L' or 'l'   A is a lower triangular matrix.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>           On entry, TRANS specifies the equations to be solved as
*>           follows:
*>
*>              TRANS = 'N' or 'n'   A*x = b.
*>
*>              TRANS = 'T' or 't'   A**T*x = b.
*>
*>              TRANS = 'C' or 'c'   A**H*x = b.
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>           On entry, DIAG specifies whether or not A is unit
*>           triangular as follows:
*>
*>              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
*>
*>              DIAG = 'N' or 'n'   A is not assumed to be unit
*>                                  triangular.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the order of the matrix A.
*>           N must be at least zero.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension ( LDA, N )
*>           Before entry with  UPLO = 'U' or 'u', the leading n by n
*>           upper triangular part of the array A must contain the upper
*>           triangular matrix and the strictly lower triangular part of
*>           A is not referenced.
*>           Before entry with UPLO = 'L' or 'l', the leading n by n
*>           lower triangular part of the array A must contain the lower
*>           triangular matrix and the strictly upper triangular part of
*>           A is not referenced.
*>           Note that when  DIAG = 'U' or 'u', the diagonal elements of
*>           A are not referenced either, but are assumed to be unity.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>           On entry, LDA specifies the first dimension of A as declared
*>           in the calling (sub) program. LDA must be at least
*>           max( 1, n ).
*> \endverbatim
*>
*> \param[in,out] X
*> \verbatim
*>          X is COMPLEX array, dimension at least
*>           ( 1 + ( n - 1 )*abs( INCX ) ).
*>           Before entry, the incremented array X must contain the n
*>           element right-hand side vector b. On exit, X is overwritten
*>           with the solution vector x.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_blas_level2
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  Level 2 Blas routine.
*>
*>  -- Written on 22-October-1986.
*>     Jack Dongarra, Argonne National Lab.
*>     Jeremy Du Croz, Nag Central Office.
*>     Sven Hammarling, Nag Central Office.
*>     Richard Hanson, Sandia National Labs.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE ctrsv(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,LDA,N
      CHARACTER DIAG,TRANS,UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX A(LDA,*),X(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX ZERO
      parameter(zero= (0.0e+0,0.0e+0))
*     ..
*     .. Local Scalars ..
      COMPLEX TEMP
      INTEGER I,INFO,IX,J,JX,KX
      LOGICAL NOCONJ,NOUNIT
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC conjg,max
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
     +         .NOT.lsame(trans,'C')) THEN
          info = 2
      ELSE IF (.NOT.lsame(diag,'U') .AND. .NOT.lsame(diag,'N')) THEN
          info = 3
      ELSE IF (n.LT.0) THEN
          info = 4
      ELSE IF (lda.LT.max(1,n)) THEN
          info = 6
      ELSE IF (incx.EQ.0) THEN
          info = 8
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('CTRSV ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF (n.EQ.0) RETURN
*
      noconj = lsame(trans,'T')
      nounit = lsame(diag,'N')
*
*     Set up the start point in X if the increment is not unity. This
*     will be  ( N - 1 )*INCX  too small for descending loops.
*
      IF (incx.LE.0) THEN
          kx = 1 - (n-1)*incx
      ELSE IF (incx.NE.1) THEN
          kx = 1
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through A.
*
      IF (lsame(trans,'N')) THEN
*
*        Form  x := inv( A )*x.
*
          IF (lsame(uplo,'U')) THEN
              IF (incx.EQ.1) THEN
                  DO 20 j = n,1,-1
                      IF (x(j).NE.zero) THEN
                          IF (nounit) x(j) = x(j)/a(j,j)
                          temp = x(j)
                          DO 10 i = j - 1,1,-1
                              x(i) = x(i) - temp*a(i,j)
   10                     CONTINUE
                      END IF
   20             CONTINUE
              ELSE
                  jx = kx + (n-1)*incx
                  DO 40 j = n,1,-1
                      IF (x(jx).NE.zero) THEN
                          IF (nounit) x(jx) = x(jx)/a(j,j)
                          temp = x(jx)
                          ix = jx
                          DO 30 i = j - 1,1,-1
                              ix = ix - incx
                              x(ix) = x(ix) - temp*a(i,j)
   30                     CONTINUE
                      END IF
                      jx = jx - incx
   40             CONTINUE
              END IF
          ELSE
              IF (incx.EQ.1) THEN
                  DO 60 j = 1,n
                      IF (x(j).NE.zero) THEN
                          IF (nounit) x(j) = x(j)/a(j,j)
                          temp = x(j)
                          DO 50 i = j + 1,n
                              x(i) = x(i) - temp*a(i,j)
   50                     CONTINUE
                      END IF
   60             CONTINUE
              ELSE
                  jx = kx
                  DO 80 j = 1,n
                      IF (x(jx).NE.zero) THEN
                          IF (nounit) x(jx) = x(jx)/a(j,j)
                          temp = x(jx)
                          ix = jx
                          DO 70 i = j + 1,n
                              ix = ix + incx
                              x(ix) = x(ix) - temp*a(i,j)
   70                     CONTINUE
                      END IF
                      jx = jx + incx
   80             CONTINUE
              END IF
          END IF
      ELSE
*
*        Form  x := inv( A**T )*x  or  x := inv( A**H )*x.
*
          IF (lsame(uplo,'U')) THEN
              IF (incx.EQ.1) THEN
                  DO 110 j = 1,n
                      temp = x(j)
                      IF (noconj) THEN
                          DO 90 i = 1,j - 1
                              temp = temp - a(i,j)*x(i)
   90                     CONTINUE
                          IF (nounit) temp = temp/a(j,j)
                      ELSE
                          DO 100 i = 1,j - 1
                              temp = temp - conjg(a(i,j))*x(i)
  100                     CONTINUE
                          IF (nounit) temp = temp/conjg(a(j,j))
                      END IF
                      x(j) = temp
  110             CONTINUE
              ELSE
                  jx = kx
                  DO 140 j = 1,n
                      ix = kx
                      temp = x(jx)
                      IF (noconj) THEN
                          DO 120 i = 1,j - 1
                              temp = temp - a(i,j)*x(ix)
                              ix = ix + incx
  120                     CONTINUE
                          IF (nounit) temp = temp/a(j,j)
                      ELSE
                          DO 130 i = 1,j - 1
                              temp = temp - conjg(a(i,j))*x(ix)
                              ix = ix + incx
  130                     CONTINUE
                          IF (nounit) temp = temp/conjg(a(j,j))
                      END IF
                      x(jx) = temp
                      jx = jx + incx
  140             CONTINUE
              END IF
          ELSE
              IF (incx.EQ.1) THEN
                  DO 170 j = n,1,-1
                      temp = x(j)
                      IF (noconj) THEN
                          DO 150 i = n,j + 1,-1
                              temp = temp - a(i,j)*x(i)
  150                     CONTINUE
                          IF (nounit) temp = temp/a(j,j)
                      ELSE
                          DO 160 i = n,j + 1,-1
                              temp = temp - conjg(a(i,j))*x(i)
  160                     CONTINUE
                          IF (nounit) temp = temp/conjg(a(j,j))
                      END IF
                      x(j) = temp
  170             CONTINUE
              ELSE
                  kx = kx + (n-1)*incx
                  jx = kx
                  DO 200 j = n,1,-1
                      ix = kx
                      temp = x(jx)
                      IF (noconj) THEN
                          DO 180 i = n,j + 1,-1
                              temp = temp - a(i,j)*x(ix)
                              ix = ix - incx
  180                     CONTINUE
                          IF (nounit) temp = temp/a(j,j)
                      ELSE
                          DO 190 i = n,j + 1,-1
                              temp = temp - conjg(a(i,j))*x(ix)
                              ix = ix - incx
  190                     CONTINUE
                          IF (nounit) temp = temp/conjg(a(j,j))
                      END IF
                      x(jx) = temp
                      jx = jx - incx
  200             CONTINUE
              END IF
          END IF
      END IF
*
      RETURN
*
*     End of CTRSV
*
      END