cgelsy.f

Go to the documentation of this file.

*> \brief <b> CGELSY solves overdetermined or underdetermined systems for GE matrices</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download CGELSY + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgelsy.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgelsy.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgelsy.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGELSY( M, N, NRHS, A, LDA, B, LDB, JPVT, RCOND, RANK,
*                          WORK, LWORK, RWORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
*       REAL               RCOND
*       ..
*       .. Array Arguments ..
*       INTEGER            JPVT( * )
*       REAL               RWORK( * )
*       COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGELSY computes the minimum-norm solution to a complex linear least
*> squares problem:
*>     minimize || A * X - B ||
*> using a complete orthogonal factorization of A.  A is an M-by-N
*> matrix which may be rank-deficient.
*>
*> Several right hand side vectors b and solution vectors x can be
*> handled in a single call; they are stored as the columns of the
*> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
*> matrix X.
*>
*> The routine first computes a QR factorization with column pivoting:
*>     A * P = Q * [ R11 R12 ]
*>                 [  0  R22 ]
*> with R11 defined as the largest leading submatrix whose estimated
*> condition number is less than 1/RCOND.  The order of R11, RANK,
*> is the effective rank of A.
*>
*> Then, R22 is considered to be negligible, and R12 is annihilated
*> by unitary transformations from the right, arriving at the
*> complete orthogonal factorization:
*>    A * P = Q * [ T11 0 ] * Z
*>                [  0  0 ]
*> The minimum-norm solution is then
*>    X = P * Z**H [ inv(T11)*Q1**H*B ]
*>                 [        0         ]
*> where Q1 consists of the first RANK columns of Q.
*>
*> This routine is basically identical to the original xGELSX except
*> three differences:
*>   o The permutation of matrix B (the right hand side) is faster and
*>     more simple.
*>   o The call to the subroutine xGEQPF has been substituted by the
*>     the call to the subroutine xGEQP3. This subroutine is a Blas-3
*>     version of the QR factorization with column pivoting.
*>   o Matrix B (the right hand side) is updated with Blas-3.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of
*>          columns of matrices B and X. NRHS >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit, A has been overwritten by details of its
*>          complete orthogonal factorization.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the M-by-NRHS right hand side matrix B.
*>          On exit, the N-by-NRHS solution matrix X.
*>          If M = 0 or N = 0, B is not referenced.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= max(1,M,N).
*> \endverbatim
*>
*> \param[in,out] JPVT
*> \verbatim
*>          JPVT is INTEGER array, dimension (N)
*>          On entry, if JPVT(i) .ne. 0, the i-th column of A is permuted
*>          to the front of AP, otherwise column i is a free column.
*>          On exit, if JPVT(i) = k, then the i-th column of A*P
*>          was the k-th column of A.
*> \endverbatim
*>
*> \param[in] RCOND
*> \verbatim
*>          RCOND is REAL
*>          RCOND is used to determine the effective rank of A, which
*>          is defined as the order of the largest leading triangular
*>          submatrix R11 in the QR factorization with pivoting of A,
*>          whose estimated condition number < 1/RCOND.
*> \endverbatim
*>
*> \param[out] RANK
*> \verbatim
*>          RANK is INTEGER
*>          The effective rank of A, i.e., the order of the submatrix
*>          R11.  This is the same as the order of the submatrix T11
*>          in the complete orthogonal factorization of A.
*>          If NRHS = 0, RANK = 0 on output.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          The unblocked strategy requires that:
*>            LWORK >= MN + MAX( 2*MN, N+1, MN+NRHS )
*>          where MN = min(M,N).
*>          The block algorithm requires that:
*>            LWORK >= MN + MAX( 2*MN, NB*(N+1), MN+MN*NB, MN+NB*NRHS )
*>          where NB is an upper bound on the blocksize returned
*>          by ILAENV for the routines CGEQP3, CTZRZF, CTZRQF, CUNMQR,
*>          and CUNMRZ.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup gelsy
*
*> \par Contributors:
*  ==================
*>
*>    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA \n
*>    E. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain \n
*>    G. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain \n
*>
*  =====================================================================
      SUBROUTINE cgelsy( M, N, NRHS, A, LDA, B, LDB, JPVT, RCOND,
     $                   RANK,
     $                   WORK, LWORK, RWORK, INFO )
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            JPVT( * )
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            IMAX, IMIN
      PARAMETER          ( IMAX = 1, imin = 2 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IASCL, IBSCL, ISMAX, ISMIN, J, LWKOPT, MN,
     $                   nb, nb1, nb2, nb3, nb4
      REAL               ANRM, BIGNUM, BNRM, SMAX, SMAXPR, SMIN, SMINPR,
     $                   SMLNUM, WSIZE
      COMPLEX            C1, C2, S1, S2
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy, cgeqp3, claic1, clascl, claset,
     $                   ctrsm,
     $                   ctzrzf, cunmqr, cunmrz, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               CLANGE, SLAMCH
      EXTERNAL           clange, ilaenv, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real, cmplx
*     ..
*     .. Executable Statements ..
*
      mn = min( m, n )
      ismin = mn + 1
      ismax = 2*mn + 1
*
*     Test the input arguments.
*
      info = 0
      nb1 = ilaenv( 1, 'CGEQRF', ' ', m, n, -1, -1 )
      nb2 = ilaenv( 1, 'CGERQF', ' ', m, n, -1, -1 )
      nb3 = ilaenv( 1, 'CUNMQR', ' ', m, n, nrhs, -1 )
      nb4 = ilaenv( 1, 'CUNMRQ', ' ', m, n, nrhs, -1 )
      nb = max( nb1, nb2, nb3, nb4 )
      lwkopt = max( 1, mn+2*n+nb*(n+1), 2*mn+nb*nrhs )
      work( 1 ) = cmplx( lwkopt )
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, m, n ) ) THEN
         info = -7
      ELSE IF( lwork.LT.( mn+max( 2*mn, n+1, mn+nrhs ) ) .AND.
     $   .NOT.lquery ) THEN
         info = -12
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELSY', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, nrhs ).EQ.0 ) THEN
         rank = 0
         RETURN
      END IF
*
*     Get machine parameters
*
      smlnum = slamch( 'S' ) / slamch( 'P' )
      bignum = one / smlnum
*
*     Scale A, B if max entries outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         rank = 0
         GO TO 70
      END IF
*
      bnrm = clange( 'M', m, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, bnrm, smlnum, m, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, bnrm, bignum, m, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
*     Compute QR factorization with column pivoting of A:
*        A * P = Q * R
*
      CALL cgeqp3( m, n, a, lda, jpvt, work( 1 ), work( mn+1 ),
     $             lwork-mn, rwork, info )
      wsize = real( mn ) + real( work( mn+1 ) )
*
*     complex workspace: MN+NB*(N+1). real workspace 2*N.
*     Details of Householder rotations stored in WORK(1:MN).
*
*     Determine RANK using incremental condition estimation
*
      work( ismin ) = cone
      work( ismax ) = cone
      smax = abs( a( 1, 1 ) )
      smin = smax
      IF( abs( a( 1, 1 ) ).EQ.zero ) THEN
         rank = 0
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         GO TO 70
      ELSE
         rank = 1
      END IF
*
   10 CONTINUE
      IF( rank.LT.mn ) THEN
         i = rank + 1
         CALL claic1( imin, rank, work( ismin ), smin, a( 1, i ),
     $                a( i, i ), sminpr, s1, c1 )
         CALL claic1( imax, rank, work( ismax ), smax, a( 1, i ),
     $                a( i, i ), smaxpr, s2, c2 )
*
         IF( smaxpr*rcond.LE.sminpr ) THEN
            DO 20 i = 1, rank
               work( ismin+i-1 ) = s1*work( ismin+i-1 )
               work( ismax+i-1 ) = s2*work( ismax+i-1 )
   20       CONTINUE
            work( ismin+rank ) = c1
            work( ismax+rank ) = c2
            smin = sminpr
            smax = smaxpr
            rank = rank + 1
            GO TO 10
         END IF
      END IF
*
*     complex workspace: 3*MN.
*
*     Logically partition R = [ R11 R12 ]
*                             [  0  R22 ]
*     where R11 = R(1:RANK,1:RANK)
*
*     [R11,R12] = [ T11, 0 ] * Y
*
      IF( rank.LT.n )
     $   CALL ctzrzf( rank, n, a, lda, work( mn+1 ), work( 2*mn+1 ),
     $                lwork-2*mn, info )
*
*     complex workspace: 2*MN.
*     Details of Householder rotations stored in WORK(MN+1:2*MN)
*
*     B(1:M,1:NRHS) := Q**H * B(1:M,1:NRHS)
*
      CALL cunmqr( 'Left', 'Conjugate transpose', m, nrhs, mn, a,
     $             lda,
     $             work( 1 ), b, ldb, work( 2*mn+1 ), lwork-2*mn, info )
      wsize = max( wsize, real( 2*mn )+real( work( 2*mn+1 ) ) )
*
*     complex workspace: 2*MN+NB*NRHS.
*
*     B(1:RANK,1:NRHS) := inv(T11) * B(1:RANK,1:NRHS)
*
      CALL ctrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', rank,
     $            nrhs, cone, a, lda, b, ldb )
*
      DO 40 j = 1, nrhs
         DO 30 i = rank + 1, n
            b( i, j ) = czero
   30    CONTINUE
   40 CONTINUE
*
*     B(1:N,1:NRHS) := Y**H * B(1:N,1:NRHS)
*
      IF( rank.LT.n ) THEN
         CALL cunmrz( 'Left', 'Conjugate transpose', n, nrhs, rank,
     $                n-rank, a, lda, work( mn+1 ), b, ldb,
     $                work( 2*mn+1 ), lwork-2*mn, info )
      END IF
*
*     complex workspace: 2*MN+NRHS.
*
*     B(1:N,1:NRHS) := P * B(1:N,1:NRHS)
*
      DO 60 j = 1, nrhs
         DO 50 i = 1, n
            work( jpvt( i ) ) = b( i, j )
   50    CONTINUE
         CALL ccopy( n, work( 1 ), 1, b( 1, j ), 1 )
   60 CONTINUE
*
*     complex workspace: N.
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, anrm, smlnum, n, nrhs, b, ldb,
     $                info )
         CALL clascl( 'U', 0, 0, smlnum, anrm, rank, rank, a, lda,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, anrm, bignum, n, nrhs, b, ldb,
     $                info )
         CALL clascl( 'U', 0, 0, bignum, anrm, rank, rank, a, lda,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, smlnum, bnrm, n, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, bignum, bnrm, n, nrhs, b, ldb,
     $                info )
      END IF
*
   70 CONTINUE
      work( 1 ) = cmplx( lwkopt )
*
      RETURN
*
*     End of CGELSY
*
      END