zhet22()

subroutine zhet22	(	integer	itype,
		character	uplo,
		integer	n,
		integer	m,
		integer	kband,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		complex*16, dimension( ldu, * )	u,
		integer	ldu,
		complex*16, dimension( ldv, * )	v,
		integer	ldv,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		double precision, dimension( 2 )	result
	)

ZHET22

Purpose:

      ZHET22  generally checks a decomposition of the form

              A U = U S

      where A is complex Hermitian, the columns of U are orthonormal,
      and S is diagonal (if KBAND=0) or symmetric tridiagonal (if
      KBAND=1).  If ITYPE=1, then U is represented as a dense matrix,
      otherwise the U is expressed as a product of Householder
      transformations, whose vectors are stored in the array "V" and
      whose scaling constants are in "TAU"; we shall use the letter
      "V" to refer to the product of Householder transformations
      (which should be equal to U).

      Specifically, if ITYPE=1, then:

              RESULT(1) = | U**H A U - S | / ( |A| m ulp ) and
              RESULT(2) = | I - U**H U | / ( m ulp )

  ITYPE   INTEGER
          Specifies the type of tests to be performed.
          1: U expressed as a dense orthogonal matrix:
             RESULT(1) = | A - U S U**H | / ( |A| n ulp )   *and
             RESULT(2) = | I - U U**H | / ( n ulp )

  UPLO    CHARACTER
          If UPLO='U', the upper triangle of A will be used and the
          (strictly) lower triangle will not be referenced.  If
          UPLO='L', the lower triangle of A will be used and the
          (strictly) upper triangle will not be referenced.
          Not modified.

  N       INTEGER
          The size of the matrix.  If it is zero, ZHET22 does nothing.
          It must be at least zero.
          Not modified.

  M       INTEGER
          The number of columns of U.  If it is zero, ZHET22 does
          nothing.  It must be at least zero.
          Not modified.

  KBAND   INTEGER
          The bandwidth of the matrix.  It may only be zero or one.
          If zero, then S is diagonal, and E is not referenced.  If
          one, then S is symmetric tri-diagonal.
          Not modified.

  A       COMPLEX*16 array, dimension (LDA , N)
          The original (unfactored) matrix.  It is assumed to be
          symmetric, and only the upper (UPLO='U') or only the lower
          (UPLO='L') will be referenced.
          Not modified.

  LDA     INTEGER
          The leading dimension of A.  It must be at least 1
          and at least N.
          Not modified.

  D       DOUBLE PRECISION array, dimension (N)
          The diagonal of the (symmetric tri-) diagonal matrix.
          Not modified.

  E       DOUBLE PRECISION array, dimension (N)
          The off-diagonal of the (symmetric tri-) diagonal matrix.
          E(1) is ignored, E(2) is the (1,2) and (2,1) element, etc.
          Not referenced if KBAND=0.
          Not modified.

  U       COMPLEX*16 array, dimension (LDU, N)
          If ITYPE=1, this contains the orthogonal matrix in
          the decomposition, expressed as a dense matrix.
          Not modified.

  LDU     INTEGER
          The leading dimension of U.  LDU must be at least N and
          at least 1.
          Not modified.

  V       COMPLEX*16 array, dimension (LDV, N)
          If ITYPE=2 or 3, the lower triangle of this array contains
          the Householder vectors used to describe the orthogonal
          matrix in the decomposition.  If ITYPE=1, then it is not
          referenced.
          Not modified.

  LDV     INTEGER
          The leading dimension of V.  LDV must be at least N and
          at least 1.
          Not modified.

  TAU     COMPLEX*16 array, dimension (N)
          If ITYPE >= 2, then TAU(j) is the scalar factor of
          v(j) v(j)**H in the Householder transformation H(j) of
          the product  U = H(1)...H(n-2)
          If ITYPE < 2, then TAU is not referenced.
          Not modified.

  WORK    COMPLEX*16 array, dimension (2*N**2)
          Workspace.
          Modified.

  RWORK   DOUBLE PRECISION array, dimension (N)
          Workspace.
          Modified.

  RESULT  DOUBLE PRECISION array, dimension (2)
          The values computed by the two tests described above.  The
          values are currently limited to 1/ulp, to avoid overflow.
          RESULT(1) is always modified.  RESULT(2) is modified only
          if LDU is at least N.
          Modified.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 159 of file zhet22.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            ITYPE, KBAND, LDA, LDU, LDV, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * ), RESULT( 2 ), RWORK( * )
      COMPLEX*16         A( LDA, * ), TAU( * ), U( LDU, * ),
     $                   V( LDV, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d0, 0.0d0 ),
     $                   cone = ( 1.0d0, 0.0d0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            J, JJ, JJ1, JJ2, NN, NNP1
      DOUBLE PRECISION   ANORM, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANHE
      EXTERNAL           dlamch, zlanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zhemm, zunt01
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 .OR. m.LE.0 )
     $   RETURN
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Precision' )
*
*     Do Test 1
*
*     Norm of A:
*
      anorm = max( zlanhe( '1', uplo, n, a, lda, rwork ), unfl )
*
*     Compute error matrix:
*
*     ITYPE=1: error = U**H A U - S
*
      CALL zhemm( 'L', uplo, n, m, cone, a, lda, u, ldu, czero, work,
     $            n )
      nn = n*n
      nnp1 = nn + 1
      CALL zgemm( 'C', 'N', m, m, n, cone, u, ldu, work, n, czero,
     $            work( nnp1 ), n )
      DO 10 j = 1, m
         jj = nn + ( j-1 )*n + j
         work( jj ) = work( jj ) - d( j )
   10 CONTINUE
      IF( kband.EQ.1 .AND. n.GT.1 ) THEN
         DO 20 j = 2, m
            jj1 = nn + ( j-1 )*n + j - 1
            jj2 = nn + ( j-2 )*n + j
            work( jj1 ) = work( jj1 ) - e( j-1 )
            work( jj2 ) = work( jj2 ) - e( j-1 )
   20    CONTINUE
      END IF
      wnorm = zlanhe( '1', uplo, m, work( nnp1 ), n, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( m*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, m*anorm ) / anorm ) / ( m*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( m ) ) / ( m*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U**H U - I
*
      IF( itype.EQ.1 )
     $   CALL zunt01( 'Columns', n, m, u, ldu, work, 2*n*n, rwork,
     $                result( 2 ) )
*
      RETURN
*
*     End of ZHET22
*

Here is the call graph for this function:

Here is the caller graph for this function: