LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sgbsvx()

subroutine sgbsvx ( character fact,
character trans,
integer n,
integer kl,
integer ku,
integer nrhs,
real, dimension( ldab, * ) ab,
integer ldab,
real, dimension( ldafb, * ) afb,
integer ldafb,
integer, dimension( * ) ipiv,
character equed,
real, dimension( * ) r,
real, dimension( * ) c,
real, dimension( ldb, * ) b,
integer ldb,
real, dimension( ldx, * ) x,
integer ldx,
real rcond,
real, dimension( * ) ferr,
real, dimension( * ) berr,
real, dimension( * ) work,
integer, dimension( * ) iwork,
integer info )

SGBSVX computes the solution to system of linear equations A * X = B for GB matrices

Download SGBSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SGBSVX uses the LU factorization to compute the solution to a real
!> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
!> where A is a band matrix of order N with KL subdiagonals and KU
!> superdiagonals, and X and B are N-by-NRHS matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!>
Description:
!>
!> The following steps are performed by this subroutine:
!>
!> 1. If FACT = 'E', real scaling factors are computed to equilibrate
!>    the system:
!>       TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
!>       TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
!>       TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
!>    Whether or not the system will be equilibrated depends on the
!>    scaling of the matrix A, but if equilibration is used, A is
!>    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
!>    or diag(C)*B (if TRANS = 'T' or 'C').
!>
!> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
!>    matrix A (after equilibration if FACT = 'E') as
!>       A = L * U,
!>    where L is a product of permutation and unit lower triangular
!>    matrices with KL subdiagonals, and U is upper triangular with
!>    KL+KU superdiagonals.
!>
!> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
!>    returns with INFO = i. Otherwise, the factored form of A is used
!>    to estimate the condition number of the matrix A.  If the
!>    reciprocal of the condition number is less than machine precision,
!>    INFO = N+1 is returned as a warning, but the routine still goes on
!>    to solve for X and compute error bounds as described below.
!>
!> 4. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 5. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!>
!> 6. If equilibration was used, the matrix X is premultiplied by
!>    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
!>    that it solves the original system before equilibration.
!>
Parameters
[in]FACT
!>          FACT is CHARACTER*1
!>          Specifies whether or not the factored form of the matrix A is
!>          supplied on entry, and if not, whether the matrix A should be
!>          equilibrated before it is factored.
!>          = 'F':  On entry, AFB and IPIV contain the factored form of
!>                  A.  If EQUED is not 'N', the matrix A has been
!>                  equilibrated with scaling factors given by R and C.
!>                  AB, AFB, and IPIV are not modified.
!>          = 'N':  The matrix A will be copied to AFB and factored.
!>          = 'E':  The matrix A will be equilibrated if necessary, then
!>                  copied to AFB and factored.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          Specifies the form of the system of equations.
!>          = 'N':  A * X = B     (No transpose)
!>          = 'T':  A**T * X = B  (Transpose)
!>          = 'C':  A**H * X = B  (Transpose)
!>
[in]N
!>          N is INTEGER
!>          The number of linear equations, i.e., the order of the
!>          matrix A.  N >= 0.
!>
[in]KL
!>          KL is INTEGER
!>          The number of subdiagonals within the band of A.  KL >= 0.
!>
[in]KU
!>          KU is INTEGER
!>          The number of superdiagonals within the band of A.  KU >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrices B and X.  NRHS >= 0.
!>
[in,out]AB
!>          AB is REAL array, dimension (LDAB,N)
!>          On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
!>          The j-th column of A is stored in the j-th column of the
!>          array AB as follows:
!>          AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
!>
!>          If FACT = 'F' and EQUED is not 'N', then A must have been
!>          equilibrated by the scaling factors in R and/or C.  AB is not
!>          modified if FACT = 'F' or 'N', or if FACT = 'E' and
!>          EQUED = 'N' on exit.
!>
!>          On exit, if EQUED .ne. 'N', A is scaled as follows:
!>          EQUED = 'R':  A := diag(R) * A
!>          EQUED = 'C':  A := A * diag(C)
!>          EQUED = 'B':  A := diag(R) * A * diag(C).
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KL+KU+1.
!>
[in,out]AFB
!>          AFB is REAL array, dimension (LDAFB,N)
!>          If FACT = 'F', then AFB is an input argument and on entry
!>          contains details of the LU factorization of the band matrix
!>          A, as computed by SGBTRF.  U is stored as an upper triangular
!>          band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
!>          and the multipliers used during the factorization are stored
!>          in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
!>          the factored form of the equilibrated matrix A.
!>
!>          If FACT = 'N', then AFB is an output argument and on exit
!>          returns details of the LU factorization of A.
!>
!>          If FACT = 'E', then AFB is an output argument and on exit
!>          returns details of the LU factorization of the equilibrated
!>          matrix A (see the description of AB for the form of the
!>          equilibrated matrix).
!>
[in]LDAFB
!>          LDAFB is INTEGER
!>          The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
!>
[in,out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          If FACT = 'F', then IPIV is an input argument and on entry
!>          contains the pivot indices from the factorization A = L*U
!>          as computed by SGBTRF; row i of the matrix was interchanged
!>          with row IPIV(i).
!>
!>          If FACT = 'N', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the original matrix A.
!>
!>          If FACT = 'E', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the equilibrated matrix A.
!>
[in,out]EQUED
!>          EQUED is CHARACTER*1
!>          Specifies the form of equilibration that was done.
!>          = 'N':  No equilibration (always true if FACT = 'N').
!>          = 'R':  Row equilibration, i.e., A has been premultiplied by
!>                  diag(R).
!>          = 'C':  Column equilibration, i.e., A has been postmultiplied
!>                  by diag(C).
!>          = 'B':  Both row and column equilibration, i.e., A has been
!>                  replaced by diag(R) * A * diag(C).
!>          EQUED is an input argument if FACT = 'F'; otherwise, it is an
!>          output argument.
!>
[in,out]R
!>          R is REAL array, dimension (N)
!>          The row scale factors for A.  If EQUED = 'R' or 'B', A is
!>          multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
!>          is not accessed.  R is an input argument if FACT = 'F';
!>          otherwise, R is an output argument.  If FACT = 'F' and
!>          EQUED = 'R' or 'B', each element of R must be positive.
!>
[in,out]C
!>          C is REAL array, dimension (N)
!>          The column scale factors for A.  If EQUED = 'C' or 'B', A is
!>          multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
!>          is not accessed.  C is an input argument if FACT = 'F';
!>          otherwise, C is an output argument.  If FACT = 'F' and
!>          EQUED = 'C' or 'B', each element of C must be positive.
!>
[in,out]B
!>          B is REAL array, dimension (LDB,NRHS)
!>          On entry, the right hand side matrix B.
!>          On exit,
!>          if EQUED = 'N', B is not modified;
!>          if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
!>          diag(R)*B;
!>          if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
!>          overwritten by diag(C)*B.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]X
!>          X is REAL array, dimension (LDX,NRHS)
!>          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
!>          to the original system of equations.  Note that A and B are
!>          modified on exit if EQUED .ne. 'N', and the solution to the
!>          equilibrated system is inv(diag(C))*X if TRANS = 'N' and
!>          EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
!>          and EQUED = 'R' or 'B'.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is REAL
!>          The estimate of the reciprocal condition number of the matrix
!>          A after equilibration (if done).  If RCOND is less than the
!>          machine precision (in particular, if RCOND = 0), the matrix
!>          is singular to working precision.  This condition is
!>          indicated by a return code of INFO > 0.
!>
[out]FERR
!>          FERR is REAL array, dimension (NRHS)
!>          The estimated forward error bound for each solution vector
!>          X(j) (the j-th column of the solution matrix X).
!>          If XTRUE is the true solution corresponding to X(j), FERR(j)
!>          is an estimated upper bound for the magnitude of the largest
!>          element in (X(j) - XTRUE) divided by the magnitude of the
!>          largest element in X(j).  The estimate is as reliable as
!>          the estimate for RCOND, and is almost always a slight
!>          overestimate of the true error.
!>
[out]BERR
!>          BERR is REAL array, dimension (NRHS)
!>          The componentwise relative backward error of each solution
!>          vector X(j) (i.e., the smallest relative change in
!>          any element of A or B that makes X(j) an exact solution).
!>
[out]WORK
!>          WORK is REAL array, dimension (MAX(1,3*N))
!>          On exit, WORK(1) contains the reciprocal pivot growth
!>          factor norm(A)/norm(U). The  norm is
!>          used. If WORK(1) is much less than 1, then the stability
!>          of the LU factorization of the (equilibrated) matrix A
!>          could be poor. This also means that the solution X, condition
!>          estimator RCOND, and forward error bound FERR could be
!>          unreliable. If factorization fails with 0<INFO<=N, then
!>          WORK(1) contains the reciprocal pivot growth factor for the
!>          leading INFO columns of A.
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, and i is
!>                <= N:  U(i,i) is exactly zero.  The factorization
!>                       has been completed, but the factor U is exactly
!>                       singular, so the solution and error bounds
!>                       could not be computed. RCOND = 0 is returned.
!>                = N+1: U is nonsingular, but RCOND is less than machine
!>                       precision, meaning that the matrix is singular
!>                       to working precision.  Nevertheless, the
!>                       solution and error bounds are computed because
!>                       there are a number of situations where the
!>                       computed solution can be more accurate than the
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 363 of file sgbsvx.f.

366*
367* -- LAPACK driver routine --
368* -- LAPACK is a software package provided by Univ. of Tennessee, --
369* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
370*
371* .. Scalar Arguments ..
372 CHARACTER EQUED, FACT, TRANS
373 INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
374 REAL RCOND
375* ..
376* .. Array Arguments ..
377 INTEGER IPIV( * ), IWORK( * )
378 REAL AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
379 $ BERR( * ), C( * ), FERR( * ), R( * ),
380 $ WORK( * ), X( LDX, * )
381* ..
382*
383* =====================================================================
384* Moved setting of INFO = N+1 so INFO does not subsequently get
385* overwritten. Sven, 17 Mar 05.
386* =====================================================================
387*
388* .. Parameters ..
389 REAL ZERO, ONE
390 parameter( zero = 0.0e+0, one = 1.0e+0 )
391* ..
392* .. Local Scalars ..
393 LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
394 CHARACTER NORM
395 INTEGER I, INFEQU, J, J1, J2
396 REAL AMAX, ANORM, BIGNUM, COLCND, RCMAX, RCMIN,
397 $ ROWCND, RPVGRW, SMLNUM
398* ..
399* .. External Functions ..
400 LOGICAL LSAME
401 REAL SLAMCH, SLANGB, SLANTB
402 EXTERNAL lsame, slamch, slangb, slantb
403* ..
404* .. External Subroutines ..
405 EXTERNAL scopy, sgbcon, sgbequ, sgbrfs, sgbtrf,
406 $ sgbtrs,
407 $ slacpy, slaqgb, xerbla
408* ..
409* .. Intrinsic Functions ..
410 INTRINSIC abs, max, min
411* ..
412* .. Executable Statements ..
413*
414 info = 0
415 nofact = lsame( fact, 'N' )
416 equil = lsame( fact, 'E' )
417 notran = lsame( trans, 'N' )
418 IF( nofact .OR. equil ) THEN
419 equed = 'N'
420 rowequ = .false.
421 colequ = .false.
422 ELSE
423 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
424 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
425 smlnum = slamch( 'Safe minimum' )
426 bignum = one / smlnum
427 END IF
428*
429* Test the input parameters.
430*
431 IF( .NOT.nofact .AND.
432 $ .NOT.equil .AND.
433 $ .NOT.lsame( fact, 'F' ) )
434 $ THEN
435 info = -1
436 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
437 $ lsame( trans, 'C' ) ) THEN
438 info = -2
439 ELSE IF( n.LT.0 ) THEN
440 info = -3
441 ELSE IF( kl.LT.0 ) THEN
442 info = -4
443 ELSE IF( ku.LT.0 ) THEN
444 info = -5
445 ELSE IF( nrhs.LT.0 ) THEN
446 info = -6
447 ELSE IF( ldab.LT.kl+ku+1 ) THEN
448 info = -8
449 ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
450 info = -10
451 ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
452 $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
453 info = -12
454 ELSE
455 IF( rowequ ) THEN
456 rcmin = bignum
457 rcmax = zero
458 DO 10 j = 1, n
459 rcmin = min( rcmin, r( j ) )
460 rcmax = max( rcmax, r( j ) )
461 10 CONTINUE
462 IF( rcmin.LE.zero ) THEN
463 info = -13
464 ELSE IF( n.GT.0 ) THEN
465 rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
466 ELSE
467 rowcnd = one
468 END IF
469 END IF
470 IF( colequ .AND. info.EQ.0 ) THEN
471 rcmin = bignum
472 rcmax = zero
473 DO 20 j = 1, n
474 rcmin = min( rcmin, c( j ) )
475 rcmax = max( rcmax, c( j ) )
476 20 CONTINUE
477 IF( rcmin.LE.zero ) THEN
478 info = -14
479 ELSE IF( n.GT.0 ) THEN
480 colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
481 ELSE
482 colcnd = one
483 END IF
484 END IF
485 IF( info.EQ.0 ) THEN
486 IF( ldb.LT.max( 1, n ) ) THEN
487 info = -16
488 ELSE IF( ldx.LT.max( 1, n ) ) THEN
489 info = -18
490 END IF
491 END IF
492 END IF
493*
494 IF( info.NE.0 ) THEN
495 CALL xerbla( 'SGBSVX', -info )
496 RETURN
497 END IF
498*
499 IF( equil ) THEN
500*
501* Compute row and column scalings to equilibrate the matrix A.
502*
503 CALL sgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
504 $ amax, infequ )
505 IF( infequ.EQ.0 ) THEN
506*
507* Equilibrate the matrix.
508*
509 CALL slaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd,
510 $ colcnd,
511 $ amax, equed )
512 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
513 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
514 END IF
515 END IF
516*
517* Scale the right hand side.
518*
519 IF( notran ) THEN
520 IF( rowequ ) THEN
521 DO 40 j = 1, nrhs
522 DO 30 i = 1, n
523 b( i, j ) = r( i )*b( i, j )
524 30 CONTINUE
525 40 CONTINUE
526 END IF
527 ELSE IF( colequ ) THEN
528 DO 60 j = 1, nrhs
529 DO 50 i = 1, n
530 b( i, j ) = c( i )*b( i, j )
531 50 CONTINUE
532 60 CONTINUE
533 END IF
534*
535 IF( nofact .OR. equil ) THEN
536*
537* Compute the LU factorization of the band matrix A.
538*
539 DO 70 j = 1, n
540 j1 = max( j-ku, 1 )
541 j2 = min( j+kl, n )
542 CALL scopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
543 $ afb( kl+ku+1-j+j1, j ), 1 )
544 70 CONTINUE
545*
546 CALL sgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
547*
548* Return if INFO is non-zero.
549*
550 IF( info.GT.0 ) THEN
551*
552* Compute the reciprocal pivot growth factor of the
553* leading rank-deficient INFO columns of A.
554*
555 anorm = zero
556 DO 90 j = 1, info
557 DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
558 anorm = max( anorm, abs( ab( i, j ) ) )
559 80 CONTINUE
560 90 CONTINUE
561 rpvgrw = slantb( 'M', 'U', 'N', info, min( info-1,
562 $ kl+ku ),
563 $ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
564 $ work )
565 IF( rpvgrw.EQ.zero ) THEN
566 rpvgrw = one
567 ELSE
568 rpvgrw = anorm / rpvgrw
569 END IF
570 work( 1 ) = rpvgrw
571 rcond = zero
572 RETURN
573 END IF
574 END IF
575*
576* Compute the norm of the matrix A and the
577* reciprocal pivot growth factor RPVGRW.
578*
579 IF( notran ) THEN
580 norm = '1'
581 ELSE
582 norm = 'I'
583 END IF
584 anorm = slangb( norm, n, kl, ku, ab, ldab, work )
585 rpvgrw = slantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, work )
586 IF( rpvgrw.EQ.zero ) THEN
587 rpvgrw = one
588 ELSE
589 rpvgrw = slangb( 'M', n, kl, ku, ab, ldab, work ) / rpvgrw
590 END IF
591*
592* Compute the reciprocal of the condition number of A.
593*
594 CALL sgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
595 $ work, iwork, info )
596*
597* Compute the solution matrix X.
598*
599 CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
600 CALL sgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
601 $ info )
602*
603* Use iterative refinement to improve the computed solution and
604* compute error bounds and backward error estimates for it.
605*
606 CALL sgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb,
607 $ ipiv,
608 $ b, ldb, x, ldx, ferr, berr, work, iwork, info )
609*
610* Transform the solution matrix X to a solution of the original
611* system.
612*
613 IF( notran ) THEN
614 IF( colequ ) THEN
615 DO 110 j = 1, nrhs
616 DO 100 i = 1, n
617 x( i, j ) = c( i )*x( i, j )
618 100 CONTINUE
619 110 CONTINUE
620 DO 120 j = 1, nrhs
621 ferr( j ) = ferr( j ) / colcnd
622 120 CONTINUE
623 END IF
624 ELSE IF( rowequ ) THEN
625 DO 140 j = 1, nrhs
626 DO 130 i = 1, n
627 x( i, j ) = r( i )*x( i, j )
628 130 CONTINUE
629 140 CONTINUE
630 DO 150 j = 1, nrhs
631 ferr( j ) = ferr( j ) / rowcnd
632 150 CONTINUE
633 END IF
634*
635* Set INFO = N+1 if the matrix is singular to working precision.
636*
637 IF( rcond.LT.slamch( 'Epsilon' ) )
638 $ info = n + 1
639*
640 work( 1 ) = rpvgrw
641 RETURN
642*
643* End of SGBSVX
644*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
scopy
subroutine scopy(n, sx, incx, sy, incy)
SCOPY
Definition scopy.f:82
sgbcon
subroutine sgbcon(norm, n, kl, ku, ab, ldab, ipiv, anorm, rcond, work, iwork, info)
SGBCON
Definition sgbcon.f:144
sgbequ
subroutine sgbequ(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, info)
SGBEQU
Definition sgbequ.f:152
sgbrfs
subroutine sgbrfs(trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, b, ldb, x, ldx, ferr, berr, work, iwork, info)
SGBRFS
Definition sgbrfs.f:204
sgbtrf
subroutine sgbtrf(m, n, kl, ku, ab, ldab, ipiv, info)
SGBTRF
Definition sgbtrf.f:142
sgbtrs
subroutine sgbtrs(trans, n, kl, ku, nrhs, ab, ldab, ipiv, b, ldb, info)
SGBTRS
Definition sgbtrs.f:137
slacpy
subroutine slacpy(uplo, m, n, a, lda, b, ldb)
SLACPY copies all or part of one two-dimensional array to another.
Definition slacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
slangb
real function slangb(norm, n, kl, ku, ab, ldab, work)
SLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition slangb.f:122
slantb
real function slantb(norm, uplo, diag, n, k, ab, ldab, work)
SLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition slantb.f:138
slaqgb
subroutine slaqgb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, equed)
SLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition slaqgb.f:158
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: