LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ slaed8()

subroutine slaed8 ( integer icompq,
integer k,
integer n,
integer qsiz,
real, dimension( * ) d,
real, dimension( ldq, * ) q,
integer ldq,
integer, dimension( * ) indxq,
real rho,
integer cutpnt,
real, dimension( * ) z,
real, dimension( * ) dlambda,
real, dimension( ldq2, * ) q2,
integer ldq2,
real, dimension( * ) w,
integer, dimension( * ) perm,
integer givptr,
integer, dimension( 2, * ) givcol,
real, dimension( 2, * ) givnum,
integer, dimension( * ) indxp,
integer, dimension( * ) indx,
integer info )

SLAED8 used by SSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matrix is dense.

Download SLAED8 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SLAED8 merges the two sets of eigenvalues together into a single
!> sorted set.  Then it tries to deflate the size of the problem.
!> There are two ways in which deflation can occur:  when two or more
!> eigenvalues are close together or if there is a tiny element in the
!> Z vector.  For each such occurrence the order of the related secular
!> equation problem is reduced by one.
!>
Parameters
[in]ICOMPQ
!>          ICOMPQ is INTEGER
!>          = 0:  Compute eigenvalues only.
!>          = 1:  Compute eigenvectors of original dense symmetric matrix
!>                also.  On entry, Q contains the orthogonal matrix used
!>                to reduce the original matrix to tridiagonal form.
!>
[out]K
!>          K is INTEGER
!>         The number of non-deflated eigenvalues, and the order of the
!>         related secular equation.
!>
[in]N
!>          N is INTEGER
!>         The dimension of the symmetric tridiagonal matrix.  N >= 0.
!>
[in]QSIZ
!>          QSIZ is INTEGER
!>         The dimension of the orthogonal matrix used to reduce
!>         the full matrix to tridiagonal form.  QSIZ >= N if ICOMPQ = 1.
!>
[in,out]D
!>          D is REAL array, dimension (N)
!>         On entry, the eigenvalues of the two submatrices to be
!>         combined.  On exit, the trailing (N-K) updated eigenvalues
!>         (those which were deflated) sorted into increasing order.
!>
[in,out]Q
!>          Q is REAL array, dimension (LDQ,N)
!>         If ICOMPQ = 0, Q is not referenced.  Otherwise,
!>         on entry, Q contains the eigenvectors of the partially solved
!>         system which has been previously updated in matrix
!>         multiplies with other partially solved eigensystems.
!>         On exit, Q contains the trailing (N-K) updated eigenvectors
!>         (those which were deflated) in its last N-K columns.
!>
[in]LDQ
!>          LDQ is INTEGER
!>         The leading dimension of the array Q.  LDQ >= max(1,N).
!>
[in]INDXQ
!>          INDXQ is INTEGER array, dimension (N)
!>         The permutation which separately sorts the two sub-problems
!>         in D into ascending order.  Note that elements in the second
!>         half of this permutation must first have CUTPNT added to
!>         their values in order to be accurate.
!>
[in,out]RHO
!>          RHO is REAL
!>         On entry, the off-diagonal element associated with the rank-1
!>         cut which originally split the two submatrices which are now
!>         being recombined.
!>         On exit, RHO has been modified to the value required by
!>         SLAED3.
!>
[in]CUTPNT
!>          CUTPNT is INTEGER
!>         The location of the last eigenvalue in the leading
!>         sub-matrix.  min(1,N) <= CUTPNT <= N.
!>
[in]Z
!>          Z is REAL array, dimension (N)
!>         On entry, Z contains the updating vector (the last row of
!>         the first sub-eigenvector matrix and the first row of the
!>         second sub-eigenvector matrix).
!>         On exit, the contents of Z are destroyed by the updating
!>         process.
!>
[out]DLAMBDA
!>          DLAMBDA is REAL array, dimension (N)
!>         A copy of the first K eigenvalues which will be used by
!>         SLAED3 to form the secular equation.
!>
[out]Q2
!>          Q2 is REAL array, dimension (LDQ2,N)
!>         If ICOMPQ = 0, Q2 is not referenced.  Otherwise,
!>         a copy of the first K eigenvectors which will be used by
!>         SLAED7 in a matrix multiply (SGEMM) to update the new
!>         eigenvectors.
!>
[in]LDQ2
!>          LDQ2 is INTEGER
!>         The leading dimension of the array Q2.  LDQ2 >= max(1,N).
!>
[out]W
!>          W is REAL array, dimension (N)
!>         The first k values of the final deflation-altered z-vector and
!>         will be passed to SLAED3.
!>
[out]PERM
!>          PERM is INTEGER array, dimension (N)
!>         The permutations (from deflation and sorting) to be applied
!>         to each eigenblock.
!>
[out]GIVPTR
!>          GIVPTR is INTEGER
!>         The number of Givens rotations which took place in this
!>         subproblem.
!>
[out]GIVCOL
!>          GIVCOL is INTEGER array, dimension (2, N)
!>         Each pair of numbers indicates a pair of columns to take place
!>         in a Givens rotation.
!>
[out]GIVNUM
!>          GIVNUM is REAL array, dimension (2, N)
!>         Each number indicates the S value to be used in the
!>         corresponding Givens rotation.
!>
[out]INDXP
!>          INDXP is INTEGER array, dimension (N)
!>         The permutation used to place deflated values of D at the end
!>         of the array.  INDXP(1:K) points to the nondeflated D-values
!>         and INDXP(K+1:N) points to the deflated eigenvalues.
!>
[out]INDX
!>          INDX is INTEGER array, dimension (N)
!>         The permutation used to sort the contents of D into ascending
!>         order.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit.
!>          < 0:  if INFO = -i, the i-th argument had an illegal value.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
Jeff Rutter, Computer Science Division, University of California at Berkeley, USA

Definition at line 238 of file slaed8.f.

241*
242* -- LAPACK computational routine --
243* -- LAPACK is a software package provided by Univ. of Tennessee, --
244* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
245*
246* .. Scalar Arguments ..
247 INTEGER CUTPNT, GIVPTR, ICOMPQ, INFO, K, LDQ, LDQ2, N,
248 $ QSIZ
249 REAL RHO
250* ..
251* .. Array Arguments ..
252 INTEGER GIVCOL( 2, * ), INDX( * ), INDXP( * ),
253 $ INDXQ( * ), PERM( * )
254 REAL D( * ), DLAMBDA( * ), GIVNUM( 2, * ),
255 $ Q( LDQ, * ), Q2( LDQ2, * ), W( * ), Z( * )
256* ..
257*
258* =====================================================================
259*
260* .. Parameters ..
261 REAL MONE, ZERO, ONE, TWO, EIGHT
262 parameter( mone = -1.0e0, zero = 0.0e0, one = 1.0e0,
263 $ two = 2.0e0, eight = 8.0e0 )
264* ..
265* .. Local Scalars ..
266*
267 INTEGER I, IMAX, J, JLAM, JMAX, JP, K2, N1, N1P1, N2
268 REAL C, EPS, S, T, TAU, TOL
269* ..
270* .. External Functions ..
271 INTEGER ISAMAX
272 REAL SLAMCH, SLAPY2
273 EXTERNAL isamax, slamch, slapy2
274* ..
275* .. External Subroutines ..
276 EXTERNAL scopy, slacpy, slamrg, srot, sscal,
277 $ xerbla
278* ..
279* .. Intrinsic Functions ..
280 INTRINSIC abs, max, min, sqrt
281* ..
282* .. Executable Statements ..
283*
284* Test the input parameters.
285*
286 info = 0
287*
288 IF( icompq.LT.0 .OR. icompq.GT.1 ) THEN
289 info = -1
290 ELSE IF( n.LT.0 ) THEN
291 info = -3
292 ELSE IF( icompq.EQ.1 .AND. qsiz.LT.n ) THEN
293 info = -4
294 ELSE IF( ldq.LT.max( 1, n ) ) THEN
295 info = -7
296 ELSE IF( cutpnt.LT.min( 1, n ) .OR. cutpnt.GT.n ) THEN
297 info = -10
298 ELSE IF( ldq2.LT.max( 1, n ) ) THEN
299 info = -14
300 END IF
301 IF( info.NE.0 ) THEN
302 CALL xerbla( 'SLAED8', -info )
303 RETURN
304 END IF
305*
306* Need to initialize GIVPTR to O here in case of quick exit
307* to prevent an unspecified code behavior (usually sigfault)
308* when IWORK array on entry to *stedc is not zeroed
309* (or at least some IWORK entries which used in *laed7 for GIVPTR).
310*
311 givptr = 0
312*
313* Quick return if possible
314*
315 IF( n.EQ.0 )
316 $ RETURN
317*
318 n1 = cutpnt
319 n2 = n - n1
320 n1p1 = n1 + 1
321*
322 IF( rho.LT.zero ) THEN
323 CALL sscal( n2, mone, z( n1p1 ), 1 )
324 END IF
325*
326* Normalize z so that norm(z) = 1
327*
328 t = one / sqrt( two )
329 DO 10 j = 1, n
330 indx( j ) = j
331 10 CONTINUE
332 CALL sscal( n, t, z, 1 )
333 rho = abs( two*rho )
334*
335* Sort the eigenvalues into increasing order
336*
337 DO 20 i = cutpnt + 1, n
338 indxq( i ) = indxq( i ) + cutpnt
339 20 CONTINUE
340 DO 30 i = 1, n
341 dlambda( i ) = d( indxq( i ) )
342 w( i ) = z( indxq( i ) )
343 30 CONTINUE
344 i = 1
345 j = cutpnt + 1
346 CALL slamrg( n1, n2, dlambda, 1, 1, indx )
347 DO 40 i = 1, n
348 d( i ) = dlambda( indx( i ) )
349 z( i ) = w( indx( i ) )
350 40 CONTINUE
351*
352* Calculate the allowable deflation tolerance
353*
354 imax = isamax( n, z, 1 )
355 jmax = isamax( n, d, 1 )
356 eps = slamch( 'Epsilon' )
357 tol = eight*eps*abs( d( jmax ) )
358*
359* If the rank-1 modifier is small enough, no more needs to be done
360* except to reorganize Q so that its columns correspond with the
361* elements in D.
362*
363 IF( rho*abs( z( imax ) ).LE.tol ) THEN
364 k = 0
365 IF( icompq.EQ.0 ) THEN
366 DO 50 j = 1, n
367 perm( j ) = indxq( indx( j ) )
368 50 CONTINUE
369 ELSE
370 DO 60 j = 1, n
371 perm( j ) = indxq( indx( j ) )
372 CALL scopy( qsiz, q( 1, perm( j ) ), 1, q2( 1, j ),
373 $ 1 )
374 60 CONTINUE
375 CALL slacpy( 'A', qsiz, n, q2( 1, 1 ), ldq2, q( 1, 1 ),
376 $ ldq )
377 END IF
378 RETURN
379 END IF
380*
381* If there are multiple eigenvalues then the problem deflates. Here
382* the number of equal eigenvalues are found. As each equal
383* eigenvalue is found, an elementary reflector is computed to rotate
384* the corresponding eigensubspace so that the corresponding
385* components of Z are zero in this new basis.
386*
387 k = 0
388 k2 = n + 1
389 DO 70 j = 1, n
390 IF( rho*abs( z( j ) ).LE.tol ) THEN
391*
392* Deflate due to small z component.
393*
394 k2 = k2 - 1
395 indxp( k2 ) = j
396 IF( j.EQ.n )
397 $ GO TO 110
398 ELSE
399 jlam = j
400 GO TO 80
401 END IF
402 70 CONTINUE
403 80 CONTINUE
404 j = j + 1
405 IF( j.GT.n )
406 $ GO TO 100
407 IF( rho*abs( z( j ) ).LE.tol ) THEN
408*
409* Deflate due to small z component.
410*
411 k2 = k2 - 1
412 indxp( k2 ) = j
413 ELSE
414*
415* Check if eigenvalues are close enough to allow deflation.
416*
417 s = z( jlam )
418 c = z( j )
419*
420* Find sqrt(a**2+b**2) without overflow or
421* destructive underflow.
422*
423 tau = slapy2( c, s )
424 t = d( j ) - d( jlam )
425 c = c / tau
426 s = -s / tau
427 IF( abs( t*c*s ).LE.tol ) THEN
428*
429* Deflation is possible.
430*
431 z( j ) = tau
432 z( jlam ) = zero
433*
434* Record the appropriate Givens rotation
435*
436 givptr = givptr + 1
437 givcol( 1, givptr ) = indxq( indx( jlam ) )
438 givcol( 2, givptr ) = indxq( indx( j ) )
439 givnum( 1, givptr ) = c
440 givnum( 2, givptr ) = s
441 IF( icompq.EQ.1 ) THEN
442 CALL srot( qsiz, q( 1, indxq( indx( jlam ) ) ), 1,
443 $ q( 1, indxq( indx( j ) ) ), 1, c, s )
444 END IF
445 t = d( jlam )*c*c + d( j )*s*s
446 d( j ) = d( jlam )*s*s + d( j )*c*c
447 d( jlam ) = t
448 k2 = k2 - 1
449 i = 1
450 90 CONTINUE
451 IF( k2+i.LE.n ) THEN
452 IF( d( jlam ).LT.d( indxp( k2+i ) ) ) THEN
453 indxp( k2+i-1 ) = indxp( k2+i )
454 indxp( k2+i ) = jlam
455 i = i + 1
456 GO TO 90
457 ELSE
458 indxp( k2+i-1 ) = jlam
459 END IF
460 ELSE
461 indxp( k2+i-1 ) = jlam
462 END IF
463 jlam = j
464 ELSE
465 k = k + 1
466 w( k ) = z( jlam )
467 dlambda( k ) = d( jlam )
468 indxp( k ) = jlam
469 jlam = j
470 END IF
471 END IF
472 GO TO 80
473 100 CONTINUE
474*
475* Record the last eigenvalue.
476*
477 k = k + 1
478 w( k ) = z( jlam )
479 dlambda( k ) = d( jlam )
480 indxp( k ) = jlam
481*
482 110 CONTINUE
483*
484* Sort the eigenvalues and corresponding eigenvectors into DLAMBDA
485* and Q2 respectively. The eigenvalues/vectors which were not
486* deflated go into the first K slots of DLAMBDA and Q2 respectively,
487* while those which were deflated go into the last N - K slots.
488*
489 IF( icompq.EQ.0 ) THEN
490 DO 120 j = 1, n
491 jp = indxp( j )
492 dlambda( j ) = d( jp )
493 perm( j ) = indxq( indx( jp ) )
494 120 CONTINUE
495 ELSE
496 DO 130 j = 1, n
497 jp = indxp( j )
498 dlambda( j ) = d( jp )
499 perm( j ) = indxq( indx( jp ) )
500 CALL scopy( qsiz, q( 1, perm( j ) ), 1, q2( 1, j ), 1 )
501 130 CONTINUE
502 END IF
503*
504* The deflated eigenvalues and their corresponding vectors go back
505* into the last N - K slots of D and Q respectively.
506*
507 IF( k.LT.n ) THEN
508 IF( icompq.EQ.0 ) THEN
509 CALL scopy( n-k, dlambda( k+1 ), 1, d( k+1 ), 1 )
510 ELSE
511 CALL scopy( n-k, dlambda( k+1 ), 1, d( k+1 ), 1 )
512 CALL slacpy( 'A', qsiz, n-k, q2( 1, k+1 ), ldq2,
513 $ q( 1, k+1 ), ldq )
514 END IF
515 END IF
516*
517 RETURN
518*
519* End of SLAED8
520*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
scopy
subroutine scopy(n, sx, incx, sy, incy)
SCOPY
Definition scopy.f:82
isamax
integer function isamax(n, sx, incx)
ISAMAX
Definition isamax.f:71
slacpy
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
slamrg
subroutine slamrg(n1, n2, a, strd1, strd2, index)
SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition slamrg.f:97
slapy2
real function slapy2(x, y)
SLAPY2 returns sqrt(x2+y2).
Definition slapy2.f:61
srot
subroutine srot(n, sx, incx, sy, incy, c, s)
SROT
Definition srot.f:92
sscal
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
Here is the call graph for this function:
Here is the caller graph for this function: