zbdt05()

subroutine zbdt05	(	integer	m,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	s,
		integer	ns,
		complex*16, dimension( * )	u,
		integer	ldu,
		complex*16, dimension( ldvt, * )	vt,
		integer	ldvt,
		complex*16, dimension( * )	work,
		double precision	resid
	)

ZBDT05

Purpose:

 ZBDT05 reconstructs a bidiagonal matrix B from its (partial) SVD:
    S = U' * B * V
 where U and V are orthogonal matrices and S is diagonal.

 The test ratio to test the singular value decomposition is
    RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS )
 where VT = V' and EPS is the machine precision.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and U.
[in]	N	N is INTEGER The number of columns of the matrices A and VT.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The m by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in]	S	S is DOUBLE PRECISION array, dimension (NS) The singular values from the (partial) SVD of B, sorted in decreasing order.
[in]	NS	NS is INTEGER The number of singular values/vectors from the (partial) SVD of B.
[in]	U	U is COMPLEX*16 array, dimension (LDU,NS) The n by ns orthogonal matrix U in S = U' * B * V.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,N)
[in]	VT	VT is COMPLEX*16 array, dimension (LDVT,N) The n by ns orthogonal matrix V in S = U' * B * V.
[in]	LDVT	LDVT is INTEGER The leading dimension of the array VT.
[out]	WORK	WORK is COMPLEX*16 array, dimension (M,N)
[out]	RESID	RESID is DOUBLE PRECISION The test ratio: norm(S - U' * A * V) / ( n * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 123 of file zbdt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDU, LDVT, M, N, NS
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   S( * )
      COMPLEX*16         A( LDA, * ), U( * ), VT( LDVT, * ), WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   ANORM, EPS
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUM( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IDAMAX
      DOUBLE PRECISION   DASUM, DZASUM, DLAMCH, ZLANGE
      EXTERNAL           lsame, idamax, dasum, dzasum, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      resid = zero
      IF( min( m, n ).LE.0 .OR. ns.LE.0 )
     $   RETURN
*
      eps = dlamch( 'Precision' )
      anorm = zlange( 'M', m, n, a, lda, dum )
*
*     Compute U' * A * V.
*
      CALL zgemm( 'N', 'C', m, ns, n, cone, a, lda, vt,
     $            ldvt, czero, work( 1+ns*ns ), m )
      CALL zgemm( 'C', 'N', ns, ns, m, -cone, u, ldu, work( 1+ns*ns ),
     $            m, czero, work, ns )
*
*     norm(S - U' * B * V)
*
      j = 0
      DO 10 i = 1, ns
         work( j+i ) =  work( j+i ) + dcmplx( s( i ), zero )
         resid = max( resid, dzasum( ns, work( j+1 ), 1 ) )
         j = j + ns
   10 CONTINUE
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( anorm.GE.resid ) THEN
            resid = ( resid / anorm ) / ( dble( n )*eps )
         ELSE
            IF( anorm.LT.one ) THEN
               resid = ( min( resid, dble( n )*anorm ) / anorm ) /
     $                 ( dble( n )*eps )
            ELSE
               resid = min( resid / anorm, dble( n ) ) /
     $                 ( dble( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of ZBDT05
*

Here is the call graph for this function:

Here is the caller graph for this function: