slatdf()

subroutine slatdf	(	integer	ijob,
		integer	n,
		real, dimension( ldz, * )	z,
		integer	ldz,
		real, dimension( * )	rhs,
		real	rdsum,
		real	rdscal,
		integer, dimension( * )	ipiv,
		integer, dimension( * )	jpiv )

SLATDF uses the LU factorization of the n-by-n matrix computed by sgetc2 and computes a contribution to the reciprocal Dif-estimate.

Download SLATDF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SLATDF uses the LU factorization of the n-by-n matrix Z computed by
!> SGETC2 and computes a contribution to the reciprocal Dif-estimate
!> by solving Z * x = b for x, and choosing the r.h.s. b such that
!> the norm of x is as large as possible. On entry RHS = b holds the
!> contribution from earlier solved sub-systems, and on return RHS = x.
!>
!> The factorization of Z returned by SGETC2 has the form Z = P*L*U*Q,
!> where P and Q are permutation matrices. L is lower triangular with
!> unit diagonal elements and U is upper triangular.
!> 

Parameters

[in]	IJOB	!> IJOB is INTEGER !> IJOB = 2: First compute an approximative null-vector e !> of Z using SGECON, e is normalized and solve for !> Zx = +-e - f with the sign giving the greater value !> of 2-norm(x). About 5 times as expensive as Default. !> IJOB .ne. 2: Local look ahead strategy where all entries of !> the r.h.s. b is chosen as either +1 or -1 (Default). !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Z. !>
[in]	Z	!> Z is REAL array, dimension (LDZ, N) !> On entry, the LU part of the factorization of the n-by-n !> matrix Z computed by SGETC2: Z = P * L * U * Q !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDA >= max(1, N). !>
[in,out]	RHS	!> RHS is REAL array, dimension N. !> On entry, RHS contains contributions from other subsystems. !> On exit, RHS contains the solution of the subsystem with !> entries according to the value of IJOB (see above). !>
[in,out]	RDSUM	!> RDSUM is REAL !> On entry, the sum of squares of computed contributions to !> the Dif-estimate under computation by STGSYL, where the !> scaling factor RDSCAL (see below) has been factored out. !> On exit, the corresponding sum of squares updated with the !> contributions from the current sub-system. !> If TRANS = 'T' RDSUM is not touched. !> NOTE: RDSUM only makes sense when STGSY2 is called by STGSYL. !>
[in,out]	RDSCAL	!> RDSCAL is REAL !> On entry, scaling factor used to prevent overflow in RDSUM. !> On exit, RDSCAL is updated w.r.t. the current contributions !> in RDSUM. !> If TRANS = 'T', RDSCAL is not touched. !> NOTE: RDSCAL only makes sense when STGSY2 is called by !> STGSYL. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= i <= N, row i of the !> matrix has been interchanged with row IPIV(i). !>
[in]	JPIV	!> JPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= j <= N, column j of the !> matrix has been interchanged with column JPIV(j). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

This routine is a further developed implementation of algorithm BSOLVE in [1] using complete pivoting in the LU factorization.

Contributors:

Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.

References:

!>
!>
!>  [1] Bo Kagstrom and Lars Westin,
!>      Generalized Schur Methods with Condition Estimators for
!>      Solving the Generalized Sylvester Equation, IEEE Transactions
!>      on Automatic Control, Vol. 34, No. 7, July 1989, pp 745-751.
!>
!>  [2] Peter Poromaa,
!>      On Efficient and Robust Estimators for the Separation
!>      between two Regular Matrix Pairs with Applications in
!>      Condition Estimation. Report IMINF-95.05, Departement of
!>      Computing Science, Umea University, S-901 87 Umea, Sweden, 1995.
!> 

Definition at line 167 of file slatdf.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IJOB, LDZ, N
      REAL               RDSCAL, RDSUM
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), JPIV( * )
      REAL               RHS( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            MAXDIM
      parameter( maxdim = 8 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J, K
      REAL               BM, BP, PMONE, SMINU, SPLUS, TEMP
*     ..
*     .. Local Arrays ..
      INTEGER            IWORK( MAXDIM )
      REAL               WORK( 4*MAXDIM ), XM( MAXDIM ), XP( MAXDIM )
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, sgecon, sgesc2, slassq,
     $                   slaswp,
     $                   sscal
*     ..
*     .. External Functions ..
      REAL               SASUM, SDOT
      EXTERNAL           sasum, sdot
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( ijob.NE.2 ) THEN
*
*        Apply permutations IPIV to RHS
*
         CALL slaswp( 1, rhs, ldz, 1, n-1, ipiv, 1 )
*
*        Solve for L-part choosing RHS either to +1 or -1.
*
         pmone = -one
*
         DO 10 j = 1, n - 1
            bp = rhs( j ) + one
            bm = rhs( j ) - one
            splus = one
*
*           Look-ahead for L-part RHS(1:N-1) = + or -1, SPLUS and
*           SMIN computed more efficiently than in BSOLVE [1].
*
            splus = splus + sdot( n-j, z( j+1, j ), 1, z( j+1, j ),
     $                            1 )
            sminu = sdot( n-j, z( j+1, j ), 1, rhs( j+1 ), 1 )
            splus = splus*rhs( j )
            IF( splus.GT.sminu ) THEN
               rhs( j ) = bp
            ELSE IF( sminu.GT.splus ) THEN
               rhs( j ) = bm
            ELSE
*
*              In this case the updating sums are equal and we can
*              choose RHS(J) +1 or -1. The first time this happens
*              we choose -1, thereafter +1. This is a simple way to
*              get good estimates of matrices like Byers well-known
*              example (see [1]). (Not done in BSOLVE.)
*
               rhs( j ) = rhs( j ) + pmone
               pmone = one
            END IF
*
*           Compute the remaining r.h.s.
*
            temp = -rhs( j )
            CALL saxpy( n-j, temp, z( j+1, j ), 1, rhs( j+1 ), 1 )
*
   10    CONTINUE
*
*        Solve for U-part, look-ahead for RHS(N) = +-1. This is not done
*        in BSOLVE and will hopefully give us a better estimate because
*        any ill-conditioning of the original matrix is transferred to U
*        and not to L. U(N, N) is an approximation to sigma_min(LU).
*
         CALL scopy( n-1, rhs, 1, xp, 1 )
         xp( n ) = rhs( n ) + one
         rhs( n ) = rhs( n ) - one
         splus = zero
         sminu = zero
         DO 30 i = n, 1, -1
            temp = one / z( i, i )
            xp( i ) = xp( i )*temp
            rhs( i ) = rhs( i )*temp
            DO 20 k = i + 1, n
               xp( i ) = xp( i ) - xp( k )*( z( i, k )*temp )
               rhs( i ) = rhs( i ) - rhs( k )*( z( i, k )*temp )
   20       CONTINUE
            splus = splus + abs( xp( i ) )
            sminu = sminu + abs( rhs( i ) )
   30    CONTINUE
         IF( splus.GT.sminu )
     $      CALL scopy( n, xp, 1, rhs, 1 )
*
*        Apply the permutations JPIV to the computed solution (RHS)
*
         CALL slaswp( 1, rhs, ldz, 1, n-1, jpiv, -1 )
*
*        Compute the sum of squares
*
         CALL slassq( n, rhs, 1, rdscal, rdsum )
*
      ELSE
*
*        IJOB = 2, Compute approximate nullvector XM of Z
*
         CALL sgecon( 'I', n, z, ldz, one, temp, work, iwork, info )
         CALL scopy( n, work( n+1 ), 1, xm, 1 )
*
*        Compute RHS
*
         CALL slaswp( 1, xm, ldz, 1, n-1, ipiv, -1 )
         temp = one / sqrt( sdot( n, xm, 1, xm, 1 ) )
         CALL sscal( n, temp, xm, 1 )
         CALL scopy( n, xm, 1, xp, 1 )
         CALL saxpy( n, one, rhs, 1, xp, 1 )
         CALL saxpy( n, -one, xm, 1, rhs, 1 )
         CALL sgesc2( n, z, ldz, rhs, ipiv, jpiv, temp )
         CALL sgesc2( n, z, ldz, xp, ipiv, jpiv, temp )
         IF( sasum( n, xp, 1 ).GT.sasum( n, rhs, 1 ) )
     $      CALL scopy( n, xp, 1, rhs, 1 )
*
*        Compute the sum of squares
*
         CALL slassq( n, rhs, 1, rdscal, rdsum )
*
      END IF
*
      RETURN
*
*     End of SLATDF
*

Here is the call graph for this function:

Here is the caller graph for this function: