sgerqs()

subroutine sgerqs	(	integer	m,
		integer	n,
		integer	nrhs,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( lwork )	work,
		integer	lwork,
		integer	info )

SGERQS

Purpose:

!>
!> Compute a minimum-norm solution
!>     min || A*X - B ||
!> using the RQ factorization
!>     A = R*Q
!> computed by SGERQF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= M >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B. NRHS >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> Details of the RQ factorization of the original matrix A as !> returned by SGERQF. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= M. !>
[in]	TAU	!> TAU is REAL array, dimension (M) !> Details of the orthogonal matrix Q. !>
[in,out]	B	!> B is REAL array, dimension (LDB,NRHS) !> On entry, the right hand side vectors for the linear system. !> On exit, the solution vectors X. Each solution vector !> is contained in rows 1:N of a column of B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	WORK	!> WORK is REAL array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK must be at least NRHS, !> and should be at least NRHS*NB, where NB is the block size !> for this environment. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 120 of file sgerqs.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, sormrq, strsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. m.GT.n ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.1 .OR. lwork.LT.nrhs .AND. m.GT.0 .AND. n.GT.0 )
     $          THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGERQS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 .OR. m.EQ.0 )
     $   RETURN
*
*     Solve R*X = B(n-m+1:n,:)
*
      CALL strsm( 'Left', 'Upper', 'No transpose', 'Non-unit', m, nrhs,
     $            one, a( 1, n-m+1 ), lda, b( n-m+1, 1 ), ldb )
*
*     Set B(1:n-m,:) to zero
*
      CALL slaset( 'Full', n-m, nrhs, zero, zero, b, ldb )
*
*     B := Q' * B
*
      CALL sormrq( 'Left', 'Transpose', n, nrhs, m, a, lda, tau, b, ldb,
     $             work, lwork, info )
*
      RETURN
*
*     End of SGERQS
*

Here is the call graph for this function:

Here is the caller graph for this function: