LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
sorgr2.f
Go to the documentation of this file.
1*> \brief \b SORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf (unblocked algorithm).
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SORGR2 + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sorgr2.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sorgr2.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sorgr2.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
22*
23* .. Scalar Arguments ..
24* INTEGER INFO, K, LDA, M, N
25* ..
26* .. Array Arguments ..
27* REAL A( LDA, * ), TAU( * ), WORK( * )
28* ..
29*
30*
31*> \par Purpose:
32* =============
33*>
34*> \verbatim
35*>
36*> SORGR2 generates an m by n real matrix Q with orthonormal rows,
37*> which is defined as the last m rows of a product of k elementary
38*> reflectors of order n
39*>
40*> Q = H(1) H(2) . . . H(k)
41*>
42*> as returned by SGERQF.
43*> \endverbatim
44*
45* Arguments:
46* ==========
47*
48*> \param[in] M
49*> \verbatim
50*> M is INTEGER
51*> The number of rows of the matrix Q. M >= 0.
52*> \endverbatim
53*>
54*> \param[in] N
55*> \verbatim
56*> N is INTEGER
57*> The number of columns of the matrix Q. N >= M.
58*> \endverbatim
59*>
60*> \param[in] K
61*> \verbatim
62*> K is INTEGER
63*> The number of elementary reflectors whose product defines the
64*> matrix Q. M >= K >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is REAL array, dimension (LDA,N)
70*> On entry, the (m-k+i)-th row must contain the vector which
71*> defines the elementary reflector H(i), for i = 1,2,...,k, as
72*> returned by SGERQF in the last k rows of its array argument
73*> A.
74*> On exit, the m by n matrix Q.
75*> \endverbatim
76*>
77*> \param[in] LDA
78*> \verbatim
79*> LDA is INTEGER
80*> The first dimension of the array A. LDA >= max(1,M).
81*> \endverbatim
82*>
83*> \param[in] TAU
84*> \verbatim
85*> TAU is REAL array, dimension (K)
86*> TAU(i) must contain the scalar factor of the elementary
87*> reflector H(i), as returned by SGERQF.
88*> \endverbatim
89*>
90*> \param[out] WORK
91*> \verbatim
92*> WORK is REAL array, dimension (M)
93*> \endverbatim
94*>
95*> \param[out] INFO
96*> \verbatim
97*> INFO is INTEGER
98*> = 0: successful exit
99*> < 0: if INFO = -i, the i-th argument has an illegal value
100*> \endverbatim
101*
102* Authors:
103* ========
104*
105*> \author Univ. of Tennessee
106*> \author Univ. of California Berkeley
107*> \author Univ. of Colorado Denver
108*> \author NAG Ltd.
109*
110*> \ingroup ungr2
111*
112* =====================================================================
113 SUBROUTINE sorgr2( M, N, K, A, LDA, TAU, WORK, INFO )
114*
115* -- LAPACK computational routine --
116* -- LAPACK is a software package provided by Univ. of Tennessee, --
117* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118*
119* .. Scalar Arguments ..
120 INTEGER INFO, K, LDA, M, N
121* ..
122* .. Array Arguments ..
123 REAL A( LDA, * ), TAU( * ), WORK( * )
124* ..
125*
126* =====================================================================
127*
128* .. Parameters ..
129 REAL ONE, ZERO
130 parameter( one = 1.0e+0, zero = 0.0e+0 )
131* ..
132* .. Local Scalars ..
133 INTEGER I, II, J, L
134* ..
135* .. External Subroutines ..
136 EXTERNAL slarf, sscal, xerbla
137* ..
138* .. Intrinsic Functions ..
139 INTRINSIC max
140* ..
141* .. Executable Statements ..
142*
143* Test the input arguments
144*
145 info = 0
146 IF( m.LT.0 ) THEN
147 info = -1
148 ELSE IF( n.LT.m ) THEN
149 info = -2
150 ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
151 info = -3
152 ELSE IF( lda.LT.max( 1, m ) ) THEN
153 info = -5
154 END IF
155 IF( info.NE.0 ) THEN
156 CALL xerbla( 'SORGR2', -info )
157 RETURN
158 END IF
159*
160* Quick return if possible
161*
162 IF( m.LE.0 )
163 $ RETURN
164*
165 IF( k.LT.m ) THEN
166*
167* Initialise rows 1:m-k to rows of the unit matrix
168*
169 DO 20 j = 1, n
170 DO 10 l = 1, m - k
171 a( l, j ) = zero
172 10 CONTINUE
173 IF( j.GT.n-m .AND. j.LE.n-k )
174 $ a( m-n+j, j ) = one
175 20 CONTINUE
176 END IF
177*
178 DO 40 i = 1, k
179 ii = m - k + i
180*
181* Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
182*
183 a( ii, n-m+ii ) = one
184 CALL slarf( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda, tau( i ),
185 $ a, lda, work )
186 CALL sscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
187 a( ii, n-m+ii ) = one - tau( i )
188*
189* Set A(m-k+i,n-k+i+1:n) to zero
190*
191 DO 30 l = n - m + ii + 1, n
192 a( ii, l ) = zero
193 30 CONTINUE
194 40 CONTINUE
195 RETURN
196*
197* End of SORGR2
198*
199 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarf(side, m, n, v, incv, tau, c, ldc, work)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition slarf.f:124
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
subroutine sorgr2(m, n, k, a, lda, tau, work, info)
SORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf...
Definition sorgr2.f:114