slamrg()

subroutine slamrg	(	integer	n1,
		integer	n2,
		real, dimension( * )	a,
		integer	strd1,
		integer	strd2,
		integer, dimension( * )	index
	)

SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single set sorted in ascending order.

Download SLAMRG + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLAMRG will create a permutation list which will merge the elements
 of A (which is composed of two independently sorted sets) into a
 single set which is sorted in ascending order.

Parameters

[in]	N1	N1 is INTEGER
[in]	N2	N2 is INTEGER These arguments contain the respective lengths of the two sorted lists to be merged.
[in]	A	A is REAL array, dimension (N1+N2) The first N1 elements of A contain a list of numbers which are sorted in either ascending or descending order. Likewise for the final N2 elements.
[in]	STRD1	STRD1 is INTEGER
[in]	STRD2	STRD2 is INTEGER These are the strides to be taken through the array A. Allowable strides are 1 and -1. They indicate whether a subset of A is sorted in ascending (STRDx = 1) or descending (STRDx = -1) order.
[out]	INDEX	INDEX is INTEGER array, dimension (N1+N2) On exit this array will contain a permutation such that if B( I ) = A( INDEX( I ) ) for I=1,N1+N2, then B will be sorted in ascending order.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 98 of file slamrg.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N1, N2, STRD1, STRD2
*     ..
*     .. Array Arguments ..
      INTEGER            INDEX( * )
      REAL               A( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, IND1, IND2, N1SV, N2SV
*     ..
*     .. Executable Statements ..
*
      n1sv = n1
      n2sv = n2
      IF( strd1.GT.0 ) THEN
         ind1 = 1
      ELSE
         ind1 = n1
      END IF
      IF( strd2.GT.0 ) THEN
         ind2 = 1 + n1
      ELSE
         ind2 = n1 + n2
      END IF
      i = 1
*     while ( (N1SV > 0) & (N2SV > 0) )
   10 CONTINUE
      IF( n1sv.GT.0 .AND. n2sv.GT.0 ) THEN
         IF( a( ind1 ).LE.a( ind2 ) ) THEN
            index( i ) = ind1
            i = i + 1
            ind1 = ind1 + strd1
            n1sv = n1sv - 1
         ELSE
            index( i ) = ind2
            i = i + 1
            ind2 = ind2 + strd2
            n2sv = n2sv - 1
         END IF
         GO TO 10
      END IF
*     end while
      IF( n1sv.EQ.0 ) THEN
         DO 20 n1sv = 1, n2sv
            index( i ) = ind2
            i = i + 1
            ind2 = ind2 + strd2
   20    CONTINUE
      ELSE
*     N2SV .EQ. 0
         DO 30 n2sv = 1, n1sv
            index( i ) = ind1
            i = i + 1
            ind1 = ind1 + strd1
   30    CONTINUE
      END IF
*
      RETURN
*
*     End of SLAMRG
*

Here is the caller graph for this function: