sgesc2()

subroutine sgesc2	(	integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	rhs,
		integer, dimension( * )	ipiv,
		integer, dimension( * )	jpiv,
		real	scale )

SGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed by sgetc2.

Download SGESC2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SGESC2 solves a system of linear equations
!>
!>           A * X = scale* RHS
!>
!> with a general N-by-N matrix A using the LU factorization with
!> complete pivoting computed by SGETC2.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the LU part of the factorization of the n-by-n !> matrix A computed by SGETC2: A = P * L * U * Q !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1, N). !>
[in,out]	RHS	!> RHS is REAL array, dimension (N). !> On entry, the right hand side vector b. !> On exit, the solution vector X. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= i <= N, row i of the !> matrix has been interchanged with row IPIV(i). !>
[in]	JPIV	!> JPIV is INTEGER array, dimension (N). !> The pivot indices; for 1 <= j <= N, column j of the !> matrix has been interchanged with column JPIV(j). !>
[out]	SCALE	!> SCALE is REAL !> On exit, SCALE contains the scale factor. SCALE is chosen !> 0 <= SCALE <= 1 to prevent overflow in the solution. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.

Definition at line 111 of file sgesc2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, N
      REAL               SCALE
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), JPIV( * )
      REAL               A( LDA, * ), RHS( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO
      parameter( one = 1.0e+0, two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               BIGNUM, EPS, SMLNUM, TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaswp, sscal
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      REAL               SLAMCH
      EXTERNAL           isamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*      Set constant to control overflow
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' ) / eps
      bignum = one / smlnum
*
*     Apply permutations IPIV to RHS
*
      CALL slaswp( 1, rhs, lda, 1, n-1, ipiv, 1 )
*
*     Solve for L part
*
      DO 20 i = 1, n - 1
         DO 10 j = i + 1, n
            rhs( j ) = rhs( j ) - a( j, i )*rhs( i )
   10    CONTINUE
   20 CONTINUE
*
*     Solve for U part
*
      scale = one
*
*     Check for scaling
*
      i = isamax( n, rhs, 1 )
      IF( two*smlnum*abs( rhs( i ) ).GT.abs( a( n, n ) ) ) THEN
         temp = ( one / two ) / abs( rhs( i ) )
         CALL sscal( n, temp, rhs( 1 ), 1 )
         scale = scale*temp
      END IF
*
      DO 40 i = n, 1, -1
         temp = one / a( i, i )
         rhs( i ) = rhs( i )*temp
         DO 30 j = i + 1, n
            rhs( i ) = rhs( i ) - rhs( j )*( a( i, j )*temp )
   30    CONTINUE
   40 CONTINUE
*
*     Apply permutations JPIV to the solution (RHS)
*
      CALL slaswp( 1, rhs, lda, 1, n-1, jpiv, -1 )
      RETURN
*
*     End of SGESC2
*

Here is the call graph for this function:

Here is the caller graph for this function: