zsyt01_rook()

subroutine zsyt01_rook	(	character	uplo,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldafac, * )	afac,
		integer	ldafac,
		integer, dimension( * )	ipiv,
		complex*16, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( * )	rwork,
		double precision	resid )

ZSYT01_ROOK

Purpose:

!>
!> ZSYT01_ROOK reconstructs a complex symmetric indefinite matrix A from its
!> block L*D*L' or U*D*U' factorization and computes the residual
!>    norm( C - A ) / ( N * norm(A) * EPS ),
!> where C is the reconstructed matrix, EPS is the machine epsilon,
!> L' is the transpose of L, and U' is the transpose of U.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> complex symmetric matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The original complex symmetric matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N) !>
[in]	AFAC	!> AFAC is COMPLEX*16 array, dimension (LDAFAC,N) !> The factored form of the matrix A. AFAC contains the block !> diagonal matrix D and the multipliers used to obtain the !> factor L or U from the block L*D*L' or U*D*U' factorization !> as computed by ZSYTRF_ROOK. !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. LDAFAC >= max(1,N). !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> The pivot indices from ZSYTRF_ROOK. !>
[out]	C	!> C is COMPLEX*16 array, dimension (LDC,N) !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) !> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 123 of file zsyt01_rook.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAFAC, LDC, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      DOUBLE PRECISION   ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANSY
      EXTERNAL           lsame, dlamch, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlaset, zlavsy_rook
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlansy( '1', uplo, n, a, lda, rwork )
*
*     Initialize C to the identity matrix.
*
      CALL zlaset( 'Full', n, n, czero, cone, c, ldc )
*
*     Call ZLAVSY_ROOK to form the product D * U' (or D * L' ).
*
      CALL zlavsy_rook( uplo, 'Transpose', 'Non-unit', n, n, afac,
     $              ldafac, ipiv, c, ldc, info )
*
*     Call ZLAVSY_ROOK again to multiply by U (or L ).
*
      CALL zlavsy_rook( uplo, 'No transpose', 'Unit', n, n, afac,
     $              ldafac, ipiv, c, ldc, info )
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 j = 1, n
            DO 10 i = 1, j
               c( i, j ) = c( i, j ) - a( i, j )
   10       CONTINUE
   20    CONTINUE
      ELSE
         DO 40 j = 1, n
            DO 30 i = j, n
               c( i, j ) = c( i, j ) - a( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = zlansy( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of ZSYT01_ROOK
*

Here is the call graph for this function:

Here is the caller graph for this function: