dpot02()

subroutine dpot02	(	character	uplo,
		integer	n,
		integer	nrhs,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldx, * )	x,
		integer	ldx,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( * )	rwork,
		double precision	resid )

DPOT02

Purpose:

!>
!> DPOT02 computes the residual for the solution of a symmetric system
!> of linear equations  A*x = b:
!>
!>    RESID = norm(B - A*X) / ( norm(A) * norm(X) * EPS ),
!>
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> symmetric matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B, the matrix of right hand sides. !> NRHS >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The original symmetric matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N) !>
[in]	X	!> X is DOUBLE PRECISION array, dimension (LDX,NRHS) !> The computed solution vectors for the system of linear !> equations. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> On entry, the right hand side vectors for the system of !> linear equations. !> On exit, B is overwritten with the difference B - A*X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> The maximum over the number of right hand sides of !> norm(B - A*X) / ( norm(A) * norm(X) * EPS ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file dpot02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDB, LDX, N, NRHS
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), RWORK( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      DOUBLE PRECISION   ANORM, BNORM, EPS, XNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANSY
      EXTERNAL           dasum, dlamch, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dsymm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansy( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute  B - A*X
*
      CALL dsymm( 'Left', uplo, n, nrhs, -one, a, lda, x, ldx, one, b,
     $            ldb )
*
*     Compute the maximum over the number of right hand sides of
*        norm( B - A*X ) / ( norm(A) * norm(X) * EPS ) .
*
      resid = zero
      DO 10 j = 1, nrhs
         bnorm = dasum( n, b( 1, j ), 1 )
         xnorm = dasum( n, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of DPOT02
*

Here is the call graph for this function:

Here is the caller graph for this function: