LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dgbsvx()

subroutine dgbsvx ( character fact,
character trans,
integer n,
integer kl,
integer ku,
integer nrhs,
double precision, dimension( ldab, * ) ab,
integer ldab,
double precision, dimension( ldafb, * ) afb,
integer ldafb,
integer, dimension( * ) ipiv,
character equed,
double precision, dimension( * ) r,
double precision, dimension( * ) c,
double precision, dimension( ldb, * ) b,
integer ldb,
double precision, dimension( ldx, * ) x,
integer ldx,
double precision rcond,
double precision, dimension( * ) ferr,
double precision, dimension( * ) berr,
double precision, dimension( * ) work,
integer, dimension( * ) iwork,
integer info )

DGBSVX computes the solution to system of linear equations A * X = B for GB matrices

Download DGBSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> DGBSVX uses the LU factorization to compute the solution to a real
!> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
!> where A is a band matrix of order N with KL subdiagonals and KU
!> superdiagonals, and X and B are N-by-NRHS matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!>
Description:
!>
!> The following steps are performed by this subroutine:
!>
!> 1. If FACT = 'E', real scaling factors are computed to equilibrate
!>    the system:
!>       TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
!>       TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
!>       TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
!>    Whether or not the system will be equilibrated depends on the
!>    scaling of the matrix A, but if equilibration is used, A is
!>    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
!>    or diag(C)*B (if TRANS = 'T' or 'C').
!>
!> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
!>    matrix A (after equilibration if FACT = 'E') as
!>       A = L * U,
!>    where L is a product of permutation and unit lower triangular
!>    matrices with KL subdiagonals, and U is upper triangular with
!>    KL+KU superdiagonals.
!>
!> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
!>    returns with INFO = i. Otherwise, the factored form of A is used
!>    to estimate the condition number of the matrix A.  If the
!>    reciprocal of the condition number is less than machine precision,
!>    INFO = N+1 is returned as a warning, but the routine still goes on
!>    to solve for X and compute error bounds as described below.
!>
!> 4. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 5. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!>
!> 6. If equilibration was used, the matrix X is premultiplied by
!>    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
!>    that it solves the original system before equilibration.
!>
Parameters
[in]FACT
!>          FACT is CHARACTER*1
!>          Specifies whether or not the factored form of the matrix A is
!>          supplied on entry, and if not, whether the matrix A should be
!>          equilibrated before it is factored.
!>          = 'F':  On entry, AFB and IPIV contain the factored form of
!>                  A.  If EQUED is not 'N', the matrix A has been
!>                  equilibrated with scaling factors given by R and C.
!>                  AB, AFB, and IPIV are not modified.
!>          = 'N':  The matrix A will be copied to AFB and factored.
!>          = 'E':  The matrix A will be equilibrated if necessary, then
!>                  copied to AFB and factored.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          Specifies the form of the system of equations.
!>          = 'N':  A * X = B     (No transpose)
!>          = 'T':  A**T * X = B  (Transpose)
!>          = 'C':  A**H * X = B  (Transpose)
!>
[in]N
!>          N is INTEGER
!>          The number of linear equations, i.e., the order of the
!>          matrix A.  N >= 0.
!>
[in]KL
!>          KL is INTEGER
!>          The number of subdiagonals within the band of A.  KL >= 0.
!>
[in]KU
!>          KU is INTEGER
!>          The number of superdiagonals within the band of A.  KU >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrices B and X.  NRHS >= 0.
!>
[in,out]AB
!>          AB is DOUBLE PRECISION array, dimension (LDAB,N)
!>          On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
!>          The j-th column of A is stored in the j-th column of the
!>          array AB as follows:
!>          AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
!>
!>          If FACT = 'F' and EQUED is not 'N', then A must have been
!>          equilibrated by the scaling factors in R and/or C.  AB is not
!>          modified if FACT = 'F' or 'N', or if FACT = 'E' and
!>          EQUED = 'N' on exit.
!>
!>          On exit, if EQUED .ne. 'N', A is scaled as follows:
!>          EQUED = 'R':  A := diag(R) * A
!>          EQUED = 'C':  A := A * diag(C)
!>          EQUED = 'B':  A := diag(R) * A * diag(C).
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KL+KU+1.
!>
[in,out]AFB
!>          AFB is DOUBLE PRECISION array, dimension (LDAFB,N)
!>          If FACT = 'F', then AFB is an input argument and on entry
!>          contains details of the LU factorization of the band matrix
!>          A, as computed by DGBTRF.  U is stored as an upper triangular
!>          band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
!>          and the multipliers used during the factorization are stored
!>          in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
!>          the factored form of the equilibrated matrix A.
!>
!>          If FACT = 'N', then AFB is an output argument and on exit
!>          returns details of the LU factorization of A.
!>
!>          If FACT = 'E', then AFB is an output argument and on exit
!>          returns details of the LU factorization of the equilibrated
!>          matrix A (see the description of AB for the form of the
!>          equilibrated matrix).
!>
[in]LDAFB
!>          LDAFB is INTEGER
!>          The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
!>
[in,out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          If FACT = 'F', then IPIV is an input argument and on entry
!>          contains the pivot indices from the factorization A = L*U
!>          as computed by DGBTRF; row i of the matrix was interchanged
!>          with row IPIV(i).
!>
!>          If FACT = 'N', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the original matrix A.
!>
!>          If FACT = 'E', then IPIV is an output argument and on exit
!>          contains the pivot indices from the factorization A = L*U
!>          of the equilibrated matrix A.
!>
[in,out]EQUED
!>          EQUED is CHARACTER*1
!>          Specifies the form of equilibration that was done.
!>          = 'N':  No equilibration (always true if FACT = 'N').
!>          = 'R':  Row equilibration, i.e., A has been premultiplied by
!>                  diag(R).
!>          = 'C':  Column equilibration, i.e., A has been postmultiplied
!>                  by diag(C).
!>          = 'B':  Both row and column equilibration, i.e., A has been
!>                  replaced by diag(R) * A * diag(C).
!>          EQUED is an input argument if FACT = 'F'; otherwise, it is an
!>          output argument.
!>
[in,out]R
!>          R is DOUBLE PRECISION array, dimension (N)
!>          The row scale factors for A.  If EQUED = 'R' or 'B', A is
!>          multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
!>          is not accessed.  R is an input argument if FACT = 'F';
!>          otherwise, R is an output argument.  If FACT = 'F' and
!>          EQUED = 'R' or 'B', each element of R must be positive.
!>
[in,out]C
!>          C is DOUBLE PRECISION array, dimension (N)
!>          The column scale factors for A.  If EQUED = 'C' or 'B', A is
!>          multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
!>          is not accessed.  C is an input argument if FACT = 'F';
!>          otherwise, C is an output argument.  If FACT = 'F' and
!>          EQUED = 'C' or 'B', each element of C must be positive.
!>
[in,out]B
!>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
!>          On entry, the right hand side matrix B.
!>          On exit,
!>          if EQUED = 'N', B is not modified;
!>          if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
!>          diag(R)*B;
!>          if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
!>          overwritten by diag(C)*B.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]X
!>          X is DOUBLE PRECISION array, dimension (LDX,NRHS)
!>          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
!>          to the original system of equations.  Note that A and B are
!>          modified on exit if EQUED .ne. 'N', and the solution to the
!>          equilibrated system is inv(diag(C))*X if TRANS = 'N' and
!>          EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
!>          and EQUED = 'R' or 'B'.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is DOUBLE PRECISION
!>          The estimate of the reciprocal condition number of the matrix
!>          A after equilibration (if done).  If RCOND is less than the
!>          machine precision (in particular, if RCOND = 0), the matrix
!>          is singular to working precision.  This condition is
!>          indicated by a return code of INFO > 0.
!>
[out]FERR
!>          FERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The estimated forward error bound for each solution vector
!>          X(j) (the j-th column of the solution matrix X).
!>          If XTRUE is the true solution corresponding to X(j), FERR(j)
!>          is an estimated upper bound for the magnitude of the largest
!>          element in (X(j) - XTRUE) divided by the magnitude of the
!>          largest element in X(j).  The estimate is as reliable as
!>          the estimate for RCOND, and is almost always a slight
!>          overestimate of the true error.
!>
[out]BERR
!>          BERR is DOUBLE PRECISION array, dimension (NRHS)
!>          The componentwise relative backward error of each solution
!>          vector X(j) (i.e., the smallest relative change in
!>          any element of A or B that makes X(j) an exact solution).
!>
[out]WORK
!>          WORK is DOUBLE PRECISION array, dimension (MAX(1,3*N))
!>          On exit, WORK(1) contains the reciprocal pivot growth
!>          factor norm(A)/norm(U). The  norm is
!>          used. If WORK(1) is much less than 1, then the stability
!>          of the LU factorization of the (equilibrated) matrix A
!>          could be poor. This also means that the solution X, condition
!>          estimator RCOND, and forward error bound FERR could be
!>          unreliable. If factorization fails with 0<INFO<=N, then
!>          WORK(1) contains the reciprocal pivot growth factor for the
!>          leading INFO columns of A.
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, and i is
!>                <= N:  U(i,i) is exactly zero.  The factorization
!>                       has been completed, but the factor U is exactly
!>                       singular, so the solution and error bounds
!>                       could not be computed. RCOND = 0 is returned.
!>                = N+1: U is nonsingular, but RCOND is less than machine
!>                       precision, meaning that the matrix is singular
!>                       to working precision.  Nevertheless, the
!>                       solution and error bounds are computed because
!>                       there are a number of situations where the
!>                       computed solution can be more accurate than the
!>                       value of RCOND would suggest.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 364 of file dgbsvx.f.

367*
368* -- LAPACK driver routine --
369* -- LAPACK is a software package provided by Univ. of Tennessee, --
370* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
371*
372* .. Scalar Arguments ..
373 CHARACTER EQUED, FACT, TRANS
374 INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
375 DOUBLE PRECISION RCOND
376* ..
377* .. Array Arguments ..
378 INTEGER IPIV( * ), IWORK( * )
379 DOUBLE PRECISION AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
380 $ BERR( * ), C( * ), FERR( * ), R( * ),
381 $ WORK( * ), X( LDX, * )
382* ..
383*
384* =====================================================================
385*
386* .. Parameters ..
387 DOUBLE PRECISION ZERO, ONE
388 parameter( zero = 0.0d+0, one = 1.0d+0 )
389* ..
390* .. Local Scalars ..
391 LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
392 CHARACTER NORM
393 INTEGER I, INFEQU, J, J1, J2
394 DOUBLE PRECISION AMAX, ANORM, BIGNUM, COLCND, RCMAX, RCMIN,
395 $ ROWCND, RPVGRW, SMLNUM
396* ..
397* .. External Functions ..
398 LOGICAL LSAME
399 DOUBLE PRECISION DLAMCH, DLANGB, DLANTB
400 EXTERNAL lsame, dlamch, dlangb, dlantb
401* ..
402* .. External Subroutines ..
403 EXTERNAL dcopy, dgbcon, dgbequ, dgbrfs, dgbtrf,
404 $ dgbtrs,
405 $ dlacpy, dlaqgb, xerbla
406* ..
407* .. Intrinsic Functions ..
408 INTRINSIC abs, max, min
409* ..
410* .. Executable Statements ..
411*
412 info = 0
413 nofact = lsame( fact, 'N' )
414 equil = lsame( fact, 'E' )
415 notran = lsame( trans, 'N' )
416 IF( nofact .OR. equil ) THEN
417 equed = 'N'
418 rowequ = .false.
419 colequ = .false.
420 ELSE
421 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
422 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
423 smlnum = dlamch( 'Safe minimum' )
424 bignum = one / smlnum
425 END IF
426*
427* Test the input parameters.
428*
429 IF( .NOT.nofact .AND.
430 $ .NOT.equil .AND.
431 $ .NOT.lsame( fact, 'F' ) )
432 $ THEN
433 info = -1
434 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
435 $ lsame( trans, 'C' ) ) THEN
436 info = -2
437 ELSE IF( n.LT.0 ) THEN
438 info = -3
439 ELSE IF( kl.LT.0 ) THEN
440 info = -4
441 ELSE IF( ku.LT.0 ) THEN
442 info = -5
443 ELSE IF( nrhs.LT.0 ) THEN
444 info = -6
445 ELSE IF( ldab.LT.kl+ku+1 ) THEN
446 info = -8
447 ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
448 info = -10
449 ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
450 $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
451 info = -12
452 ELSE
453 IF( rowequ ) THEN
454 rcmin = bignum
455 rcmax = zero
456 DO 10 j = 1, n
457 rcmin = min( rcmin, r( j ) )
458 rcmax = max( rcmax, r( j ) )
459 10 CONTINUE
460 IF( rcmin.LE.zero ) THEN
461 info = -13
462 ELSE IF( n.GT.0 ) THEN
463 rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
464 ELSE
465 rowcnd = one
466 END IF
467 END IF
468 IF( colequ .AND. info.EQ.0 ) THEN
469 rcmin = bignum
470 rcmax = zero
471 DO 20 j = 1, n
472 rcmin = min( rcmin, c( j ) )
473 rcmax = max( rcmax, c( j ) )
474 20 CONTINUE
475 IF( rcmin.LE.zero ) THEN
476 info = -14
477 ELSE IF( n.GT.0 ) THEN
478 colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
479 ELSE
480 colcnd = one
481 END IF
482 END IF
483 IF( info.EQ.0 ) THEN
484 IF( ldb.LT.max( 1, n ) ) THEN
485 info = -16
486 ELSE IF( ldx.LT.max( 1, n ) ) THEN
487 info = -18
488 END IF
489 END IF
490 END IF
491*
492 IF( info.NE.0 ) THEN
493 CALL xerbla( 'DGBSVX', -info )
494 RETURN
495 END IF
496*
497 IF( equil ) THEN
498*
499* Compute row and column scalings to equilibrate the matrix A.
500*
501 CALL dgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
502 $ amax, infequ )
503 IF( infequ.EQ.0 ) THEN
504*
505* Equilibrate the matrix.
506*
507 CALL dlaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd,
508 $ colcnd,
509 $ amax, equed )
510 rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
511 colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
512 END IF
513 END IF
514*
515* Scale the right hand side.
516*
517 IF( notran ) THEN
518 IF( rowequ ) THEN
519 DO 40 j = 1, nrhs
520 DO 30 i = 1, n
521 b( i, j ) = r( i )*b( i, j )
522 30 CONTINUE
523 40 CONTINUE
524 END IF
525 ELSE IF( colequ ) THEN
526 DO 60 j = 1, nrhs
527 DO 50 i = 1, n
528 b( i, j ) = c( i )*b( i, j )
529 50 CONTINUE
530 60 CONTINUE
531 END IF
532*
533 IF( nofact .OR. equil ) THEN
534*
535* Compute the LU factorization of the band matrix A.
536*
537 DO 70 j = 1, n
538 j1 = max( j-ku, 1 )
539 j2 = min( j+kl, n )
540 CALL dcopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
541 $ afb( kl+ku+1-j+j1, j ), 1 )
542 70 CONTINUE
543*
544 CALL dgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
545*
546* Return if INFO is non-zero.
547*
548 IF( info.GT.0 ) THEN
549*
550* Compute the reciprocal pivot growth factor of the
551* leading rank-deficient INFO columns of A.
552*
553 anorm = zero
554 DO 90 j = 1, info
555 DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
556 anorm = max( anorm, abs( ab( i, j ) ) )
557 80 CONTINUE
558 90 CONTINUE
559 rpvgrw = dlantb( 'M', 'U', 'N', info, min( info-1,
560 $ kl+ku ),
561 $ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
562 $ work )
563 IF( rpvgrw.EQ.zero ) THEN
564 rpvgrw = one
565 ELSE
566 rpvgrw = anorm / rpvgrw
567 END IF
568 work( 1 ) = rpvgrw
569 rcond = zero
570 RETURN
571 END IF
572 END IF
573*
574* Compute the norm of the matrix A and the
575* reciprocal pivot growth factor RPVGRW.
576*
577 IF( notran ) THEN
578 norm = '1'
579 ELSE
580 norm = 'I'
581 END IF
582 anorm = dlangb( norm, n, kl, ku, ab, ldab, work )
583 rpvgrw = dlantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, work )
584 IF( rpvgrw.EQ.zero ) THEN
585 rpvgrw = one
586 ELSE
587 rpvgrw = dlangb( 'M', n, kl, ku, ab, ldab, work ) / rpvgrw
588 END IF
589*
590* Compute the reciprocal of the condition number of A.
591*
592 CALL dgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
593 $ work, iwork, info )
594*
595* Compute the solution matrix X.
596*
597 CALL dlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
598 CALL dgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
599 $ info )
600*
601* Use iterative refinement to improve the computed solution and
602* compute error bounds and backward error estimates for it.
603*
604 CALL dgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb,
605 $ ipiv,
606 $ b, ldb, x, ldx, ferr, berr, work, iwork, info )
607*
608* Transform the solution matrix X to a solution of the original
609* system.
610*
611 IF( notran ) THEN
612 IF( colequ ) THEN
613 DO 110 j = 1, nrhs
614 DO 100 i = 1, n
615 x( i, j ) = c( i )*x( i, j )
616 100 CONTINUE
617 110 CONTINUE
618 DO 120 j = 1, nrhs
619 ferr( j ) = ferr( j ) / colcnd
620 120 CONTINUE
621 END IF
622 ELSE IF( rowequ ) THEN
623 DO 140 j = 1, nrhs
624 DO 130 i = 1, n
625 x( i, j ) = r( i )*x( i, j )
626 130 CONTINUE
627 140 CONTINUE
628 DO 150 j = 1, nrhs
629 ferr( j ) = ferr( j ) / rowcnd
630 150 CONTINUE
631 END IF
632*
633* Set INFO = N+1 if the matrix is singular to working precision.
634*
635 IF( rcond.LT.dlamch( 'Epsilon' ) )
636 $ info = n + 1
637*
638 work( 1 ) = rpvgrw
639 RETURN
640*
641* End of DGBSVX
642*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
dcopy
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
dgbcon
subroutine dgbcon(norm, n, kl, ku, ab, ldab, ipiv, anorm, rcond, work, iwork, info)
DGBCON
Definition dgbcon.f:145
dgbequ
subroutine dgbequ(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, info)
DGBEQU
Definition dgbequ.f:152
dgbrfs
subroutine dgbrfs(trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv, b, ldb, x, ldx, ferr, berr, work, iwork, info)
DGBRFS
Definition dgbrfs.f:204
dgbtrf
subroutine dgbtrf(m, n, kl, ku, ab, ldab, ipiv, info)
DGBTRF
Definition dgbtrf.f:142
dgbtrs
subroutine dgbtrs(trans, n, kl, ku, nrhs, ab, ldab, ipiv, b, ldb, info)
DGBTRS
Definition dgbtrs.f:137
dlacpy
subroutine dlacpy(uplo, m, n, a, lda, b, ldb)
DLACPY copies all or part of one two-dimensional array to another.
Definition dlacpy.f:101
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
dlangb
double precision function dlangb(norm, n, kl, ku, ab, ldab, work)
DLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition dlangb.f:122
dlantb
double precision function dlantb(norm, uplo, diag, n, k, ab, ldab, work)
DLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition dlantb.f:138
dlaqgb
subroutine dlaqgb(m, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd, amax, equed)
DLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition dlaqgb.f:158
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
Here is the call graph for this function:
Here is the caller graph for this function: