cpotrf2()

recursive subroutine cpotrf2	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer	info
	)

CPOTRF2

Purpose:

 CPOTRF2 computes the Cholesky factorization of a Hermitian
 positive definite matrix A using the recursive algorithm.

 The factorization has the form
    A = U**H * U,  if UPLO = 'U', or
    A = L  * L**H,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular.

 This is the recursive version of the algorithm. It divides
 the matrix into four submatrices:

        [  A11 | A12  ]  where A11 is n1 by n1 and A22 is n2 by n2
    A = [ -----|----- ]  with n1 = n/2
        [  A21 | A22  ]       n2 = n-n1

 The subroutine calls itself to factor A11. Update and scale A21
 or A12, update A22 then calls itself to factor A22.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the factor U or L from the Cholesky factorization A = U**H*U or A = L*L**H.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the leading principal minor of order i is not positive, and the factorization could not be completed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 105 of file cpotrf2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      COMPLEX            CONE
      parameter( cone = (1.0e+0, 0.0e+0) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            N1, N2, IINFO
      REAL               AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, SISNAN
      EXTERNAL           lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           cherk, ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPOTRF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     N=1 case
*
      IF( n.EQ.1 ) THEN
*
*        Test for non-positive-definiteness
*
         ajj = real( a( 1, 1 ) )
         IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
            info = 1
            RETURN
         END IF
*
*        Factor
*
         a( 1, 1 ) = sqrt( ajj )
*
*     Use recursive code
*
      ELSE
         n1 = n/2
         n2 = n-n1
*
*        Factor A11
*
         CALL cpotrf2( uplo, n1, a( 1, 1 ), lda, iinfo )
         IF ( iinfo.NE.0 ) THEN
            info = iinfo
            RETURN
         END IF
*
*        Compute the Cholesky factorization A = U**H*U
*
         IF( upper ) THEN
*
*           Update and scale A12
*
            CALL ctrsm( 'L', 'U', 'C', 'N', n1, n2, cone,
     $                  a( 1, 1 ), lda, a( 1, n1+1 ), lda )
*
*           Update and factor A22
*
            CALL cherk( uplo, 'C', n2, n1, -one, a( 1, n1+1 ), lda,
     $                  one, a( n1+1, n1+1 ), lda )
*
            CALL cpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
*
            IF ( iinfo.NE.0 ) THEN
               info = iinfo + n1
               RETURN
            END IF
*
*        Compute the Cholesky factorization A = L*L**H
*
         ELSE
*
*           Update and scale A21
*
            CALL ctrsm( 'R', 'L', 'C', 'N', n2, n1, cone,
     $                  a( 1, 1 ), lda, a( n1+1, 1 ), lda )
*
*           Update and factor A22
*
            CALL cherk( uplo, 'N', n2, n1, -one, a( n1+1, 1 ), lda,
     $                  one, a( n1+1, n1+1 ), lda )
*
            CALL cpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
*
            IF ( iinfo.NE.0 ) THEN
               info = iinfo + n1
               RETURN
            END IF
*
         END IF
      END IF
      RETURN
*
*     End of CPOTRF2
*

Here is the call graph for this function:

Here is the caller graph for this function: