cher2()

subroutine cher2	(	character	uplo,
		integer	n,
		complex	alpha,
		complex, dimension(*)	x,
		integer	incx,
		complex, dimension(*)	y,
		integer	incy,
		complex, dimension(lda,*)	a,
		integer	lda )

CHER2

Purpose:

!>
!> CHER2  performs the hermitian rank 2 operation
!>
!>    A := alpha*x*y**H + conjg( alpha )*y*x**H + A,
!>
!> where alpha is a scalar, x and y are n element vectors and A is an n
!> by n hermitian matrix.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> On entry, UPLO specifies whether the upper or lower !> triangular part of the array A is to be referenced as !> follows: !> !> UPLO = 'U' or 'u' Only the upper triangular part of A !> is to be referenced. !> !> UPLO = 'L' or 'l' Only the lower triangular part of A !> is to be referenced. !>
[in]	N	!> N is INTEGER !> On entry, N specifies the order of the matrix A. !> N must be at least zero. !>
[in]	ALPHA	!> ALPHA is COMPLEX !> On entry, ALPHA specifies the scalar alpha. !>
[in]	X	!> X is COMPLEX array, dimension at least !> ( 1 + ( n - 1 )*abs( INCX ) ). !> Before entry, the incremented array X must contain the n !> element vector x. !>
[in]	INCX	!> INCX is INTEGER !> On entry, INCX specifies the increment for the elements of !> X. INCX must not be zero. !>
[in]	Y	!> Y is COMPLEX array, dimension at least !> ( 1 + ( n - 1 )*abs( INCY ) ). !> Before entry, the incremented array Y must contain the n !> element vector y. !>
[in]	INCY	!> INCY is INTEGER !> On entry, INCY specifies the increment for the elements of !> Y. INCY must not be zero. !>
[in,out]	A	!> A is COMPLEX array, dimension ( LDA, N ) !> Before entry with UPLO = 'U' or 'u', the leading n by n !> upper triangular part of the array A must contain the upper !> triangular part of the hermitian matrix and the strictly !> lower triangular part of A is not referenced. On exit, the !> upper triangular part of the array A is overwritten by the !> upper triangular part of the updated matrix. !> Before entry with UPLO = 'L' or 'l', the leading n by n !> lower triangular part of the array A must contain the lower !> triangular part of the hermitian matrix and the strictly !> upper triangular part of A is not referenced. On exit, the !> lower triangular part of the array A is overwritten by the !> lower triangular part of the updated matrix. !> Note that the imaginary parts of the diagonal elements need !> not be set, they are assumed to be zero, and on exit they !> are set to zero. !>
[in]	LDA	!> LDA is INTEGER !> On entry, LDA specifies the first dimension of A as declared !> in the calling (sub) program. LDA must be at least !> max( 1, n ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  Level 2 Blas routine.
!>
!>  -- Written on 22-October-1986.
!>     Jack Dongarra, Argonne National Lab.
!>     Jeremy Du Croz, Nag Central Office.
!>     Sven Hammarling, Nag Central Office.
!>     Richard Hanson, Sandia National Labs.
!> 

Definition at line 149 of file cher2.f.

*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      COMPLEX ALPHA
      INTEGER INCX,INCY,LDA,N
      CHARACTER UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX A(LDA,*),X(*),Y(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX ZERO
      parameter(zero= (0.0e+0,0.0e+0))
*     ..
*     .. Local Scalars ..
      COMPLEX TEMP1,TEMP2
      INTEGER I,INFO,IX,IY,J,JX,JY,KX,KY
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC conjg,max,real
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (n.LT.0) THEN
          info = 2
      ELSE IF (incx.EQ.0) THEN
          info = 5
      ELSE IF (incy.EQ.0) THEN
          info = 7
      ELSE IF (lda.LT.max(1,n)) THEN
          info = 9
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('CHER2 ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF ((n.EQ.0) .OR. (alpha.EQ.zero)) RETURN
*
*     Set up the start points in X and Y if the increments are not both
*     unity.
*
      IF ((incx.NE.1) .OR. (incy.NE.1)) THEN
          IF (incx.GT.0) THEN
              kx = 1
          ELSE
              kx = 1 - (n-1)*incx
          END IF
          IF (incy.GT.0) THEN
              ky = 1
          ELSE
              ky = 1 - (n-1)*incy
          END IF
          jx = kx
          jy = ky
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through the triangular part
*     of A.
*
      IF (lsame(uplo,'U')) THEN
*
*        Form  A  when A is stored in the upper triangle.
*
          IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
              DO 20 j = 1,n
                  IF ((x(j).NE.zero) .OR. (y(j).NE.zero)) THEN
                      temp1 = alpha*conjg(y(j))
                      temp2 = conjg(alpha*x(j))
                      DO 10 i = 1,j - 1
                          a(i,j) = a(i,j) + x(i)*temp1 + y(i)*temp2
   10                 CONTINUE
                      a(j,j) = real(a(j,j)) +
     +                         real(x(j)*temp1+y(j)*temp2)
                  ELSE
                      a(j,j) = real(a(j,j))
                  END IF
   20         CONTINUE
          ELSE
              DO 40 j = 1,n
                  IF ((x(jx).NE.zero) .OR. (y(jy).NE.zero)) THEN
                      temp1 = alpha*conjg(y(jy))
                      temp2 = conjg(alpha*x(jx))
                      ix = kx
                      iy = ky
                      DO 30 i = 1,j - 1
                          a(i,j) = a(i,j) + x(ix)*temp1 + y(iy)*temp2
                          ix = ix + incx
                          iy = iy + incy
   30                 CONTINUE
                      a(j,j) = real(a(j,j)) +
     +                         real(x(jx)*temp1+y(jy)*temp2)
                  ELSE
                      a(j,j) = real(a(j,j))
                  END IF
                  jx = jx + incx
                  jy = jy + incy
   40         CONTINUE
          END IF
      ELSE
*
*        Form  A  when A is stored in the lower triangle.
*
          IF ((incx.EQ.1) .AND. (incy.EQ.1)) THEN
              DO 60 j = 1,n
                  IF ((x(j).NE.zero) .OR. (y(j).NE.zero)) THEN
                      temp1 = alpha*conjg(y(j))
                      temp2 = conjg(alpha*x(j))
                      a(j,j) = real(a(j,j)) +
     +                         real(x(j)*temp1+y(j)*temp2)
                      DO 50 i = j + 1,n
                          a(i,j) = a(i,j) + x(i)*temp1 + y(i)*temp2
   50                 CONTINUE
                  ELSE
                      a(j,j) = real(a(j,j))
                  END IF
   60         CONTINUE
          ELSE
              DO 80 j = 1,n
                  IF ((x(jx).NE.zero) .OR. (y(jy).NE.zero)) THEN
                      temp1 = alpha*conjg(y(jy))
                      temp2 = conjg(alpha*x(jx))
                      a(j,j) = real(a(j,j)) +
     +                         real(x(jx)*temp1+y(jy)*temp2)
                      ix = jx
                      iy = jy
                      DO 70 i = j + 1,n
                          ix = ix + incx
                          iy = iy + incy
                          a(i,j) = a(i,j) + x(ix)*temp1 + y(iy)*temp2
   70                 CONTINUE
                  ELSE
                      a(j,j) = real(a(j,j))
                  END IF
                  jx = jx + incx
                  jy = jy + incy
   80         CONTINUE
          END IF
      END IF
*
      RETURN
*
*     End of CHER2
*

Here is the call graph for this function:

Here is the caller graph for this function: