slaed7()

subroutine slaed7	(	integer	icompq,
		integer	n,
		integer	qsiz,
		integer	tlvls,
		integer	curlvl,
		integer	curpbm,
		real, dimension( * )	d,
		real, dimension( ldq, * )	q,
		integer	ldq,
		integer, dimension( * )	indxq,
		real	rho,
		integer	cutpnt,
		real, dimension( * )	qstore,
		integer, dimension( * )	qptr,
		integer, dimension( * )	prmptr,
		integer, dimension( * )	perm,
		integer, dimension( * )	givptr,
		integer, dimension( 2, * )	givcol,
		real, dimension( 2, * )	givnum,
		real, dimension( * )	work,
		integer, dimension( * )	iwork,
		integer	info )

SLAED7 used by SSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is dense.

Download SLAED7 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SLAED7 computes the updated eigensystem of a diagonal
!> matrix after modification by a rank-one symmetric matrix. This
!> routine is used only for the eigenproblem which requires all
!> eigenvalues and optionally eigenvectors of a dense symmetric matrix
!> that has been reduced to tridiagonal form.  SLAED1 handles
!> the case in which all eigenvalues and eigenvectors of a symmetric
!> tridiagonal matrix are desired.
!>
!>   T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)
!>
!>    where Z = Q**Tu, u is a vector of length N with ones in the
!>    CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.
!>
!>    The eigenvectors of the original matrix are stored in Q, and the
!>    eigenvalues are in D.  The algorithm consists of three stages:
!>
!>       The first stage consists of deflating the size of the problem
!>       when there are multiple eigenvalues or if there is a zero in
!>       the Z vector.  For each such occurrence the dimension of the
!>       secular equation problem is reduced by one.  This stage is
!>       performed by the routine SLAED8.
!>
!>       The second stage consists of calculating the updated
!>       eigenvalues. This is done by finding the roots of the secular
!>       equation via the routine SLAED4 (as called by SLAED9).
!>       This routine also calculates the eigenvectors of the current
!>       problem.
!>
!>       The final stage consists of computing the updated eigenvectors
!>       directly using the updated eigenvalues.  The eigenvectors for
!>       the current problem are multiplied with the eigenvectors from
!>       the overall problem.
!> 

Parameters

[in]	ICOMPQ	!> ICOMPQ is INTEGER !> = 0: Compute eigenvalues only. !> = 1: Compute eigenvectors of original dense symmetric matrix !> also. On entry, Q contains the orthogonal matrix used !> to reduce the original matrix to tridiagonal form. !>
[in]	N	!> N is INTEGER !> The dimension of the symmetric tridiagonal matrix. N >= 0. !>
[in]	QSIZ	!> QSIZ is INTEGER !> The dimension of the orthogonal matrix used to reduce !> the full matrix to tridiagonal form. QSIZ >= N if ICOMPQ = 1. !>
[in]	TLVLS	!> TLVLS is INTEGER !> The total number of merging levels in the overall divide and !> conquer tree. !>
[in]	CURLVL	!> CURLVL is INTEGER !> The current level in the overall merge routine, !> 0 <= CURLVL <= TLVLS. !>
[in]	CURPBM	!> CURPBM is INTEGER !> The current problem in the current level in the overall !> merge routine (counting from upper left to lower right). !>
[in,out]	D	!> D is REAL array, dimension (N) !> On entry, the eigenvalues of the rank-1-perturbed matrix. !> On exit, the eigenvalues of the repaired matrix. !>
[in,out]	Q	!> Q is REAL array, dimension (LDQ, N) !> On entry, the eigenvectors of the rank-1-perturbed matrix. !> On exit, the eigenvectors of the repaired tridiagonal matrix. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,N). !>
[out]	INDXQ	!> INDXQ is INTEGER array, dimension (N) !> The permutation which will reintegrate the subproblem just !> solved back into sorted order, i.e., D( INDXQ( I = 1, N ) ) !> will be in ascending order. !>
[in]	RHO	!> RHO is REAL !> The subdiagonal element used to create the rank-1 !> modification. !>
[in]	CUTPNT	!> CUTPNT is INTEGER !> Contains the location of the last eigenvalue in the leading !> sub-matrix. min(1,N) <= CUTPNT <= N. !>
[in,out]	QSTORE	!> QSTORE is REAL array, dimension (N**2+1) !> Stores eigenvectors of submatrices encountered during !> divide and conquer, packed together. QPTR points to !> beginning of the submatrices. !>
[in,out]	QPTR	!> QPTR is INTEGER array, dimension (N+2) !> List of indices pointing to beginning of submatrices stored !> in QSTORE. The submatrices are numbered starting at the !> bottom left of the divide and conquer tree, from left to !> right and bottom to top. !>
[in]	PRMPTR	!> PRMPTR is INTEGER array, dimension (N lg N) !> Contains a list of pointers which indicate where in PERM a !> level's permutation is stored. PRMPTR(i+1) - PRMPTR(i) !> indicates the size of the permutation and also the size of !> the full, non-deflated problem. !>
[in]	PERM	!> PERM is INTEGER array, dimension (N lg N) !> Contains the permutations (from deflation and sorting) to be !> applied to each eigenblock. !>
[in]	GIVPTR	!> GIVPTR is INTEGER array, dimension (N lg N) !> Contains a list of pointers which indicate where in GIVCOL a !> level's Givens rotations are stored. GIVPTR(i+1) - GIVPTR(i) !> indicates the number of Givens rotations. !>
[in]	GIVCOL	!> GIVCOL is INTEGER array, dimension (2, N lg N) !> Each pair of numbers indicates a pair of columns to take place !> in a Givens rotation. !>
[in]	GIVNUM	!> GIVNUM is REAL array, dimension (2, N lg N) !> Each number indicates the S value to be used in the !> corresponding Givens rotation. !>
[out]	WORK	!> WORK is REAL array, dimension (3*N+2*QSIZ*N) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (4*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = 1, an eigenvalue did not converge !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Jeff Rutter, Computer Science Division, University of California at Berkeley, USA

Definition at line 254 of file slaed7.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            CURLVL, CURPBM, CUTPNT, ICOMPQ, INFO, LDQ, N,
     $                   QSIZ, TLVLS
      REAL               RHO
*     ..
*     .. Array Arguments ..
      INTEGER            GIVCOL( 2, * ), GIVPTR( * ), INDXQ( * ),
     $                   IWORK( * ), PERM( * ), PRMPTR( * ), QPTR( * )
      REAL               D( * ), GIVNUM( 2, * ), Q( LDQ, * ),
     $                   QSTORE( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            COLTYP, CURR, I, IDLMDA, INDX, INDXC, INDXP,
     $                   IQ2, IS, IW, IZ, K, LDQ2, N1, N2, PTR
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slaed8, slaed9, slaeda, slamrg,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( icompq.LT.0 .OR. icompq.GT.1 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( icompq.EQ.1 .AND. qsiz.LT.n ) THEN
         info = -3
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( min( 1, n ).GT.cutpnt .OR. n.LT.cutpnt ) THEN
         info = -12
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLAED7', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     The following values are for bookkeeping purposes only.  They are
*     integer pointers which indicate the portion of the workspace
*     used by a particular array in SLAED8 and SLAED9.
*
      IF( icompq.EQ.1 ) THEN
         ldq2 = qsiz
      ELSE
         ldq2 = n
      END IF
*
      iz = 1
      idlmda = iz + n
      iw = idlmda + n
      iq2 = iw + n
      is = iq2 + n*ldq2
*
      indx = 1
      indxc = indx + n
      coltyp = indxc + n
      indxp = coltyp + n
*
*     Form the z-vector which consists of the last row of Q_1 and the
*     first row of Q_2.
*
      ptr = 1 + 2**tlvls
      DO 10 i = 1, curlvl - 1
         ptr = ptr + 2**( tlvls-i )
   10 CONTINUE
      curr = ptr + curpbm
      CALL slaeda( n, tlvls, curlvl, curpbm, prmptr, perm, givptr,
     $             givcol, givnum, qstore, qptr, work( iz ),
     $             work( iz+n ), info )
*
*     When solving the final problem, we no longer need the stored data,
*     so we will overwrite the data from this level onto the previously
*     used storage space.
*
      IF( curlvl.EQ.tlvls ) THEN
         qptr( curr ) = 1
         prmptr( curr ) = 1
         givptr( curr ) = 1
      END IF
*
*     Sort and Deflate eigenvalues.
*
      CALL slaed8( icompq, k, n, qsiz, d, q, ldq, indxq, rho, cutpnt,
     $             work( iz ), work( idlmda ), work( iq2 ), ldq2,
     $             work( iw ), perm( prmptr( curr ) ), givptr( curr+1 ),
     $             givcol( 1, givptr( curr ) ),
     $             givnum( 1, givptr( curr ) ), iwork( indxp ),
     $             iwork( indx ), info )
      prmptr( curr+1 ) = prmptr( curr ) + n
      givptr( curr+1 ) = givptr( curr+1 ) + givptr( curr )
*
*     Solve Secular Equation.
*
      IF( k.NE.0 ) THEN
         CALL slaed9( k, 1, k, n, d, work( is ), k, rho,
     $                work( idlmda ),
     $                work( iw ), qstore( qptr( curr ) ), k, info )
         IF( info.NE.0 )
     $      GO TO 30
         IF( icompq.EQ.1 ) THEN
            CALL sgemm( 'N', 'N', qsiz, k, k, one, work( iq2 ), ldq2,
     $                  qstore( qptr( curr ) ), k, zero, q, ldq )
         END IF
         qptr( curr+1 ) = qptr( curr ) + k**2
*
*     Prepare the INDXQ sorting permutation.
*
         n1 = k
         n2 = n - k
         CALL slamrg( n1, n2, d, 1, -1, indxq )
      ELSE
         qptr( curr+1 ) = qptr( curr )
         DO 20 i = 1, n
            indxq( i ) = i
   20    CONTINUE
      END IF
*
   30 CONTINUE
      RETURN
*
*     End of SLAED7
*

Here is the call graph for this function:

Here is the caller graph for this function: