LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zhemm()

subroutine zhemm ( character side,
character uplo,
integer m,
integer n,
complex*16 alpha,
complex*16, dimension(lda,*) a,
integer lda,
complex*16, dimension(ldb,*) b,
integer ldb,
complex*16 beta,
complex*16, dimension(ldc,*) c,
integer ldc )

ZHEMM

Purpose:
!>
!> ZHEMM  performs one of the matrix-matrix operations
!>
!>    C := alpha*A*B + beta*C,
!>
!> or
!>
!>    C := alpha*B*A + beta*C,
!>
!> where alpha and beta are scalars, A is an hermitian matrix and  B and
!> C are m by n matrices.
!>
Parameters
[in]SIDE
!>          SIDE is CHARACTER*1
!>           On entry,  SIDE  specifies whether  the  hermitian matrix  A
!>           appears on the  left or right  in the  operation as follows:
!>
!>              SIDE = 'L' or 'l'   C := alpha*A*B + beta*C,
!>
!>              SIDE = 'R' or 'r'   C := alpha*B*A + beta*C,
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>           On  entry,   UPLO  specifies  whether  the  upper  or  lower
!>           triangular  part  of  the  hermitian  matrix   A  is  to  be
!>           referenced as follows:
!>
!>              UPLO = 'U' or 'u'   Only the upper triangular part of the
!>                                  hermitian matrix is to be referenced.
!>
!>              UPLO = 'L' or 'l'   Only the lower triangular part of the
!>                                  hermitian matrix is to be referenced.
!>
[in]M
!>          M is INTEGER
!>           On entry,  M  specifies the number of rows of the matrix  C.
!>           M  must be at least zero.
!>
[in]N
!>          N is INTEGER
!>           On entry, N specifies the number of columns of the matrix C.
!>           N  must be at least zero.
!>
[in]ALPHA
!>          ALPHA is COMPLEX*16
!>           On entry, ALPHA specifies the scalar alpha.
!>
[in]A
!>          A is COMPLEX*16 array, dimension ( LDA, ka ), where ka is
!>           m  when  SIDE = 'L' or 'l'  and is n  otherwise.
!>           Before entry  with  SIDE = 'L' or 'l',  the  m by m  part of
!>           the array  A  must contain the  hermitian matrix,  such that
!>           when  UPLO = 'U' or 'u', the leading m by m upper triangular
!>           part of the array  A  must contain the upper triangular part
!>           of the  hermitian matrix and the  strictly  lower triangular
!>           part of  A  is not referenced,  and when  UPLO = 'L' or 'l',
!>           the leading  m by m  lower triangular part  of the  array  A
!>           must  contain  the  lower triangular part  of the  hermitian
!>           matrix and the  strictly upper triangular part of  A  is not
!>           referenced.
!>           Before entry  with  SIDE = 'R' or 'r',  the  n by n  part of
!>           the array  A  must contain the  hermitian matrix,  such that
!>           when  UPLO = 'U' or 'u', the leading n by n upper triangular
!>           part of the array  A  must contain the upper triangular part
!>           of the  hermitian matrix and the  strictly  lower triangular
!>           part of  A  is not referenced,  and when  UPLO = 'L' or 'l',
!>           the leading  n by n  lower triangular part  of the  array  A
!>           must  contain  the  lower triangular part  of the  hermitian
!>           matrix and the  strictly upper triangular part of  A  is not
!>           referenced.
!>           Note that the imaginary parts  of the diagonal elements need
!>           not be set, they are assumed to be zero.
!>
[in]LDA
!>          LDA is INTEGER
!>           On entry, LDA specifies the first dimension of A as declared
!>           in the  calling (sub) program. When  SIDE = 'L' or 'l'  then
!>           LDA must be at least  max( 1, m ), otherwise  LDA must be at
!>           least max( 1, n ).
!>
[in]B
!>          B is COMPLEX*16 array, dimension ( LDB, N )
!>           Before entry, the leading  m by n part of the array  B  must
!>           contain the matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>           On entry, LDB specifies the first dimension of B as declared
!>           in  the  calling  (sub)  program.   LDB  must  be  at  least
!>           max( 1, m ).
!>
[in]BETA
!>          BETA is COMPLEX*16
!>           On entry,  BETA  specifies the scalar  beta.  When  BETA  is
!>           supplied as zero then C need not be set on input.
!>
[in,out]C
!>          C is COMPLEX*16 array, dimension ( LDC, N )
!>           Before entry, the leading  m by n  part of the array  C must
!>           contain the matrix  C,  except when  beta  is zero, in which
!>           case C need not be set on entry.
!>           On exit, the array  C  is overwritten by the  m by n updated
!>           matrix.
!>
[in]LDC
!>          LDC is INTEGER
!>           On entry, LDC specifies the first dimension of C as declared
!>           in  the  calling  (sub)  program.   LDC  must  be  at  least
!>           max( 1, m ).
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  Level 3 Blas routine.
!>
!>  -- Written on 8-February-1989.
!>     Jack Dongarra, Argonne National Laboratory.
!>     Iain Duff, AERE Harwell.
!>     Jeremy Du Croz, Numerical Algorithms Group Ltd.
!>     Sven Hammarling, Numerical Algorithms Group Ltd.
!>

Definition at line 190 of file zhemm.f.

191*
192* -- Reference BLAS level3 routine --
193* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
194* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195*
196* .. Scalar Arguments ..
197 COMPLEX*16 ALPHA,BETA
198 INTEGER LDA,LDB,LDC,M,N
199 CHARACTER SIDE,UPLO
200* ..
201* .. Array Arguments ..
202 COMPLEX*16 A(LDA,*),B(LDB,*),C(LDC,*)
203* ..
204*
205* =====================================================================
206*
207* .. External Functions ..
208 LOGICAL LSAME
209 EXTERNAL lsame
210* ..
211* .. External Subroutines ..
212 EXTERNAL xerbla
213* ..
214* .. Intrinsic Functions ..
215 INTRINSIC dble,dconjg,max
216* ..
217* .. Local Scalars ..
218 COMPLEX*16 TEMP1,TEMP2
219 INTEGER I,INFO,J,K,NROWA
220 LOGICAL UPPER
221* ..
222* .. Parameters ..
223 COMPLEX*16 ONE
224 parameter(one= (1.0d+0,0.0d+0))
225 COMPLEX*16 ZERO
226 parameter(zero= (0.0d+0,0.0d+0))
227* ..
228*
229* Set NROWA as the number of rows of A.
230*
231 IF (lsame(side,'L')) THEN
232 nrowa = m
233 ELSE
234 nrowa = n
235 END IF
236 upper = lsame(uplo,'U')
237*
238* Test the input parameters.
239*
240 info = 0
241 IF ((.NOT.lsame(side,'L')) .AND.
242 + (.NOT.lsame(side,'R'))) THEN
243 info = 1
244 ELSE IF ((.NOT.upper) .AND.
245 + (.NOT.lsame(uplo,'L'))) THEN
246 info = 2
247 ELSE IF (m.LT.0) THEN
248 info = 3
249 ELSE IF (n.LT.0) THEN
250 info = 4
251 ELSE IF (lda.LT.max(1,nrowa)) THEN
252 info = 7
253 ELSE IF (ldb.LT.max(1,m)) THEN
254 info = 9
255 ELSE IF (ldc.LT.max(1,m)) THEN
256 info = 12
257 END IF
258 IF (info.NE.0) THEN
259 CALL xerbla('ZHEMM ',info)
260 RETURN
261 END IF
262*
263* Quick return if possible.
264*
265 IF ((m.EQ.0) .OR. (n.EQ.0) .OR.
266 + ((alpha.EQ.zero).AND. (beta.EQ.one))) RETURN
267*
268* And when alpha.eq.zero.
269*
270 IF (alpha.EQ.zero) THEN
271 IF (beta.EQ.zero) THEN
272 DO 20 j = 1,n
273 DO 10 i = 1,m
274 c(i,j) = zero
275 10 CONTINUE
276 20 CONTINUE
277 ELSE
278 DO 40 j = 1,n
279 DO 30 i = 1,m
280 c(i,j) = beta*c(i,j)
281 30 CONTINUE
282 40 CONTINUE
283 END IF
284 RETURN
285 END IF
286*
287* Start the operations.
288*
289 IF (lsame(side,'L')) THEN
290*
291* Form C := alpha*A*B + beta*C.
292*
293 IF (upper) THEN
294 DO 70 j = 1,n
295 DO 60 i = 1,m
296 temp1 = alpha*b(i,j)
297 temp2 = zero
298 DO 50 k = 1,i - 1
299 c(k,j) = c(k,j) + temp1*a(k,i)
300 temp2 = temp2 + b(k,j)*dconjg(a(k,i))
301 50 CONTINUE
302 IF (beta.EQ.zero) THEN
303 c(i,j) = temp1*dble(a(i,i)) + alpha*temp2
304 ELSE
305 c(i,j) = beta*c(i,j) + temp1*dble(a(i,i)) +
306 + alpha*temp2
307 END IF
308 60 CONTINUE
309 70 CONTINUE
310 ELSE
311 DO 100 j = 1,n
312 DO 90 i = m,1,-1
313 temp1 = alpha*b(i,j)
314 temp2 = zero
315 DO 80 k = i + 1,m
316 c(k,j) = c(k,j) + temp1*a(k,i)
317 temp2 = temp2 + b(k,j)*dconjg(a(k,i))
318 80 CONTINUE
319 IF (beta.EQ.zero) THEN
320 c(i,j) = temp1*dble(a(i,i)) + alpha*temp2
321 ELSE
322 c(i,j) = beta*c(i,j) + temp1*dble(a(i,i)) +
323 + alpha*temp2
324 END IF
325 90 CONTINUE
326 100 CONTINUE
327 END IF
328 ELSE
329*
330* Form C := alpha*B*A + beta*C.
331*
332 DO 170 j = 1,n
333 temp1 = alpha*dble(a(j,j))
334 IF (beta.EQ.zero) THEN
335 DO 110 i = 1,m
336 c(i,j) = temp1*b(i,j)
337 110 CONTINUE
338 ELSE
339 DO 120 i = 1,m
340 c(i,j) = beta*c(i,j) + temp1*b(i,j)
341 120 CONTINUE
342 END IF
343 DO 140 k = 1,j - 1
344 IF (upper) THEN
345 temp1 = alpha*a(k,j)
346 ELSE
347 temp1 = alpha*dconjg(a(j,k))
348 END IF
349 DO 130 i = 1,m
350 c(i,j) = c(i,j) + temp1*b(i,k)
351 130 CONTINUE
352 140 CONTINUE
353 DO 160 k = j + 1,n
354 IF (upper) THEN
355 temp1 = alpha*dconjg(a(j,k))
356 ELSE
357 temp1 = alpha*a(k,j)
358 END IF
359 DO 150 i = 1,m
360 c(i,j) = c(i,j) + temp1*b(i,k)
361 150 CONTINUE
362 160 CONTINUE
363 170 CONTINUE
364 END IF
365*
366 RETURN
367*
368* End of ZHEMM
369*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: