dlarf1f()

subroutine dlarf1f	(	character	side,
		integer	m,
		integer	n,
		double precision, dimension( * )	v,
		integer	incv,
		double precision	tau,
		double precision, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( * )	work )

DLARF1F applies an elementary reflector to a general rectangular

Download DLARF1F + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DLARF1F applies a real elementary reflector H to a real m by n matrix
!> C, from either the left or the right. H is represented in the form
!>
!>       H = I - tau * v * v**T
!>
!> where tau is a real scalar and v is a real vector.
!>
!> If tau = 0, then H is taken to be the unit matrix.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': form H * C !> = 'R': form C * H !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. !>
[in]	V	!> V is DOUBLE PRECISION array, dimension !> (1 + (M-1)*abs(INCV)) if SIDE = 'L' !> or (1 + (N-1)*abs(INCV)) if SIDE = 'R' !> The vector v in the representation of H. V is not used if !> TAU = 0. V(1) is not referenced or modified. !>
[in]	INCV	!> INCV is INTEGER !> The increment between elements of v. INCV <> 0. !>
[in]	TAU	!> TAU is DOUBLE PRECISION !> The value tau in the representation of H. !>
[in,out]	C	!> C is DOUBLE PRECISION array, dimension (LDC,N) !> On entry, the m by n matrix C. !> On exit, C is overwritten by the matrix H * C if SIDE = 'L', !> or C * H if SIDE = 'R'. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension !> (N) if SIDE = 'L' !> or (M) if SIDE = 'R' !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 156 of file dlarf1f.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE
      INTEGER            INCV, LDC, M, N
      DOUBLE PRECISION   TAU
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   C( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            APPLYLEFT
      INTEGER            I, LASTV, LASTC
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv, dger, daxpy, dscal
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILADLR, ILADLC
      EXTERNAL           lsame, iladlr, iladlc
*     ..
*     .. Executable Statements ..
*
      applyleft = lsame( side, 'L' )
      lastv = 1
      lastc = 0
      IF( tau.NE.zero ) THEN
!     Set up variables for scanning V.  LASTV begins pointing to the end
!     of V.
         IF( applyleft ) THEN
            lastv = m
         ELSE
            lastv = n
         END IF
         IF( incv.GT.0 ) THEN
            i = 1 + (lastv-1) * incv
         ELSE
            i = 1
         END IF
!     Look for the last non-zero row in V.
!        Since we are assuming that V(1) = 1, and it is not stored, so we
!        shouldn't access it.
         DO WHILE( lastv.GT.1 .AND. v( i ).EQ.zero )
            lastv = lastv - 1
            i = i - incv
         END DO
         IF( applyleft ) THEN
!     Scan for the last non-zero column in C(1:lastv,:).
            lastc = iladlc(lastv, n, c, ldc)
         ELSE
!     Scan for the last non-zero row in C(:,1:lastv).
            lastc = iladlr(m, lastv, c, ldc)
         END IF
      END IF
      IF( lastc.EQ.0 ) THEN
         RETURN
      END IF
      IF( applyleft ) THEN
*
*        Form  H * C
*
         ! Check if lastv = 1. This means v = 1, So we just need to compute
         ! C := HC = (1-\tau)C.
         IF( lastv.EQ.1 ) THEN
*
*           C(1,1:lastc) := ( 1 - tau ) * C(1,1:lastc)
*
            CALL dscal(lastc, one - tau, c, ldc)
         ELSE
*
*           w(1:lastc,1) := C(1:lastv,1:lastc)**T * v(1:lastv,1)
*
            ! w(1:lastc,1) := C(2:lastv,1:lastc)**T * v(2:lastv,1)
            CALL dgemv( 'Transpose', lastv-1, lastc, one, c(1+1,1),
     $                  ldc, v(1+incv), incv, zero, work, 1)
            ! w(1:lastc,1) += C(1,1:lastc)**T * v(1,1) = C(1,1:lastc)**T
            CALL daxpy(lastc, one, c, ldc, work, 1)
*
*           C(1:lastv,1:lastc) := C(...) - tau * v(1:lastv,1) * w(1:lastc,1)**T
*
            ! C(1, 1:lastc)   := C(...) - tau * v(1,1) * w(1:lastc,1)**T
            !                  = C(...) - tau * w(1:lastc,1)**T
            CALL daxpy(lastc, -tau, work, 1, c, ldc)
            ! C(2:lastv,1:lastc) := C(...) - tau * v(2:lastv,1)*w(1:lastc,1)**T
            CALL dger(lastv-1, lastc, -tau, v(1+incv), incv, work, 1,
     $                  c(1+1,1), ldc)
         END IF
      ELSE
*
*        Form  C * H
*
         ! Check if n = 1. This means v = 1, so we just need to compute
         ! C := CH = C(1-\tau).
         IF( lastv.EQ.1 ) THEN
*
*           C(1:lastc,1) := ( 1 - tau ) * C(1:lastc,1)
*
            CALL dscal(lastc, one - tau, c, 1)
         ELSE
*
*           w(1:lastc,1) := C(1:lastc,1:lastv) * v(1:lastv,1)
*
            ! w(1:lastc,1) := C(1:lastc,2:lastv) * v(2:lastv,1)
            CALL dgemv( 'No transpose', lastc, lastv-1, one, 
     $         c(1,1+1), ldc, v(1+incv), incv, zero, work, 1 )
            ! w(1:lastc,1) += C(1:lastc,1) v(1,1) = C(1:lastc,1)
            CALL daxpy(lastc, one, c, 1, work, 1)
*
*           C(1:lastc,1:lastv) := C(...) - tau * w(1:lastc,1) * v(1:lastv,1)**T
*
            ! C(1:lastc,1)     := C(...) - tau * w(1:lastc,1) * v(1,1)**T
            !                   = C(...) - tau * w(1:lastc,1)
            CALL daxpy(lastc, -tau, work, 1, c, 1)
            ! C(1:lastc,2:lastv) := C(...) - tau * w(1:lastc,1) * v(2:lastv)**T
            CALL dger( lastc, lastv-1, -tau, work, 1, v(1+incv),
     $                  incv, c(1,1+1), ldc )
         END IF
      END IF
      RETURN
*
*     End of DLARF1F
*

Here is the call graph for this function:

Here is the caller graph for this function: