LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ zlaswlq()

 subroutine zlaswlq ( integer m, integer n, integer mb, integer nb, complex*16, dimension( lda, * ) a, integer lda, complex*16, dimension( ldt, *) t, integer ldt, complex*16, dimension( * ) work, integer lwork, integer info )

ZLASWLQ

Purpose:
``` ZLASWLQ computes a blocked Tall-Skinny LQ factorization of
a complexx M-by-N matrix A for M <= N:

A = ( L 0 ) *  Q,

where:

Q is a n-by-N orthogonal matrix, stored on exit in an implicit
form in the elements above the diagonal of the array A and in
the elements of the array T;
L is a lower-triangular M-by-M matrix stored on exit in
the elements on and below the diagonal of the array A.
0 is a M-by-(N-M) zero matrix, if M < N, and is not stored.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= M >= 0.``` [in] MB ``` MB is INTEGER The row block size to be used in the blocked QR. M >= MB >= 1``` [in] NB ``` NB is INTEGER The column block size to be used in the blocked QR. NB > 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, the elements on and below the diagonal of the array contain the N-by-N lower triangular matrix L; the elements above the diagonal represent Q by the rows of blocked V (see Further Details).``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [out] T ``` T is COMPLEX*16 array, dimension (LDT, N * Number_of_row_blocks) where Number_of_row_blocks = CEIL((N-M)/(NB-M)) The blocked upper triangular block reflectors stored in compact form as a sequence of upper triangular blocks. See Further Details below.``` [in] LDT ``` LDT is INTEGER The leading dimension of the array T. LDT >= MB.``` [out] WORK ` (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. LWORK >= MB*M. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```
Further Details:
``` Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations,
representing Q as a product of other orthogonal matrices
Q = Q(1) * Q(2) * . . . * Q(k)
where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
Q(1) zeros out the upper diagonal entries of rows 1:NB of A
Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
. . .

Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
stored under the diagonal of rows 1:MB of A, and by upper triangular
block reflectors, stored in array T(1:LDT,1:N).

Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
The last Q(k) may use fewer rows.

For more details of the overall algorithm, see the description of
Sequential TSQR in Section 2.2 of [1].

[1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
SIAM J. Sci. Comput, vol. 34, no. 1, 2012```

Definition at line 165 of file zlaswlq.f.

167*
168* -- LAPACK computational routine --
169* -- LAPACK is a software package provided by Univ. of Tennessee, --
170* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
171*
172* .. Scalar Arguments ..
173 INTEGER INFO, LDA, M, N, MB, NB, LWORK, LDT
174* ..
175* .. Array Arguments ..
176 COMPLEX*16 A( LDA, * ), WORK( * ), T( LDT, *)
177* ..
178*
179* =====================================================================
180*
181* ..
182* .. Local Scalars ..
183 LOGICAL LQUERY
184 INTEGER I, II, KK, CTR
185* ..
186* .. EXTERNAL FUNCTIONS ..
187 LOGICAL LSAME
188 EXTERNAL lsame
189* .. EXTERNAL SUBROUTINES ..
190 EXTERNAL zgelqt, ztplqt, xerbla
191* .. INTRINSIC FUNCTIONS ..
192 INTRINSIC max, min, mod
193* ..
194* .. EXECUTABLE STATEMENTS ..
195*
196* TEST THE INPUT ARGUMENTS
197*
198 info = 0
199*
200 lquery = ( lwork.EQ.-1 )
201*
202 IF( m.LT.0 ) THEN
203 info = -1
204 ELSE IF( n.LT.0 .OR. n.LT.m ) THEN
205 info = -2
206 ELSE IF( mb.LT.1 .OR. ( mb.GT.m .AND. m.GT.0 )) THEN
207 info = -3
208 ELSE IF( nb.LE.0 ) THEN
209 info = -4
210 ELSE IF( lda.LT.max( 1, m ) ) THEN
211 info = -6
212 ELSE IF( ldt.LT.mb ) THEN
213 info = -8
214 ELSE IF( ( lwork.LT.m*mb) .AND. (.NOT.lquery) ) THEN
215 info = -10
216 END IF
217 IF( info.EQ.0) THEN
218 work(1) = mb*m
219 END IF
220*
221 IF( info.NE.0 ) THEN
222 CALL xerbla( 'ZLASWLQ', -info )
223 RETURN
224 ELSE IF (lquery) THEN
225 RETURN
226 END IF
227*
228* Quick return if possible
229*
230 IF( min(m,n).EQ.0 ) THEN
231 RETURN
232 END IF
233*
234* The LQ Decomposition
235*
236 IF((m.GE.n).OR.(nb.LE.m).OR.(nb.GE.n)) THEN
237 CALL zgelqt( m, n, mb, a, lda, t, ldt, work, info)
238 RETURN
239 END IF
240*
241 kk = mod((n-m),(nb-m))
242 ii=n-kk+1
243*
244* Compute the LQ factorization of the first block A(1:M,1:NB)
245*
246 CALL zgelqt( m, nb, mb, a(1,1), lda, t, ldt, work, info)
247 ctr = 1
248*
249 DO i = nb+1, ii-nb+m , (nb-m)
250*
251* Compute the QR factorization of the current block A(1:M,I:I+NB-M)
252*
253 CALL ztplqt( m, nb-m, 0, mb, a(1,1), lda, a( 1, i ),
254 \$ lda, t(1, ctr * m + 1),
255 \$ ldt, work, info )
256 ctr = ctr + 1
257 END DO
258*
259* Compute the QR factorization of the last block A(1:M,II:N)
260*
261 IF (ii.LE.n) THEN
262 CALL ztplqt( m, kk, 0, mb, a(1,1), lda, a( 1, ii ),
263 \$ lda, t(1, ctr * m + 1), ldt,
264 \$ work, info )
265 END IF
266*
267 work( 1 ) = m * mb
268 RETURN
269*
270* End of ZLASWLQ
271*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zgelqt(m, n, mb, a, lda, t, ldt, work, info)
ZGELQT
Definition zgelqt.f:139
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
subroutine ztplqt(m, n, l, mb, a, lda, b, ldb, t, ldt, work, info)
ZTPLQT
Definition ztplqt.f:189
Here is the call graph for this function:
Here is the caller graph for this function: