LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
dpot02.f
Go to the documentation of this file.
1*> \brief \b DPOT02
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DPOT02( UPLO, N, NRHS, A, LDA, X, LDX, B, LDB, RWORK,
12* RESID )
13*
14* .. Scalar Arguments ..
15* CHARACTER UPLO
16* INTEGER LDA, LDB, LDX, N, NRHS
17* DOUBLE PRECISION RESID
18* ..
19* .. Array Arguments ..
20* DOUBLE PRECISION A( LDA, * ), B( LDB, * ), RWORK( * ),
21* $ X( LDX, * )
22* ..
23*
24*
25*> \par Purpose:
26* =============
27*>
28*> \verbatim
29*>
30*> DPOT02 computes the residual for the solution of a symmetric system
31*> of linear equations A*x = b:
32*>
33*> RESID = norm(B - A*X) / ( norm(A) * norm(X) * EPS ),
34*>
35*> where EPS is the machine epsilon.
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] UPLO
42*> \verbatim
43*> UPLO is CHARACTER*1
44*> Specifies whether the upper or lower triangular part of the
45*> symmetric matrix A is stored:
46*> = 'U': Upper triangular
47*> = 'L': Lower triangular
48*> \endverbatim
49*>
50*> \param[in] N
51*> \verbatim
52*> N is INTEGER
53*> The number of rows and columns of the matrix A. N >= 0.
54*> \endverbatim
55*>
56*> \param[in] NRHS
57*> \verbatim
58*> NRHS is INTEGER
59*> The number of columns of B, the matrix of right hand sides.
60*> NRHS >= 0.
61*> \endverbatim
62*>
63*> \param[in] A
64*> \verbatim
65*> A is DOUBLE PRECISION array, dimension (LDA,N)
66*> The original symmetric matrix A.
67*> \endverbatim
68*>
69*> \param[in] LDA
70*> \verbatim
71*> LDA is INTEGER
72*> The leading dimension of the array A. LDA >= max(1,N)
73*> \endverbatim
74*>
75*> \param[in] X
76*> \verbatim
77*> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
78*> The computed solution vectors for the system of linear
79*> equations.
80*> \endverbatim
81*>
82*> \param[in] LDX
83*> \verbatim
84*> LDX is INTEGER
85*> The leading dimension of the array X. LDX >= max(1,N).
86*> \endverbatim
87*>
88*> \param[in,out] B
89*> \verbatim
90*> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
91*> On entry, the right hand side vectors for the system of
92*> linear equations.
93*> On exit, B is overwritten with the difference B - A*X.
94*> \endverbatim
95*>
96*> \param[in] LDB
97*> \verbatim
98*> LDB is INTEGER
99*> The leading dimension of the array B. LDB >= max(1,N).
100*> \endverbatim
101*>
102*> \param[out] RWORK
103*> \verbatim
104*> RWORK is DOUBLE PRECISION array, dimension (N)
105*> \endverbatim
106*>
107*> \param[out] RESID
108*> \verbatim
109*> RESID is DOUBLE PRECISION
110*> The maximum over the number of right hand sides of
111*> norm(B - A*X) / ( norm(A) * norm(X) * EPS ).
112*> \endverbatim
113*
114* Authors:
115* ========
116*
117*> \author Univ. of Tennessee
118*> \author Univ. of California Berkeley
119*> \author Univ. of Colorado Denver
120*> \author NAG Ltd.
121*
122*> \ingroup double_lin
123*
124* =====================================================================
125 SUBROUTINE dpot02( UPLO, N, NRHS, A, LDA, X, LDX, B, LDB, RWORK,
126 $ RESID )
127*
128* -- LAPACK test routine --
129* -- LAPACK is a software package provided by Univ. of Tennessee, --
130* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131*
132* .. Scalar Arguments ..
133 CHARACTER UPLO
134 INTEGER LDA, LDB, LDX, N, NRHS
135 DOUBLE PRECISION RESID
136* ..
137* .. Array Arguments ..
138 DOUBLE PRECISION A( LDA, * ), B( LDB, * ), RWORK( * ),
139 $ x( ldx, * )
140* ..
141*
142* =====================================================================
143*
144* .. Parameters ..
145 DOUBLE PRECISION ZERO, ONE
146 parameter( zero = 0.0d+0, one = 1.0d+0 )
147* ..
148* .. Local Scalars ..
149 INTEGER J
150 DOUBLE PRECISION ANORM, BNORM, EPS, XNORM
151* ..
152* .. External Functions ..
153 DOUBLE PRECISION DASUM, DLAMCH, DLANSY
154 EXTERNAL dasum, dlamch, dlansy
155* ..
156* .. External Subroutines ..
157 EXTERNAL dsymm
158* ..
159* .. Intrinsic Functions ..
160 INTRINSIC max
161* ..
162* .. Executable Statements ..
163*
164* Quick exit if N = 0 or NRHS = 0.
165*
166 IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
167 resid = zero
168 RETURN
169 END IF
170*
171* Exit with RESID = 1/EPS if ANORM = 0.
172*
173 eps = dlamch( 'Epsilon' )
174 anorm = dlansy( '1', uplo, n, a, lda, rwork )
175 IF( anorm.LE.zero ) THEN
176 resid = one / eps
177 RETURN
178 END IF
179*
180* Compute B - A*X
181*
182 CALL dsymm( 'Left', uplo, n, nrhs, -one, a, lda, x, ldx, one, b,
183 $ ldb )
184*
185* Compute the maximum over the number of right hand sides of
186* norm( B - A*X ) / ( norm(A) * norm(X) * EPS ) .
187*
188 resid = zero
189 DO 10 j = 1, nrhs
190 bnorm = dasum( n, b( 1, j ), 1 )
191 xnorm = dasum( n, x( 1, j ), 1 )
192 IF( xnorm.LE.zero ) THEN
193 resid = one / eps
194 ELSE
195 resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
196 END IF
197 10 CONTINUE
198*
199 RETURN
200*
201* End of DPOT02
202*
203 END
subroutine dsymm(SIDE, UPLO, M, N, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DSYMM
Definition: dsymm.f:189
subroutine dpot02(UPLO, N, NRHS, A, LDA, X, LDX, B, LDB, RWORK, RESID)
DPOT02
Definition: dpot02.f:127