LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zla_syrfsx_extended()

subroutine zla_syrfsx_extended ( integer prec_type,
character uplo,
integer n,
integer nrhs,
complex*16, dimension( lda, * ) a,
integer lda,
complex*16, dimension( ldaf, * ) af,
integer ldaf,
integer, dimension( * ) ipiv,
logical colequ,
double precision, dimension( * ) c,
complex*16, dimension( ldb, * ) b,
integer ldb,
complex*16, dimension( ldy, * ) y,
integer ldy,
double precision, dimension( * ) berr_out,
integer n_norms,
double precision, dimension( nrhs, * ) err_bnds_norm,
double precision, dimension( nrhs, * ) err_bnds_comp,
complex*16, dimension( * ) res,
double precision, dimension( * ) ayb,
complex*16, dimension( * ) dy,
complex*16, dimension( * ) y_tail,
double precision rcond,
integer ithresh,
double precision rthresh,
double precision dz_ub,
logical ignore_cwise,
integer info )

ZLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download ZLA_SYRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> ZLA_SYRFSX_EXTENDED improves the computed solution to a system of
!> linear equations by performing extra-precise iterative refinement
!> and provides error bounds and backward error estimates for the solution.
!> This subroutine is called by ZSYRFSX to perform iterative refinement.
!> In addition to normwise error bound, the code provides maximum
!> componentwise error bound if possible. See comments for ERR_BNDS_NORM
!> and ERR_BNDS_COMP for details of the error bounds. Note that this
!> subroutine is only responsible for setting the second fields of
!> ERR_BNDS_NORM and ERR_BNDS_COMP.
!>
Parameters
[in]PREC_TYPE
!>          PREC_TYPE is INTEGER
!>     Specifies the intermediate precision to be used in refinement.
!>     The value is defined by ILAPREC(P) where P is a CHARACTER and P
!>          = 'S':  Single
!>          = 'D':  Double
!>          = 'I':  Indigenous
!>          = 'X' or 'E':  Extra
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>       = 'U':  Upper triangle of A is stored;
!>       = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>     The number of linear equations, i.e., the order of the
!>     matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>     The number of right-hand-sides, i.e., the number of columns of the
!>     matrix B.
!>
[in]A
!>          A is COMPLEX*16 array, dimension (LDA,N)
!>     On entry, the N-by-N matrix A.
!>
[in]LDA
!>          LDA is INTEGER
!>     The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]AF
!>          AF is COMPLEX*16 array, dimension (LDAF,N)
!>     The block diagonal matrix D and the multipliers used to
!>     obtain the factor U or L as computed by ZSYTRF.
!>
[in]LDAF
!>          LDAF is INTEGER
!>     The leading dimension of the array AF.  LDAF >= max(1,N).
!>
[in]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>     Details of the interchanges and the block structure of D
!>     as determined by ZSYTRF.
!>
[in]COLEQU
!>          COLEQU is LOGICAL
!>     If .TRUE. then column equilibration was done to A before calling
!>     this routine. This is needed to compute the solution and error
!>     bounds correctly.
!>
[in]C
!>          C is DOUBLE PRECISION array, dimension (N)
!>     The column scale factors for A. If COLEQU = .FALSE., C
!>     is not accessed. If C is input, each element of C should be a power
!>     of the radix to ensure a reliable solution and error estimates.
!>     Scaling by powers of the radix does not cause rounding errors unless
!>     the result underflows or overflows. Rounding errors during scaling
!>     lead to refining with a matrix that is not equivalent to the
!>     input matrix, producing error estimates that may not be
!>     reliable.
!>
[in]B
!>          B is COMPLEX*16 array, dimension (LDB,NRHS)
!>     The right-hand-side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>     The leading dimension of the array B.  LDB >= max(1,N).
!>
[in,out]Y
!>          Y is COMPLEX*16 array, dimension (LDY,NRHS)
!>     On entry, the solution matrix X, as computed by ZSYTRS.
!>     On exit, the improved solution matrix Y.
!>
[in]LDY
!>          LDY is INTEGER
!>     The leading dimension of the array Y.  LDY >= max(1,N).
!>
[out]BERR_OUT
!>          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
!>     On exit, BERR_OUT(j) contains the componentwise relative backward
!>     error for right-hand-side j from the formula
!>         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
!>     where abs(Z) is the componentwise absolute value of the matrix
!>     or vector Z. This is computed by ZLA_LIN_BERR.
!>
[in]N_NORMS
!>          N_NORMS is INTEGER
!>     Determines which error bounds to return (see ERR_BNDS_NORM
!>     and ERR_BNDS_COMP).
!>     If N_NORMS >= 1 return normwise error bounds.
!>     If N_NORMS >= 2 return componentwise error bounds.
!>
[in,out]ERR_BNDS_NORM
!>          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     normwise relative error, which is defined as follows:
!>
!>     Normwise relative error in the ith solution vector:
!>             max_j (abs(XTRUE(j,i) - X(j,i)))
!>            ------------------------------
!>                  max_j abs(X(j,i))
!>
!>     The array is indexed by the type of error information as described
!>     below. There currently are up to three pieces of information
!>     returned.
!>
!>     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_NORM(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated normwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*A, where S scales each row by a power of the
!>              radix so all absolute row sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in,out]ERR_BNDS_COMP
!>          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     componentwise relative error, which is defined as follows:
!>
!>     Componentwise relative error in the ith solution vector:
!>                    abs(XTRUE(j,i) - X(j,i))
!>             max_j ----------------------
!>                         abs(X(j,i))
!>
!>     The array is indexed by the right-hand side i (on which the
!>     componentwise relative error depends), and the type of error
!>     information as described below. There currently are up to three
!>     pieces of information returned for each right-hand side. If
!>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
!>     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
!>     the first (:,N_ERR_BNDS) entries are returned.
!>
!>     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERR_BNDS_COMP(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated componentwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*(A*diag(x)), where x is the solution for the
!>              current right-hand side and S scales each row of
!>              A*diag(x) by a power of the radix so all absolute row
!>              sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in]RES
!>          RES is COMPLEX*16 array, dimension (N)
!>     Workspace to hold the intermediate residual.
!>
[in]AYB
!>          AYB is DOUBLE PRECISION array, dimension (N)
!>     Workspace.
!>
[in]DY
!>          DY is COMPLEX*16 array, dimension (N)
!>     Workspace to hold the intermediate solution.
!>
[in]Y_TAIL
!>          Y_TAIL is COMPLEX*16 array, dimension (N)
!>     Workspace to hold the trailing bits of the intermediate solution.
!>
[in]RCOND
!>          RCOND is DOUBLE PRECISION
!>     Reciprocal scaled condition number.  This is an estimate of the
!>     reciprocal Skeel condition number of the matrix A after
!>     equilibration (if done).  If this is less than the machine
!>     precision (in particular, if it is zero), the matrix is singular
!>     to working precision.  Note that the error may still be small even
!>     if this number is very small and the matrix appears ill-
!>     conditioned.
!>
[in]ITHRESH
!>          ITHRESH is INTEGER
!>     The maximum number of residual computations allowed for
!>     refinement. The default is 10. For 'aggressive' set to 100 to
!>     permit convergence using approximate factorizations or
!>     factorizations other than LU. If the factorization uses a
!>     technique other than Gaussian elimination, the guarantees in
!>     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
!>
[in]RTHRESH
!>          RTHRESH is DOUBLE PRECISION
!>     Determines when to stop refinement if the error estimate stops
!>     decreasing. Refinement will stop when the next solution no longer
!>     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
!>     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
!>     default value is 0.5. For 'aggressive' set to 0.9 to permit
!>     convergence on extremely ill-conditioned matrices. See LAWN 165
!>     for more details.
!>
[in]DZ_UB
!>          DZ_UB is DOUBLE PRECISION
!>     Determines when to start considering componentwise convergence.
!>     Componentwise convergence is only considered after each component
!>     of the solution Y is stable, which we define as the relative
!>     change in each component being less than DZ_UB. The default value
!>     is 0.25, requiring the first bit to be stable. See LAWN 165 for
!>     more details.
!>
[in]IGNORE_CWISE
!>          IGNORE_CWISE is LOGICAL
!>     If .TRUE. then ignore componentwise convergence. Default value
!>     is .FALSE..
!>
[out]INFO
!>          INFO is INTEGER
!>       = 0:  Successful exit.
!>       < 0:  if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
!>             value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 386 of file zla_syrfsx_extended.f.

394*
395* -- LAPACK computational routine --
396* -- LAPACK is a software package provided by Univ. of Tennessee, --
397* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
398*
399* .. Scalar Arguments ..
400 INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
401 $ N_NORMS, ITHRESH
402 CHARACTER UPLO
403 LOGICAL COLEQU, IGNORE_CWISE
404 DOUBLE PRECISION RTHRESH, DZ_UB
405* ..
406* .. Array Arguments ..
407 INTEGER IPIV( * )
408 COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
409 $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
410 DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
411 $ ERR_BNDS_NORM( NRHS, * ),
412 $ ERR_BNDS_COMP( NRHS, * )
413* ..
414*
415* =====================================================================
416*
417* .. Local Scalars ..
418 INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
419 $ Y_PREC_STATE
420 DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
421 $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
422 $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
423 $ EPS, HUGEVAL, INCR_THRESH
424 LOGICAL INCR_PREC, UPPER
425 COMPLEX*16 ZDUM
426* ..
427* .. Parameters ..
428 INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
429 $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
430 $ EXTRA_Y
431 parameter( unstable_state = 0, working_state = 1,
432 $ conv_state = 2, noprog_state = 3 )
433 parameter( base_residual = 0, extra_residual = 1,
434 $ extra_y = 2 )
435 INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
436 INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
437 INTEGER CMP_ERR_I, PIV_GROWTH_I
438 parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
439 $ berr_i = 3 )
440 parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
441 parameter( cmp_rcond_i = 7, cmp_err_i = 8,
442 $ piv_growth_i = 9 )
443 INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
444 $ LA_LINRX_CWISE_I
445 parameter( la_linrx_itref_i = 1,
446 $ la_linrx_ithresh_i = 2 )
447 parameter( la_linrx_cwise_i = 3 )
448 INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
449 $ LA_LINRX_RCOND_I
450 parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
451 parameter( la_linrx_rcond_i = 3 )
452* ..
453* .. External Functions ..
454 LOGICAL LSAME
455 EXTERNAL ilauplo
456 INTEGER ILAUPLO
457* ..
458* .. External Subroutines ..
459 EXTERNAL zaxpy, zcopy, zsytrs, zsymv,
460 $ blas_zsymv_x,
461 $ blas_zsymv2_x, zla_syamv, zla_wwaddw,
462 $ zla_lin_berr
463 DOUBLE PRECISION DLAMCH
464* ..
465* .. Intrinsic Functions ..
466 INTRINSIC abs, real, dimag, max, min
467* ..
468* .. Statement Functions ..
469 DOUBLE PRECISION CABS1
470* ..
471* .. Statement Function Definitions ..
472 cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
473* ..
474* .. Executable Statements ..
475*
476 info = 0
477 upper = lsame( uplo, 'U' )
478 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
479 info = -2
480 ELSE IF( n.LT.0 ) THEN
481 info = -3
482 ELSE IF( nrhs.LT.0 ) THEN
483 info = -4
484 ELSE IF( lda.LT.max( 1, n ) ) THEN
485 info = -6
486 ELSE IF( ldaf.LT.max( 1, n ) ) THEN
487 info = -8
488 ELSE IF( ldb.LT.max( 1, n ) ) THEN
489 info = -13
490 ELSE IF( ldy.LT.max( 1, n ) ) THEN
491 info = -15
492 END IF
493 IF( info.NE.0 ) THEN
494 CALL xerbla( 'ZLA_HERFSX_EXTENDED', -info )
495 RETURN
496 END IF
497 eps = dlamch( 'Epsilon' )
498 hugeval = dlamch( 'Overflow' )
499* Force HUGEVAL to Inf
500 hugeval = hugeval * hugeval
501* Using HUGEVAL may lead to spurious underflows.
502 incr_thresh = dble( n ) * eps
503
504 IF ( lsame( uplo, 'L' ) ) THEN
505 uplo2 = ilauplo( 'L' )
506 ELSE
507 uplo2 = ilauplo( 'U' )
508 ENDIF
509
510 DO j = 1, nrhs
511 y_prec_state = extra_residual
512 IF ( y_prec_state .EQ. extra_y ) THEN
513 DO i = 1, n
514 y_tail( i ) = 0.0d+0
515 END DO
516 END IF
517
518 dxrat = 0.0d+0
519 dxratmax = 0.0d+0
520 dzrat = 0.0d+0
521 dzratmax = 0.0d+0
522 final_dx_x = hugeval
523 final_dz_z = hugeval
524 prevnormdx = hugeval
525 prev_dz_z = hugeval
526 dz_z = hugeval
527 dx_x = hugeval
528
529 x_state = working_state
530 z_state = unstable_state
531 incr_prec = .false.
532
533 DO cnt = 1, ithresh
534*
535* Compute residual RES = B_s - op(A_s) * Y,
536* op(A) = A, A**T, or A**H depending on TRANS (and type).
537*
538 CALL zcopy( n, b( 1, j ), 1, res, 1 )
539 IF ( y_prec_state .EQ. base_residual ) THEN
540 CALL zsymv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j),
541 $ 1,
542 $ dcmplx(1.0d+0), res, 1 )
543 ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
544 CALL blas_zsymv_x( uplo2, n, dcmplx(-1.0d+0), a, lda,
545 $ y( 1, j ), 1, dcmplx(1.0d+0), res, 1, prec_type )
546 ELSE
547 CALL blas_zsymv2_x(uplo2, n, dcmplx(-1.0d+0), a, lda,
548 $ y(1, j), y_tail, 1, dcmplx(1.0d+0), res, 1,
549 $ prec_type)
550 END IF
551
552! XXX: RES is no longer needed.
553 CALL zcopy( n, res, 1, dy, 1 )
554 CALL zsytrs( uplo, n, 1, af, ldaf, ipiv, dy, n, info )
555*
556* Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
557*
558 normx = 0.0d+0
559 normy = 0.0d+0
560 normdx = 0.0d+0
561 dz_z = 0.0d+0
562 ymin = hugeval
563
564 DO i = 1, n
565 yk = cabs1( y( i, j ) )
566 dyk = cabs1( dy( i ) )
567
568 IF ( yk .NE. 0.0d+0 ) THEN
569 dz_z = max( dz_z, dyk / yk )
570 ELSE IF ( dyk .NE. 0.0d+0 ) THEN
571 dz_z = hugeval
572 END IF
573
574 ymin = min( ymin, yk )
575
576 normy = max( normy, yk )
577
578 IF ( colequ ) THEN
579 normx = max( normx, yk * c( i ) )
580 normdx = max( normdx, dyk * c( i ) )
581 ELSE
582 normx = normy
583 normdx = max( normdx, dyk )
584 END IF
585 END DO
586
587 IF ( normx .NE. 0.0d+0 ) THEN
588 dx_x = normdx / normx
589 ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
590 dx_x = 0.0d+0
591 ELSE
592 dx_x = hugeval
593 END IF
594
595 dxrat = normdx / prevnormdx
596 dzrat = dz_z / prev_dz_z
597*
598* Check termination criteria.
599*
600 IF ( ymin*rcond .LT. incr_thresh*normy
601 $ .AND. y_prec_state .LT. extra_y )
602 $ incr_prec = .true.
603
604 IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
605 $ x_state = working_state
606 IF ( x_state .EQ. working_state ) THEN
607 IF ( dx_x .LE. eps ) THEN
608 x_state = conv_state
609 ELSE IF ( dxrat .GT. rthresh ) THEN
610 IF ( y_prec_state .NE. extra_y ) THEN
611 incr_prec = .true.
612 ELSE
613 x_state = noprog_state
614 END IF
615 ELSE
616 IF (dxrat .GT. dxratmax) dxratmax = dxrat
617 END IF
618 IF ( x_state .GT. working_state ) final_dx_x = dx_x
619 END IF
620
621 IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
622 $ z_state = working_state
623 IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
624 $ z_state = working_state
625 IF ( z_state .EQ. working_state ) THEN
626 IF ( dz_z .LE. eps ) THEN
627 z_state = conv_state
628 ELSE IF ( dz_z .GT. dz_ub ) THEN
629 z_state = unstable_state
630 dzratmax = 0.0d+0
631 final_dz_z = hugeval
632 ELSE IF ( dzrat .GT. rthresh ) THEN
633 IF ( y_prec_state .NE. extra_y ) THEN
634 incr_prec = .true.
635 ELSE
636 z_state = noprog_state
637 END IF
638 ELSE
639 IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
640 END IF
641 IF ( z_state .GT. working_state ) final_dz_z = dz_z
642 END IF
643
644 IF ( x_state.NE.working_state.AND.
645 $ ( ignore_cwise.OR.z_state.NE.working_state ) )
646 $ GOTO 666
647
648 IF ( incr_prec ) THEN
649 incr_prec = .false.
650 y_prec_state = y_prec_state + 1
651 DO i = 1, n
652 y_tail( i ) = 0.0d+0
653 END DO
654 END IF
655
656 prevnormdx = normdx
657 prev_dz_z = dz_z
658*
659* Update solution.
660*
661 IF ( y_prec_state .LT. extra_y ) THEN
662 CALL zaxpy( n, dcmplx(1.0d+0), dy, 1, y(1,j), 1 )
663 ELSE
664 CALL zla_wwaddw( n, y(1,j), y_tail, dy )
665 END IF
666
667 END DO
668* Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
669 666 CONTINUE
670*
671* Set final_* when cnt hits ithresh.
672*
673 IF ( x_state .EQ. working_state ) final_dx_x = dx_x
674 IF ( z_state .EQ. working_state ) final_dz_z = dz_z
675*
676* Compute error bounds.
677*
678 IF ( n_norms .GE. 1 ) THEN
679 err_bnds_norm( j, la_linrx_err_i ) =
680 $ final_dx_x / (1 - dxratmax)
681 END IF
682 IF ( n_norms .GE. 2 ) THEN
683 err_bnds_comp( j, la_linrx_err_i ) =
684 $ final_dz_z / (1 - dzratmax)
685 END IF
686*
687* Compute componentwise relative backward error from formula
688* max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
689* where abs(Z) is the componentwise absolute value of the matrix
690* or vector Z.
691*
692* Compute residual RES = B_s - op(A_s) * Y,
693* op(A) = A, A**T, or A**H depending on TRANS (and type).
694*
695 CALL zcopy( n, b( 1, j ), 1, res, 1 )
696 CALL zsymv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j), 1,
697 $ dcmplx(1.0d+0), res, 1 )
698
699 DO i = 1, n
700 ayb( i ) = cabs1( b( i, j ) )
701 END DO
702*
703* Compute abs(op(A_s))*abs(Y) + abs(B_s).
704*
705 CALL zla_syamv ( uplo2, n, 1.0d+0,
706 $ a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )
707
708 CALL zla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
709*
710* End of loop for each RHS.
711*
712 END DO
713*
714 RETURN
715*
716* End of ZLA_SYRFSX_EXTENDED
717*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zaxpy
subroutine zaxpy(n, za, zx, incx, zy, incy)
ZAXPY
Definition zaxpy.f:88
zcopy
subroutine zcopy(n, zx, incx, zy, incy)
ZCOPY
Definition zcopy.f:81
zsymv
subroutine zsymv(uplo, n, alpha, a, lda, x, incx, beta, y, incy)
ZSYMV computes a matrix-vector product for a complex symmetric matrix.
Definition zsymv.f:156
zsytrs
subroutine zsytrs(uplo, n, nrhs, a, lda, ipiv, b, ldb, info)
ZSYTRS
Definition zsytrs.f:118
ilauplo
integer function ilauplo(uplo)
ILAUPLO
Definition ilauplo.f:56
zla_syamv
subroutine zla_syamv(uplo, n, alpha, a, lda, x, incx, beta, y, incy)
ZLA_SYAMV computes a matrix-vector product using a symmetric indefinite matrix to calculate error bou...
Definition zla_syamv.f:177
zla_lin_berr
subroutine zla_lin_berr(n, nz, nrhs, res, ayb, berr)
ZLA_LIN_BERR computes a component-wise relative backward error.
Definition zla_lin_berr.f:99
zla_wwaddw
subroutine zla_wwaddw(n, x, y, w)
ZLA_WWADDW adds a vector into a doubled-single vector.
Definition zla_wwaddw.f:79
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: