dspev()

subroutine dspev	(	character	jobz,
		character	uplo,
		integer	n,
		double precision, dimension( * )	ap,
		double precision, dimension( * )	w,
		double precision, dimension( ldz, * )	z,
		integer	ldz,
		double precision, dimension( * )	work,
		integer	info
	)

DSPEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices

Download DSPEV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DSPEV computes all the eigenvalues and, optionally, eigenvectors of a
 real symmetric matrix A in packed storage.

Parameters

[in]	JOBZ	JOBZ is CHARACTER*1 = 'N': Compute eigenvalues only; = 'V': Compute eigenvalues and eigenvectors.
[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	AP	AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n. On exit, AP is overwritten by values generated during the reduction to tridiagonal form. If UPLO = 'U', the diagonal and first superdiagonal of the tridiagonal matrix T overwrite the corresponding elements of A, and if UPLO = 'L', the diagonal and first subdiagonal of T overwrite the corresponding elements of A.
[out]	W	W is DOUBLE PRECISION array, dimension (N) If INFO = 0, the eigenvalues in ascending order.
[out]	Z	Z is DOUBLE PRECISION array, dimension (LDZ, N) If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal eigenvectors of the matrix A, with the i-th column of Z holding the eigenvector associated with W(i). If JOBZ = 'N', then Z is not referenced.
[in]	LDZ	LDZ is INTEGER The leading dimension of the array Z. LDZ >= 1, and if JOBZ = 'V', LDZ >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (3*N)
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = i, the algorithm failed to converge; i off-diagonal elements of an intermediate tridiagonal form did not converge to zero.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 129 of file dspev.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            INFO, LDZ, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AP( * ), W( * ), WORK( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            WANTZ
      INTEGER            IINFO, IMAX, INDE, INDTAU, INDWRK, ISCALE
      DOUBLE PRECISION   ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
     $                   SMLNUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLANSP
      EXTERNAL           lsame, dlamch, dlansp
*     ..
*     .. External Subroutines ..
      EXTERNAL           dopgtr, dscal, dsptrd, dsteqr, dsterf, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      wantz = lsame( jobz, 'V' )
*
      info = 0
      IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( lsame( uplo, 'U' ) .OR. lsame( uplo, 'L' ) ) )
     $          THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
         info = -7
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSPEV ', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( n.EQ.1 ) THEN
         w( 1 ) = ap( 1 )
         IF( wantz )
     $      z( 1, 1 ) = one
         RETURN
      END IF
*
*     Get machine constants.
*
      safmin = dlamch( 'Safe minimum' )
      eps = dlamch( 'Precision' )
      smlnum = safmin / eps
      bignum = one / smlnum
      rmin = sqrt( smlnum )
      rmax = sqrt( bignum )
*
*     Scale matrix to allowable range, if necessary.
*
      anrm = dlansp( 'M', uplo, n, ap, work )
      iscale = 0
      IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
         iscale = 1
         sigma = rmin / anrm
      ELSE IF( anrm.GT.rmax ) THEN
         iscale = 1
         sigma = rmax / anrm
      END IF
      IF( iscale.EQ.1 ) THEN
         CALL dscal( ( n*( n+1 ) ) / 2, sigma, ap, 1 )
      END IF
*
*     Call DSPTRD to reduce symmetric packed matrix to tridiagonal form.
*
      inde = 1
      indtau = inde + n
      CALL dsptrd( uplo, n, ap, w, work( inde ), work( indtau ), iinfo )
*
*     For eigenvalues only, call DSTERF.  For eigenvectors, first call
*     DOPGTR to generate the orthogonal matrix, then call DSTEQR.
*
      IF( .NOT.wantz ) THEN
         CALL dsterf( n, w, work( inde ), info )
      ELSE
         indwrk = indtau + n
         CALL dopgtr( uplo, n, ap, work( indtau ), z, ldz,
     $                work( indwrk ), iinfo )
         CALL dsteqr( jobz, n, w, work( inde ), z, ldz, work( indtau ),
     $                info )
      END IF
*
*     If matrix was scaled, then rescale eigenvalues appropriately.
*
      IF( iscale.EQ.1 ) THEN
         IF( info.EQ.0 ) THEN
            imax = n
         ELSE
            imax = info - 1
         END IF
         CALL dscal( imax, one / sigma, w, 1 )
      END IF
*
      RETURN
*
*     End of DSPEV
*

Here is the call graph for this function:

Here is the caller graph for this function: