drzt01()

double precision function drzt01	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		double precision, dimension( lda, * )	af,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( lwork )	work,
		integer	lwork )

DRZT01

Purpose:

!>
!> DRZT01 returns
!>      || A - R*Q || / ( M * eps * ||A|| )
!> for an upper trapezoidal A that was factored with DTZRZF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrices A and AF. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and AF. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The original upper trapezoidal M by N matrix A. !>
[in]	AF	!> AF is DOUBLE PRECISION array, dimension (LDA,N) !> The output of DTZRZF for input matrix A. !> The lower triangle is not referenced. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A and AF. !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (M) !> Details of the Householder transformations as returned by !> DTZRZF. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK >= m*n + m*nb. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 96 of file drzt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      DOUBLE PRECISION   NORMA
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dlaset, dormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
      drzt01 = zero
*
      IF( lwork.LT.m*n+m ) THEN
         CALL xerbla( 'DRZT01', 8 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = dlange( 'One-norm', m, n, a, lda, rwork )
*
*     Copy upper triangle R
*
      CALL dlaset( 'Full', m, n, zero, zero, work, m )
      DO 20 j = 1, m
         DO 10 i = 1, j
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     R = R * P(1) * ... *P(m)
*
      CALL dormrz( 'Right', 'No transpose', m, n, m, n-m, af, lda, tau,
     $             work, m, work( m*n+1 ), lwork-m*n, info )
*
*     R = R - A
*
      DO 30 i = 1, n
         CALL daxpy( m, -one, a( 1, i ), 1, work( ( i-1 )*m+1 ), 1 )
   30 CONTINUE
*
      drzt01 = dlange( 'One-norm', m, n, work, m, rwork )
*
      drzt01 = drzt01 / ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      IF( norma.NE.zero )
     $   drzt01 = drzt01 / norma
*
      RETURN
*
*     End of DRZT01
*

Here is the call graph for this function:

Here is the caller graph for this function: