LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dgebd2()

subroutine dgebd2 ( integer m,
integer n,
double precision, dimension( lda, * ) a,
integer lda,
double precision, dimension( * ) d,
double precision, dimension( * ) e,
double precision, dimension( * ) tauq,
double precision, dimension( * ) taup,
double precision, dimension( * ) work,
integer info )

DGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download DGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> DGEBD2 reduces a real general m by n matrix A to upper or lower
!> bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.
!>
!> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
!>
Parameters
[in]M
!>          M is INTEGER
!>          The number of rows in the matrix A.  M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns in the matrix A.  N >= 0.
!>
[in,out]A
!>          A is DOUBLE PRECISION array, dimension (LDA,N)
!>          On entry, the m by n general matrix to be reduced.
!>          On exit,
!>          if m >= n, the diagonal and the first superdiagonal are
!>            overwritten with the upper bidiagonal matrix B; the
!>            elements below the diagonal, with the array TAUQ, represent
!>            the orthogonal matrix Q as a product of elementary
!>            reflectors, and the elements above the first superdiagonal,
!>            with the array TAUP, represent the orthogonal matrix P as
!>            a product of elementary reflectors;
!>          if m < n, the diagonal and the first subdiagonal are
!>            overwritten with the lower bidiagonal matrix B; the
!>            elements below the first subdiagonal, with the array TAUQ,
!>            represent the orthogonal matrix Q as a product of
!>            elementary reflectors, and the elements above the diagonal,
!>            with the array TAUP, represent the orthogonal matrix P as
!>            a product of elementary reflectors.
!>          See Further Details.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,M).
!>
[out]D
!>          D is DOUBLE PRECISION array, dimension (min(M,N))
!>          The diagonal elements of the bidiagonal matrix B:
!>          D(i) = A(i,i).
!>
[out]E
!>          E is DOUBLE PRECISION array, dimension (min(M,N)-1)
!>          The off-diagonal elements of the bidiagonal matrix B:
!>          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
!>          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
!>
[out]TAUQ
!>          TAUQ is DOUBLE PRECISION array, dimension (min(M,N))
!>          The scalar factors of the elementary reflectors which
!>          represent the orthogonal matrix Q. See Further Details.
!>
[out]TAUP
!>          TAUP is DOUBLE PRECISION array, dimension (min(M,N))
!>          The scalar factors of the elementary reflectors which
!>          represent the orthogonal matrix P. See Further Details.
!>
[out]WORK
!>          WORK is DOUBLE PRECISION array, dimension (max(M,N))
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0: successful exit.
!>          < 0: if INFO = -i, the i-th argument had an illegal value.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The matrices Q and P are represented as products of elementary
!>  reflectors:
!>
!>  If m >= n,
!>
!>     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)
!>
!>  Each H(i) and G(i) has the form:
!>
!>     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T
!>
!>  where tauq and taup are real scalars, and v and u are real vectors;
!>  v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in A(i+1:m,i);
!>  u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in A(i,i+2:n);
!>  tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  If m < n,
!>
!>     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)
!>
!>  Each H(i) and G(i) has the form:
!>
!>     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T
!>
!>  where tauq and taup are real scalars, and v and u are real vectors;
!>  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
!>  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
!>  tauq is stored in TAUQ(i) and taup in TAUP(i).
!>
!>  The contents of A on exit are illustrated by the following examples:
!>
!>  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):
!>
!>    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
!>    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
!>    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
!>    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
!>    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
!>    (  v1  v2  v3  v4  v5 )
!>
!>  where d and e denote diagonal and off-diagonal elements of B, vi
!>  denotes an element of the vector defining H(i), and ui an element of
!>  the vector defining G(i).
!>

Definition at line 186 of file dgebd2.f.

187*
188* -- LAPACK computational routine --
189* -- LAPACK is a software package provided by Univ. of Tennessee, --
190* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
191*
192* .. Scalar Arguments ..
193 INTEGER INFO, LDA, M, N
194* ..
195* .. Array Arguments ..
196 DOUBLE PRECISION A( LDA, * ), D( * ), E( * ), TAUP( * ),
197 $ TAUQ( * ), WORK( * )
198* ..
199*
200* =====================================================================
201*
202* .. Parameters ..
203 DOUBLE PRECISION ZERO
204 parameter( zero = 0.0d+0 )
205* ..
206* .. Local Scalars ..
207 INTEGER I
208* ..
209* .. External Subroutines ..
210 EXTERNAL dlarf1f, dlarfg, xerbla
211* ..
212* .. Intrinsic Functions ..
213 INTRINSIC max, min
214* ..
215* .. Executable Statements ..
216*
217* Test the input parameters
218*
219 info = 0
220 IF( m.LT.0 ) THEN
221 info = -1
222 ELSE IF( n.LT.0 ) THEN
223 info = -2
224 ELSE IF( lda.LT.max( 1, m ) ) THEN
225 info = -4
226 END IF
227 IF( info.LT.0 ) THEN
228 CALL xerbla( 'DGEBD2', -info )
229 RETURN
230 END IF
231*
232 IF( m.GE.n ) THEN
233*
234* Reduce to upper bidiagonal form
235*
236 DO 10 i = 1, n
237*
238* Generate elementary reflector H(i) to annihilate A(i+1:m,i)
239*
240 CALL dlarfg( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
241 $ tauq( i ) )
242 d( i ) = a( i, i )
243*
244* Apply H(i) to A(i:m,i+1:n) from the left
245*
246 IF( i.LT.n )
247 $ CALL dlarf1f( 'Left', m-i+1, n-i, a( i, i ), 1,
248 $ tauq( i ),
249 $ a( i, i+1 ), lda, work )
250*
251 IF( i.LT.n ) THEN
252*
253* Generate elementary reflector G(i) to annihilate
254* A(i,i+2:n)
255*
256 CALL dlarfg( n-i, a( i, i+1 ), a( i, min( i+2, n ) ),
257 $ lda, taup( i ) )
258 e( i ) = a( i, i+1 )
259*
260* Apply G(i) to A(i+1:m,i+1:n) from the right
261*
262 CALL dlarf1f( 'Right', m-i, n-i, a( i, i+1 ), lda,
263 $ taup( i ), a( i+1, i+1 ), lda, work )
264 ELSE
265 taup( i ) = zero
266 END IF
267 10 CONTINUE
268 ELSE
269*
270* Reduce to lower bidiagonal form
271*
272 DO 20 i = 1, m
273*
274* Generate elementary reflector G(i) to annihilate A(i,i+1:n)
275*
276 CALL dlarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ),
277 $ lda,
278 $ taup( i ) )
279 d( i ) = a( i, i )
280*
281* Apply G(i) to A(i+1:m,i:n) from the right
282*
283 IF( i.LT.m )
284 $ CALL dlarf1f( 'Right', m-i, n-i+1, a( i, i ), lda,
285 $ taup( i ), a( i+1, i ), lda, work )
286*
287 IF( i.LT.m ) THEN
288*
289* Generate elementary reflector H(i) to annihilate
290* A(i+2:m,i)
291*
292 CALL dlarfg( m-i, a( i+1, i ), a( min( i+2, m ), i ),
293 $ 1,
294 $ tauq( i ) )
295 e( i ) = a( i+1, i )
296*
297* Apply H(i) to A(i+1:m,i+1:n) from the left
298*
299 CALL dlarf1f( 'Left', m-i, n-i, a( i+1, i ), 1,
300 $ tauq( i ),
301 $ a( i+1, i+1 ), lda, work )
302 ELSE
303 tauq( i ) = zero
304 END IF
305 20 CONTINUE
306 END IF
307 RETURN
308*
309* End of DGEBD2
310*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
dlarf1f
subroutine dlarf1f(side, m, n, v, incv, tau, c, ldc, work)
DLARF1F applies an elementary reflector to a general rectangular
Definition dlarf1f.f:157
dlarfg
subroutine dlarfg(n, alpha, x, incx, tau)
DLARFG generates an elementary reflector (Householder matrix).
Definition dlarfg.f:104
Here is the call graph for this function:
Here is the caller graph for this function: