LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sormrq.f
Go to the documentation of this file.
1*> \brief \b SORMRQ
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sormrq.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sormrq.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sormrq.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SORMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22* WORK, LWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER SIDE, TRANS
26* INTEGER INFO, K, LDA, LDC, LWORK, M, N
27* ..
28* .. Array Arguments ..
29* REAL A( LDA, * ), C( LDC, * ), TAU( * ),
30* \$ WORK( * )
31* ..
32*
33*
34*> \par Purpose:
35* =============
36*>
37*> \verbatim
38*>
39*> SORMRQ overwrites the general real M-by-N matrix C with
40*>
41*> SIDE = 'L' SIDE = 'R'
42*> TRANS = 'N': Q * C C * Q
43*> TRANS = 'T': Q**T * C C * Q**T
44*>
45*> where Q is a real orthogonal matrix defined as the product of k
46*> elementary reflectors
47*>
48*> Q = H(1) H(2) . . . H(k)
49*>
50*> as returned by SGERQF. Q is of order M if SIDE = 'L' and of order N
51*> if SIDE = 'R'.
52*> \endverbatim
53*
54* Arguments:
55* ==========
56*
57*> \param[in] SIDE
58*> \verbatim
59*> SIDE is CHARACTER*1
60*> = 'L': apply Q or Q**T from the Left;
61*> = 'R': apply Q or Q**T from the Right.
62*> \endverbatim
63*>
64*> \param[in] TRANS
65*> \verbatim
66*> TRANS is CHARACTER*1
67*> = 'N': No transpose, apply Q;
68*> = 'T': Transpose, apply Q**T.
69*> \endverbatim
70*>
71*> \param[in] M
72*> \verbatim
73*> M is INTEGER
74*> The number of rows of the matrix C. M >= 0.
75*> \endverbatim
76*>
77*> \param[in] N
78*> \verbatim
79*> N is INTEGER
80*> The number of columns of the matrix C. N >= 0.
81*> \endverbatim
82*>
83*> \param[in] K
84*> \verbatim
85*> K is INTEGER
86*> The number of elementary reflectors whose product defines
87*> the matrix Q.
88*> If SIDE = 'L', M >= K >= 0;
89*> if SIDE = 'R', N >= K >= 0.
90*> \endverbatim
91*>
92*> \param[in] A
93*> \verbatim
94*> A is REAL array, dimension
95*> (LDA,M) if SIDE = 'L',
96*> (LDA,N) if SIDE = 'R'
97*> The i-th row must contain the vector which defines the
98*> elementary reflector H(i), for i = 1,2,...,k, as returned by
99*> SGERQF in the last k rows of its array argument A.
100*> \endverbatim
101*>
102*> \param[in] LDA
103*> \verbatim
104*> LDA is INTEGER
105*> The leading dimension of the array A. LDA >= max(1,K).
106*> \endverbatim
107*>
108*> \param[in] TAU
109*> \verbatim
110*> TAU is REAL array, dimension (K)
111*> TAU(i) must contain the scalar factor of the elementary
112*> reflector H(i), as returned by SGERQF.
113*> \endverbatim
114*>
115*> \param[in,out] C
116*> \verbatim
117*> C is REAL array, dimension (LDC,N)
118*> On entry, the M-by-N matrix C.
119*> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
120*> \endverbatim
121*>
122*> \param[in] LDC
123*> \verbatim
124*> LDC is INTEGER
125*> The leading dimension of the array C. LDC >= max(1,M).
126*> \endverbatim
127*>
128*> \param[out] WORK
129*> \verbatim
130*> WORK is REAL array, dimension (MAX(1,LWORK))
131*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132*> \endverbatim
133*>
134*> \param[in] LWORK
135*> \verbatim
136*> LWORK is INTEGER
137*> The dimension of the array WORK.
138*> If SIDE = 'L', LWORK >= max(1,N);
139*> if SIDE = 'R', LWORK >= max(1,M).
140*> For good performance, LWORK should generally be larger.
141*>
142*> If LWORK = -1, then a workspace query is assumed; the routine
143*> only calculates the optimal size of the WORK array, returns
144*> this value as the first entry of the WORK array, and no error
145*> message related to LWORK is issued by XERBLA.
146*> \endverbatim
147*>
148*> \param[out] INFO
149*> \verbatim
150*> INFO is INTEGER
151*> = 0: successful exit
152*> < 0: if INFO = -i, the i-th argument had an illegal value
153*> \endverbatim
154*
155* Authors:
156* ========
157*
158*> \author Univ. of Tennessee
159*> \author Univ. of California Berkeley
160*> \author Univ. of Colorado Denver
161*> \author NAG Ltd.
162*
163*> \ingroup unmrq
164*
165* =====================================================================
166 SUBROUTINE sormrq( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
167 \$ WORK, LWORK, INFO )
168*
169* -- LAPACK computational routine --
170* -- LAPACK is a software package provided by Univ. of Tennessee, --
171* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
172*
173* .. Scalar Arguments ..
174 CHARACTER SIDE, TRANS
175 INTEGER INFO, K, LDA, LDC, LWORK, M, N
176* ..
177* .. Array Arguments ..
178 REAL A( LDA, * ), C( LDC, * ), TAU( * ),
179 \$ work( * )
180* ..
181*
182* =====================================================================
183*
184* .. Parameters ..
185 INTEGER NBMAX, LDT, TSIZE
186 parameter( nbmax = 64, ldt = nbmax+1,
187 \$ tsize = ldt*nbmax )
188* ..
189* .. Local Scalars ..
190 LOGICAL LEFT, LQUERY, NOTRAN
191 CHARACTER TRANST
192 INTEGER I, I1, I2, I3, IB, IINFO, IWT, LDWORK, LWKOPT,
193 \$ mi, nb, nbmin, ni, nq, nw
194* ..
195* .. External Functions ..
196 LOGICAL LSAME
197 INTEGER ILAENV
198 REAL SROUNDUP_LWORK
199 EXTERNAL lsame, ilaenv, sroundup_lwork
200* ..
201* .. External Subroutines ..
202 EXTERNAL slarfb, slarft, sormr2, xerbla
203* ..
204* .. Intrinsic Functions ..
205 INTRINSIC max, min
206* ..
207* .. Executable Statements ..
208*
209* Test the input arguments
210*
211 info = 0
212 left = lsame( side, 'L' )
213 notran = lsame( trans, 'N' )
214 lquery = ( lwork.EQ.-1 )
215*
216* NQ is the order of Q and NW is the minimum dimension of WORK
217*
218 IF( left ) THEN
219 nq = m
220 nw = max( 1, n )
221 ELSE
222 nq = n
223 nw = max( 1, m )
224 END IF
225 IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
226 info = -1
227 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
228 info = -2
229 ELSE IF( m.LT.0 ) THEN
230 info = -3
231 ELSE IF( n.LT.0 ) THEN
232 info = -4
233 ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
234 info = -5
235 ELSE IF( lda.LT.max( 1, k ) ) THEN
236 info = -7
237 ELSE IF( ldc.LT.max( 1, m ) ) THEN
238 info = -10
239 ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
240 info = -12
241 END IF
242*
243 IF( info.EQ.0 ) THEN
244*
245* Compute the workspace requirements
246*
247 IF( m.EQ.0 .OR. n.EQ.0 ) THEN
248 lwkopt = 1
249 ELSE
250 nb = min( nbmax, ilaenv( 1, 'SORMRQ', side // trans, m, n,
251 \$ k, -1 ) )
252 lwkopt = nw*nb + tsize
253 END IF
254 work( 1 ) = sroundup_lwork(lwkopt)
255 END IF
256*
257 IF( info.NE.0 ) THEN
258 CALL xerbla( 'SORMRQ', -info )
259 RETURN
260 ELSE IF( lquery ) THEN
261 RETURN
262 END IF
263*
264* Quick return if possible
265*
266 IF( m.EQ.0 .OR. n.EQ.0 ) THEN
267 RETURN
268 END IF
269*
270 nbmin = 2
271 ldwork = nw
272 IF( nb.GT.1 .AND. nb.LT.k ) THEN
273 IF( lwork.LT.lwkopt ) THEN
274 nb = (lwork-tsize) / ldwork
275 nbmin = max( 2, ilaenv( 2, 'SORMRQ', side // trans, m, n, k,
276 \$ -1 ) )
277 END IF
278 END IF
279*
280 IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
281*
282* Use unblocked code
283*
284 CALL sormr2( side, trans, m, n, k, a, lda, tau, c, ldc, work,
285 \$ iinfo )
286 ELSE
287*
288* Use blocked code
289*
290 iwt = 1 + nw*nb
291 IF( ( left .AND. .NOT.notran ) .OR.
292 \$ ( .NOT.left .AND. notran ) ) THEN
293 i1 = 1
294 i2 = k
295 i3 = nb
296 ELSE
297 i1 = ( ( k-1 ) / nb )*nb + 1
298 i2 = 1
299 i3 = -nb
300 END IF
301*
302 IF( left ) THEN
303 ni = n
304 ELSE
305 mi = m
306 END IF
307*
308 IF( notran ) THEN
309 transt = 'T'
310 ELSE
311 transt = 'N'
312 END IF
313*
314 DO 10 i = i1, i2, i3
315 ib = min( nb, k-i+1 )
316*
317* Form the triangular factor of the block reflector
318* H = H(i+ib-1) . . . H(i+1) H(i)
319*
320 CALL slarft( 'Backward', 'Rowwise', nq-k+i+ib-1, ib,
321 \$ a( i, 1 ), lda, tau( i ), work( iwt ), ldt )
322 IF( left ) THEN
323*
324* H or H**T is applied to C(1:m-k+i+ib-1,1:n)
325*
326 mi = m - k + i + ib - 1
327 ELSE
328*
329* H or H**T is applied to C(1:m,1:n-k+i+ib-1)
330*
331 ni = n - k + i + ib - 1
332 END IF
333*
334* Apply H or H**T
335*
336 CALL slarfb( side, transt, 'Backward', 'Rowwise', mi, ni,
337 \$ ib, a( i, 1 ), lda, work( iwt ), ldt, c, ldc,
338 \$ work, ldwork )
339 10 CONTINUE
340 END IF
341 work( 1 ) = sroundup_lwork(lwkopt)
342 RETURN
343*
344* End of SORMRQ
345*
346 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarfb(side, trans, direct, storev, m, n, k, v, ldv, t, ldt, c, ldc, work, ldwork)
SLARFB applies a block reflector or its transpose to a general rectangular matrix.
Definition slarfb.f:197
subroutine slarft(direct, storev, n, k, v, ldv, tau, t, ldt)
SLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition slarft.f:163
subroutine sormr2(side, trans, m, n, k, a, lda, tau, c, ldc, work, info)
SORMR2 multiplies a general matrix by the orthogonal matrix from a RQ factorization determined by sge...
Definition sormr2.f:159
subroutine sormrq(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
SORMRQ
Definition sormrq.f:168