LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ ssysv()

 subroutine ssysv ( character uplo, integer n, integer nrhs, real, dimension( lda, * ) a, integer lda, integer, dimension( * ) ipiv, real, dimension( ldb, * ) b, integer ldb, real, dimension( * ) work, integer lwork, integer info )

SSYSV computes the solution to system of linear equations A * X = B for SY matrices

Purpose:
``` SSYSV computes the solution to a real system of linear equations
A * X = B,
where A is an N-by-N symmetric matrix and X and B are N-by-NRHS
matrices.

The diagonal pivoting method is used to factor A as
A = U * D * U**T,  if UPLO = 'U', or
A = L * D * L**T,  if UPLO = 'L',
where U (or L) is a product of permutation and unit upper (lower)
triangular matrices, and D is symmetric and block diagonal with
1-by-1 and 2-by-2 diagonal blocks.  The factored form of A is then
used to solve the system of equations A * X = B.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] N ``` N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.``` [in,out] A ``` A is REAL array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the block diagonal matrix D and the multipliers used to obtain the factor U or L from the factorization A = U*D*U**T or A = L*D*L**T as computed by SSYTRF.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [out] IPIV ``` IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D, as determined by SSYTRF. If IPIV(k) > 0, then rows and columns k and IPIV(k) were interchanged, and D(k,k) is a 1-by-1 diagonal block. If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k) is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) = IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.``` [in,out] B ``` B is REAL array, dimension (LDB,NRHS) On entry, the N-by-NRHS right hand side matrix B. On exit, if INFO = 0, the N-by-NRHS solution matrix X.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [out] WORK ``` WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.``` [in] LWORK ``` LWORK is INTEGER The length of WORK. LWORK >= 1, and for best performance LWORK >= max(1,N*NB), where NB is the optimal blocksize for SSYTRF. for LWORK < N, TRS will be done with Level BLAS 2 for LWORK >= N, TRS will be done with Level BLAS 3 If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, D(i,i) is exactly zero. The factorization has been completed, but the block diagonal matrix D is exactly singular, so the solution could not be computed.```

Definition at line 169 of file ssysv.f.

171*
172* -- LAPACK driver routine --
173* -- LAPACK is a software package provided by Univ. of Tennessee, --
174* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
175*
176* .. Scalar Arguments ..
177 CHARACTER UPLO
178 INTEGER INFO, LDA, LDB, LWORK, N, NRHS
179* ..
180* .. Array Arguments ..
181 INTEGER IPIV( * )
182 REAL A( LDA, * ), B( LDB, * ), WORK( * )
183* ..
184*
185* =====================================================================
186*
187* .. Local Scalars ..
188 LOGICAL LQUERY
189 INTEGER LWKOPT
190* ..
191* .. External Functions ..
192 LOGICAL LSAME
193 REAL SROUNDUP_LWORK
194 EXTERNAL lsame, sroundup_lwork
195* ..
196* .. External Subroutines ..
197 EXTERNAL xerbla, ssytrf, ssytrs, ssytrs2
198* ..
199* .. Intrinsic Functions ..
200 INTRINSIC max
201* ..
202* .. Executable Statements ..
203*
204* Test the input parameters.
205*
206 info = 0
207 lquery = ( lwork.EQ.-1 )
208 IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
209 info = -1
210 ELSE IF( n.LT.0 ) THEN
211 info = -2
212 ELSE IF( nrhs.LT.0 ) THEN
213 info = -3
214 ELSE IF( lda.LT.max( 1, n ) ) THEN
215 info = -5
216 ELSE IF( ldb.LT.max( 1, n ) ) THEN
217 info = -8
218 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
219 info = -10
220 END IF
221*
222 IF( info.EQ.0 ) THEN
223 IF( n.EQ.0 ) THEN
224 lwkopt = 1
225 ELSE
226 CALL ssytrf( uplo, n, a, lda, ipiv, work, -1, info )
227 lwkopt = int( work( 1 ) )
228 END IF
229 work( 1 ) = sroundup_lwork(lwkopt)
230 END IF
231*
232 IF( info.NE.0 ) THEN
233 CALL xerbla( 'SSYSV ', -info )
234 RETURN
235 ELSE IF( lquery ) THEN
236 RETURN
237 END IF
238*
239* Compute the factorization A = U*D*U**T or A = L*D*L**T.
240*
241 CALL ssytrf( uplo, n, a, lda, ipiv, work, lwork, info )
242 IF( info.EQ.0 ) THEN
243*
244* Solve the system A*X = B, overwriting B with X.
245*
246 IF ( lwork.LT.n ) THEN
247*
248* Solve with TRS ( Use Level BLAS 2)
249*
250 CALL ssytrs( uplo, n, nrhs, a, lda, ipiv, b, ldb, info )
251*
252 ELSE
253*
254* Solve with TRS2 ( Use Level BLAS 3)
255*
256 CALL ssytrs2( uplo,n,nrhs,a,lda,ipiv,b,ldb,work,info )
257*
258 END IF
259*
260 END IF
261*
262 work( 1 ) = sroundup_lwork(lwkopt)
263*
264 RETURN
265*
266* End of SSYSV
267*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine ssytrf(uplo, n, a, lda, ipiv, work, lwork, info)
SSYTRF
Definition ssytrf.f:182
subroutine ssytrs2(uplo, n, nrhs, a, lda, ipiv, b, ldb, work, info)
SSYTRS2
Definition ssytrs2.f:132
subroutine ssytrs(uplo, n, nrhs, a, lda, ipiv, b, ldb, info)
SSYTRS
Definition ssytrs.f:120
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Here is the call graph for this function:
Here is the caller graph for this function: