LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
cpotrf2.f
Go to the documentation of this file.
1*> \brief \b CPOTRF2
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* RECURSIVE SUBROUTINE CPOTRF2( UPLO, N, A, LDA, INFO )
12*
13* .. Scalar Arguments ..
14* CHARACTER UPLO
15* INTEGER INFO, LDA, N
16* ..
17* .. Array Arguments ..
18* COMPLEX A( LDA, * )
19* ..
20*
21*
22*> \par Purpose:
23* =============
24*>
25*> \verbatim
26*>
27*> CPOTRF2 computes the Cholesky factorization of a Hermitian
28*> positive definite matrix A using the recursive algorithm.
29*>
30*> The factorization has the form
31*> A = U**H * U, if UPLO = 'U', or
32*> A = L * L**H, if UPLO = 'L',
33*> where U is an upper triangular matrix and L is lower triangular.
34*>
35*> This is the recursive version of the algorithm. It divides
36*> the matrix into four submatrices:
37*>
38*> [ A11 | A12 ] where A11 is n1 by n1 and A22 is n2 by n2
39*> A = [ -----|----- ] with n1 = n/2
40*> [ A21 | A22 ] n2 = n-n1
41*>
42*> The subroutine calls itself to factor A11. Update and scale A21
43*> or A12, update A22 then calls itself to factor A22.
44*>
45*> \endverbatim
46*
47* Arguments:
48* ==========
49*
50*> \param[in] UPLO
51*> \verbatim
52*> UPLO is CHARACTER*1
53*> = 'U': Upper triangle of A is stored;
54*> = 'L': Lower triangle of A is stored.
55*> \endverbatim
56*>
57*> \param[in] N
58*> \verbatim
59*> N is INTEGER
60*> The order of the matrix A. N >= 0.
61*> \endverbatim
62*>
63*> \param[in,out] A
64*> \verbatim
65*> A is COMPLEX array, dimension (LDA,N)
66*> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
67*> N-by-N upper triangular part of A contains the upper
68*> triangular part of the matrix A, and the strictly lower
69*> triangular part of A is not referenced. If UPLO = 'L', the
70*> leading N-by-N lower triangular part of A contains the lower
71*> triangular part of the matrix A, and the strictly upper
72*> triangular part of A is not referenced.
73*>
74*> On exit, if INFO = 0, the factor U or L from the Cholesky
75*> factorization A = U**H*U or A = L*L**H.
76*> \endverbatim
77*>
78*> \param[in] LDA
79*> \verbatim
80*> LDA is INTEGER
81*> The leading dimension of the array A. LDA >= max(1,N).
82*> \endverbatim
83*>
84*> \param[out] INFO
85*> \verbatim
86*> INFO is INTEGER
87*> = 0: successful exit
88*> < 0: if INFO = -i, the i-th argument had an illegal value
89*> > 0: if INFO = i, the leading minor of order i is not
90*> positive definite, and the factorization could not be
91*> completed.
92*> \endverbatim
93*
94* Authors:
95* ========
96*
97*> \author Univ. of Tennessee
98*> \author Univ. of California Berkeley
99*> \author Univ. of Colorado Denver
100*> \author NAG Ltd.
101*
102*> \ingroup complexPOcomputational
103*
104* =====================================================================
105 RECURSIVE SUBROUTINE cpotrf2( UPLO, N, A, LDA, INFO )
106*
107* -- LAPACK computational routine --
108* -- LAPACK is a software package provided by Univ. of Tennessee, --
109* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
110*
111* .. Scalar Arguments ..
112 CHARACTER uplo
113 INTEGER info, lda, n
114* ..
115* .. Array Arguments ..
116 COMPLEX a( lda, * )
117* ..
118*
119* =====================================================================
120*
121* .. Parameters ..
122 REAL one, zero
123 parameter( one = 1.0e+0, zero = 0.0e+0 )
124 COMPLEX cone
125 parameter( cone = (1.0e+0, 0.0e+0) )
126* ..
127* .. Local Scalars ..
128 LOGICAL upper
129 INTEGER n1, n2, iinfo
130 REAL ajj
131* ..
132* .. External Functions ..
133 LOGICAL lsame, sisnan
134 EXTERNAL lsame, sisnan
135* ..
136* .. External Subroutines ..
137 EXTERNAL cherk, ctrsm, xerbla
138* ..
139* .. Intrinsic Functions ..
140 INTRINSIC max, real, sqrt
141* ..
142* .. Executable Statements ..
143*
144* Test the input parameters
145*
146 info = 0
147 upper = lsame( uplo, 'U' )
148 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
149 info = -1
150 ELSE IF( n.LT.0 ) THEN
151 info = -2
152 ELSE IF( lda.LT.max( 1, n ) ) THEN
153 info = -4
154 END IF
155 IF( info.NE.0 ) THEN
156 CALL xerbla( 'CPOTRF2', -info )
157 RETURN
158 END IF
159*
160* Quick return if possible
161*
162 IF( n.EQ.0 )
163 \$ RETURN
164*
165* N=1 case
166*
167 IF( n.EQ.1 ) THEN
168*
169* Test for non-positive-definiteness
170*
171 ajj = real( a( 1, 1 ) )
172 IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
173 info = 1
174 RETURN
175 END IF
176*
177* Factor
178*
179 a( 1, 1 ) = sqrt( ajj )
180*
181* Use recursive code
182*
183 ELSE
184 n1 = n/2
185 n2 = n-n1
186*
187* Factor A11
188*
189 CALL cpotrf2( uplo, n1, a( 1, 1 ), lda, iinfo )
190 IF ( iinfo.NE.0 ) THEN
191 info = iinfo
192 RETURN
193 END IF
194*
195* Compute the Cholesky factorization A = U**H*U
196*
197 IF( upper ) THEN
198*
199* Update and scale A12
200*
201 CALL ctrsm( 'L', 'U', 'C', 'N', n1, n2, cone,
202 \$ a( 1, 1 ), lda, a( 1, n1+1 ), lda )
203*
204* Update and factor A22
205*
206 CALL cherk( uplo, 'C', n2, n1, -one, a( 1, n1+1 ), lda,
207 \$ one, a( n1+1, n1+1 ), lda )
208*
209 CALL cpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
210*
211 IF ( iinfo.NE.0 ) THEN
212 info = iinfo + n1
213 RETURN
214 END IF
215*
216* Compute the Cholesky factorization A = L*L**H
217*
218 ELSE
219*
220* Update and scale A21
221*
222 CALL ctrsm( 'R', 'L', 'C', 'N', n2, n1, cone,
223 \$ a( 1, 1 ), lda, a( n1+1, 1 ), lda )
224*
225* Update and factor A22
226*
227 CALL cherk( uplo, 'N', n2, n1, -one, a( n1+1, 1 ), lda,
228 \$ one, a( n1+1, n1+1 ), lda )
229*
230 CALL cpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
231*
232 IF ( iinfo.NE.0 ) THEN
233 info = iinfo + n1
234 RETURN
235 END IF
236*
237 END IF
238 END IF
239 RETURN
240*
241* End of CPOTRF2
242*
243 END
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine cherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
CHERK
Definition: cherk.f:173
subroutine ctrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRSM
Definition: ctrsm.f:180
recursive subroutine cpotrf2(UPLO, N, A, LDA, INFO)
CPOTRF2
Definition: cpotrf2.f:106