dlauum()

subroutine dlauum	(	character	uplo,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		integer	info
	)

DLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).

Download DLAUUM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLAUUM computes the product U * U**T or L**T * L, where the triangular
 factor U or L is stored in the upper or lower triangular part of
 the array A.

 If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
 overwriting the factor U in A.
 If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
 overwriting the factor L in A.

 This is the blocked form of the algorithm, calling Level 3 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the triangular factor stored in the array A is upper or lower triangular: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the triangular factor U or L. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the triangular factor U or L. On exit, if UPLO = 'U', the upper triangle of A is overwritten with the upper triangle of the product U * U**T; if UPLO = 'L', the lower triangle of A is overwritten with the lower triangle of the product L**T * L.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file dlauum.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IB, NB
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlauu2, dsyrk, dtrmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAUUM', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'DLAUUM', uplo, n, -1, -1, -1 )
*
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL dlauu2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code
*
         IF( upper ) THEN
*
*           Compute the product U * U**T.
*
            DO 10 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL dtrmm( 'Right', 'Upper', 'Transpose', 'Non-unit',
     $                     i-1, ib, one, a( i, i ), lda, a( 1, i ),
     $                     lda )
               CALL dlauu2( 'Upper', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL dgemm( 'No transpose', 'Transpose', i-1, ib,
     $                        n-i-ib+1, one, a( 1, i+ib ), lda,
     $                        a( i, i+ib ), lda, one, a( 1, i ), lda )
                  CALL dsyrk( 'Upper', 'No transpose', ib, n-i-ib+1,
     $                        one, a( i, i+ib ), lda, one, a( i, i ),
     $                        lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute the product L**T * L.
*
            DO 20 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL dtrmm( 'Left', 'Lower', 'Transpose', 'Non-unit', ib,
     $                     i-1, one, a( i, i ), lda, a( i, 1 ), lda )
               CALL dlauu2( 'Lower', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL dgemm( 'Transpose', 'No transpose', ib, i-1,
     $                        n-i-ib+1, one, a( i+ib, i ), lda,
     $                        a( i+ib, 1 ), lda, one, a( i, 1 ), lda )
                  CALL dsyrk( 'Lower', 'Transpose', ib, n-i-ib+1, one,
     $                        a( i+ib, i ), lda, one, a( i, i ), lda )
               END IF
   20       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of DLAUUM
*

Here is the call graph for this function:

Here is the caller graph for this function: